neorobin

没学 PERL, CMD 弄了个

零零, 你去哪了, 我好想你, 我有好多好多 money 哦, 你快回来.....

@echo off & title RMB & chcp 936 & setlocal enabledelayedexpansion
set "unit=仟佰拾个" & set "unit1=角分" & set "num=零壹贰叁肆伍陆柒捌玖"

for %%x in (
    0
    0.00
    8
    0.2
    0.0
    987654321.12
    0.09
    3.02
    7.60
    50.00
    987654321
    987654320
    987654300
    987654000
    987650000
    987650321
    987654021
    987654301
    987650021
    987654001
    987650301
    987650001
    900000321
    900000000
    900000021
    900000001
    900000000.03
    900000000.00
    900000000.10
) do for /f "tokens=1-2 delims=." %%a in (
    "%%x"
) do (
    echo %%x
    set "dgt=%%a" & set "I="
    for /l %%i in (-16 1 -1) do (
        set /a "j=%%i+1, s=j>>31, j=s&j|~s&1, k=(%%i+1) %% 4 - 1"
        for /f "tokens=1-2" %%j in ("!j! !k!") do (
            if "!dgt:~%%i,%%j!" neq "" (
                for %%n in (!dgt:~%%i^,%%j!) do set "I=!I!!num:~%%n,1!!unit:~%%k,1!"
            )
        )
    )

    set "I=A!I:~-24,-16!亿!I:~-16,-8!万!I:~-8!元"
    set "I=!I:A亿=A!"
    set "I=!I:A万=A!"

    set "I=!I:零个=个!"
    set "I=!I:零拾个=个!"
    set "I=!I:零佰个=个!"
    set "I=!I:零仟个=个!"
    set "I=!I:个=!"

    set "I=!I:亿万元=亿元!"
    set "I=!I:亿万=亿零!"
    set "I=!I:零仟=零!"
    set "I=!I:零佰=零!"
    set "I=!I:零拾=零!"
    set "I=!I:零零=零!"
    set "I=!I:零零=零!"

    set "T=%%b00" & set "F="
    for %%i in (0 1) do for %%n in (!T:~%%i^,1!) do set "F=!F!!num:~%%n,1!!unit1:~%%i,1!"

    set "F=!F:零分=D!"
    set "F=!F:零角D=整!"
    set "F=!F:零角=零!"
    set "F=!F:D="!

    set "R=!I!!F!"
    set "R=!R:A元整=零元整!"
    set "R=!R:A元零=!"
    set "R=!R:A元=!"
    set "R=!R:A=!"

    echo !R! & echo.
)

pause
复制代码

neorobin

回复 4# 523066680

这个东东要精确而完整的的把逻辑 表达出来, 还真有点耗脑筋, 与其说代码的技术问题, 不如说是逻辑的表述, 整理. 我的代码, 我也没法证明是对的. 不管了.

会一点 C

neorobin

回复 6# 523066680

最早时用 QB 弄过立方体旋转, 可没有要用 C/C++ 开发 3D 引擎类的大志, BAT 不用编译, 随手就撸, 纯属自娱

neorobin

回复 6# 523066680


想起了经典歌词啊:  I CAN SING MY ABC