小智BAT

回复 15# Batcher


    看看这个，是根据你帖子改写的。

@echo off
REM 设置网络适配器的名称
REM 英文系统一般是：Local Area Connection
REM set "AdapterName=Local Area Connection"
REM 中文系统一般是：本地连接
set "AdapterName=本地连接"

set "FileTmp=%temp%\ipList.txt"
ipconfig /all >"%FileTmp%"
for /f "delims=:" %%i in ('findstr /n /c:"%AdapterName%" "%FileTmp%"') do (
    set "SkipRow=%%i"
    goto :DoSkip
)

:DoSkip
for /f "tokens=2 delims=:(" %%i in ('more +%SkipRow% "%FileTmp%" ^| findstr /v "IPv6" ^|findstr "IP"') do (
    set "IP=%%i"
    goto :ShowResult
)

:ShowResult
set "IP=%IP: =%"
echo,%IP%
for /f "tokens=2 delims=:(" %%i in ('more +%SkipRow% "%FileTmp%" ^| findstr /v "IPv6" ^|findstr "子网掩码"') do (
    set "sm=%%i"
    goto :Showsm
)

:Showsm
set "sm=%sm: =%"
echo,%sm%
for /f "tokens=2 delims=:(" %%i in ('more +%SkipRow% "%FileTmp%" ^| findstr /v "IPv6" ^|findstr "默认网关"') do (
    set "wg=%%i"
    goto :Showwg
)

:Showwg
set "wg=%wg: =%"
echo,%wg%
pause
复制代码

小智BAT

回复 15# Batcher


    我已经更新代码了，你看看这样行不？

Batcher

回复 17# 小智BAT


    你自己多找一些不同的机器测试吧

apang

wmic

@echo off
set "w1=wmic nic where "NetConnectionID='无线网络连接'" get Index"
for /f %%a in ('%w1% ^| findstr /b [0-9]') do set "n=%%a"
set "w2=wmic nicconfig where "Index='%n%'" get DefaultIPGateway^,IPAddress^,IPSubnet"
for /f tokens^=1-2delims^={^" %%a in ('%w2% /value^|find "."')do set "%%a%%b"
echo,%IPAddress%
echo,%IPSubnet%
echo,%DefaultIPGateway%
pause
复制代码

apang

注册表：
xp下，reg query 的 /s 和 /v 开关好像不能一起使用，改一下：

@echo off & setlocal enabledelayedexpansion
set "v1=HKLM\SYSTEM\CurrentControlSet\Control\Network"
set "v2=HKLM\SYSTEM\CurrentControlSet\services\Tcpip\Parameters\Interfaces"
set "s=EnableDHCP IPAddress SubnetMask DefaultGateway"

for /f "delims=" %%i in ('reg query "%v1%" /s') do (
        set "v=%%i"
        if /i "!v:~,4!" == "HKEY" (
                for %%a in ("!v!\..") do set "ID=%%~nxa"
        ) else for /f "tokens=1,2*" %%a in ("!v!") do (
                if /i "%%a" == "Name" if "%%c" == "本地连接" goto :Next
        )
)

:Next
for /f "tokens=1,2*" %%i in ('reg query "%v2%\%ID%"^|findstr /i "%s%"')do (
        set "v=%%k" & set "%%i=!v:\0=!"
)

if /i "%EnableDHCP%" == "0x1" (
        echo,IP 地 址：%DHCPIPAddress%
        echo,子网掩码：%DHCPSubnetMask%
        echo,默认网关：%DHCPDefaultGateway%
) else (
        echo,IP 地 址：%IPAddress%
        echo,子网掩码：%SubnetMask%
        echo,默认网关：%DefaultGateway%
)
pause
复制代码

terse

回复 7# 小智BAT

这个仅显示 没测试多网卡 设置的话 WMIC应该也可以哦

@echo off&setlocal enabledelayedexpansion
set "str=DefaultIPGateway^,IPAddress^,DNSServerSearchOrder^,IPSubnet^,DHCPEnabled"
for /f "skip=1tokens=1*" %%i in ('wmic Nic where "Manufacturer<>'Microsoft' and NetConnectionStatus='2'" get Index^,NetConnectionID^') do (
    for /f %%j in ("%%j") do (
        echo 当前连接：%%j
        for /f "tokens=1,2 delims={}," %%a in ('wmic Nicconfig where "Index='%%i'" get %str% /value') do (
            for /f %%c in ("%%a%%~b") do set %%c
        )
    if /i "!DHCPEnabled!" == "TRUE" (
       echo 当前获取IP模式：自动
    ) else echo 当前获取IP模式：手动 
      echo 默认网关： !DefaultIPGateway!
      echo ip地址： !IPAddress!
      echo 主DNS： !DNSServerSearchOrder!
      echo 子网掩码： !IPSubnet!
    )
)
pause
复制代码

当然也可以获取 SettingID 后再在注册表里直接获取或修改

小智BAT

回复 19# apang


    很好很强大，话说wmic改IP怎么修改的，能不能给个栗子？？

Batcher

回复 22# 小智BAT

wmic nicconfig where(index='8') call enablestatic "192.168.1.81","255.255.255.0"
复制代码

http://bbs.bathome.net/thread-4068-1-1.html