[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[日期时间] 批处理获取指定天数之前的日期(2016-06-13更新)

日期计算是不能直接进行减法(或加法)的,因为涉及到跨月、跨年、闰年等情况。

1582年以来公历的置闰规则:
普通闰年:公历年份是4的倍数,且不是100的倍数的,为闰年(如2004年、2020年等就是闰年)。
世纪闰年:公历年份是整百数的,必须是400的倍数才是闰年(如1900年不是闰年,2000年是闰年)。

1582年以前的惯例:
四年一闰;如果公元A年的A(正数)能被4整除,那么它就是闰年;如果公元前B年的B(正数)除以4余1,那么它也是闰年。

【方案一】BAT调用PowerShell
  1. @echo off
  2. REM Win7/Win10/Win11等系统自带PowerShell
  3. REM 指定天数
  4. set DaysAgo=1
  5. for /f %%i in ('powershell -c "Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y-%%m-%%d""') do (
  6.     set "DstDate=%%i"
  7. )
  8. echo,%DstDate%
  9. pause
复制代码
【方案二】BAT调用VBS
  1. @echo off
  2. REM 指定天数
  3. set DaysAgo=1
  4. >"%temp%\MyDate.vbs" echo LastDate=date()-%DaysAgo%
  5. >>"%temp%\MyDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  6. >>"%temp%\MyDate.vbs" echo wscript.echo FmtDate
  7. for /f %%a in ('cscript /nologo "%temp%\MyDate.vbs"') do (
  8.     set DstDate=%%a
  9. )
  10. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  11. echo %DaysAgo%天之前的日期是:%DstDate%
  12. pause
复制代码
【方案三】BAT调用gawk
  1. @echo off
  2. REM 本例需要命令行工具gawk.exe的支持,下载地址:
  3. REM http://bcn.bathome.net/s/tool/index.html?key=gawk
  4. REM 指定天数
  5. set DaysAgo=1
  6. set ThisDate=2014-02-20
  7. echo %ThisDate% | gawk -F "-" -v days=%DaysAgo% "{$1=$1;print strftime(\"%%F\",mktime($0\" 0 0 0\")-86400*days)}"
  8. pause
复制代码
【方案四】BAT调用日期时间函数
  1. @echo off
  2. REM 此类方法的关键在于如何获取标准化的当前系统日期
  3. REM 请参考http://bbs.bathome.cn/thread-3328-1-1.html
  4. REM 然后调用 Ritchie Lawrence 的日期函数,便可扩展出很多种方法,此处不再赘述。
  5. REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
  6. REM 指定天数
  7. set DaysAgo=1
  8. for /f "skip=4 delims= " %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  9.     set RegDateOld=%%a
  10. )
  11. set RegDateOld=%RegDateOld:~-8%
  12. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  13. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
  14. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  15. set /a PassDays-=%DaysAgo%
  16. call :DaysToDate %PassDays% DstYear DstMonth DstDay
  17. set DstDate=%DstYear%-%DstMonth%-%DstDay%
  18. echo %DaysAgo%天之前的日期是:%DstDate%
  19. pause
  20. goto :eof
  21. :DateToDays %yy% %mm% %dd% days
  22. setlocal ENABLEEXTENSIONS
  23. set yy=%1&set mm=%2&set dd=%3
  24. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  25. set /a dd=100%dd%%%100,mm=100%mm%%%100
  26. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
  27. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
  28. endlocal&set %4=%j%&goto :EOF
  29. :DaysToDate %days% yy mm dd
  30. setlocal ENABLEEXTENSIONS
  31. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
  32. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
  33. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
  34. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
  35. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

返回列表