[文件操作] 【已解决】批处理创建右键菜单项，实现在选中的文件或文件夹的名称前加上当前日期前缀

279491611

右键重命名收到的文件或文件夹在前面加日期， 比如我今天 收到一个文件夹为 “ ABC”  我 希望点击文件夹--右键 -- 就能重命名为" 2015-01-21_ABC"。
再比如我今天 收到一个文件为 “ ABC.rar”  我 希望点击文件夹--右键 -- 就能重命名为" 2015-01-21_ABC.rar",后缀不变。
当然要是能选几个一起，分别在前面加上 当前日期 那就更完美了。 当然文件也是一样的。只要选中的才修改。没选中的都不变。
日期和原文件名（文件夹名）之间用“_"隔开。日期格式 如 ”2015-01-21” 一样的.

pcl_test

回复 1# 279491611

支持选中单个或多个文件重命名，也支持选中单个或多个文件夹重命名，不支持文件和文件夹混合重命名
请以管理员身份运行该批处理，因为需写入注册表，如果被杀软拦截，请选择允许运行或先退出杀软

@echo off
echo ren %%1 "%%date:~0,4%%-%%date:~5,2%%-%%date:~8,2%%_%%~n1%%~x1" >"C:\Program Files\文件名添加日期.bat"
reg add "HKCR\*\shell\文件名添加日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件名添加日期.bat\" \"%%1\"" /f
echo ren %%1 "%%date:~0,4%%-%%date:~5,2%%-%%date:~8,2%%_%%~n1" >"C:\Program Files\文件夹名添加日期.bat"
reg add "HKCR\Directory\shell\文件夹名添加日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件夹名添加日期.bat\" \"%%1\"" /f
echo 建立“文件或文件夹名添加日期”右键菜单成功！
pause
复制代码

279491611

回复 2# pcl_test


    谢谢！果然好用。而且介绍的也很详细.

279491611

用两个批处理来完成这个动作，果然高明，我老想着一个呢。思路很重要啊。

alexmai

回复 2# pcl_test



我尝试把日期后置，出现问题，请帮忙调整，增加扩展名，感谢

@echo off
echo ren %%1 "%%~n1-%%date:~0,4%%.%%date:~5,2%%.%%date:~8,2%%~x" >"C:\Program Files\文件名添加日期.bat"
reg add "HKCR\*\shell\文件名添加日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件名添加日期.bat\" \"%%1\"" /f
echo ren %%1 "%%~n1-%%date:~0,4%%.%%date:~5,2%%.%%date:~8,2" >"C:\Program Files\文件夹名添加日期.bat"
reg add "HKCR\Directory\shell\文件夹名添加日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件夹名添加日期.bat\" \"%%1\"" /f
echo 建立“文件或文件夹名添加日期”右键菜单成功！
pause
复制代码

77七

回复 5# alexmai

@echo off
echo ren %%1 "%%~n1-%%date:~0,4%%-%%date:~5,2%%-%%date:~8,2%%%%~x1" >"C:\Program Files\文件名添加日期.bat"
reg add "HKCR\*\shell\文件名添加日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件名添加日期.bat\" \"%%1\"" /f
echo ren %%1 "%%~n1-%%date:~0,4%%-%%date:~5,2%%-%%date:~8,2%%" >"C:\Program Files\文件夹名添加日期.bat"
reg add "HKCR\Directory\shell\文件夹名添加日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件夹名添加日期.bat\" \"%%1\"" /f
echo 建立“文件或文件夹名添加日期”右键菜单成功！
pause
复制代码

563406396

回复 6# 77七


    能否再出一个
将日期后缀更新为当前日期

563406396

回复 2# pcl_test


       能否再出一个
将日期后缀更新为当前日期

77七

回复 7# 563406396


   文件名格式如 xxxx2023-11-26.xxx ，取文件名 （不包括扩展名）后10位。（添加文件名可使用6楼代码）
文件夹名格式如 xxxx2023-11-26

@echo off
rem 批处理保存为ansi编码格式
>"C:\Program Files\文件名更新日期.bat" (
        echo set oldN=%%~n1
        echo ren "%%~1" "%%oldN:~0,-10%%%%date:~0,4%%-%%date:~5,2%%-%%date:~8,2%%%%~x1"
)
reg add "HKCR\*\shell\文件名更新日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件名更新日期.bat\" \"%%1\"" /f
>"C:\Program Files\文件夹名更新日期.bat" (
        echo set oldN=%%~nx1
        echo ren "%%~1" "%%oldN:~0,-10%%%%date:~0,4%%-%%date:~5,2%%-%%date:~8,2%%"
)
reg add "HKCR\Directory\shell\文件夹名更新日期\Command" /ve /t REG_SZ /d "\"C:\Program Files\文件夹名更新日期.bat\" \"%%1\"" /f
echo 建立“文件或文件夹名更新日期”右键菜单成功！
pause
复制代码

563406396

回复 9# 77七


    完美解决，谢谢大佬