[文件操作] （已解决）批处理如何查找并替换指定目录中文本内的字符串？

yuanyannian

我碰到了难题：有一个文本，比如 H:\aaa\aaa.txt，内容如下：

RegLoad,SYS,"%x_y%\system"
zzzzzzzzzzzzzzz
zzzzzzzzzzzzzzz
zzzzzzzzzzzzzzz
zzzzzzzzzzzzzzz
UnLoad,SYS
复制代码

我的批处理为 D:\bbb\bbb.bat，我要将 aaa.txt 中的 %x_y% 替换为 H:\aaa，该如何写批处理。
我用下面的语句，只能处理批处理所在目录下的文本。

@echo off
Setlocal Enabledelayedexpansion

Set OName=H:\aaa\aaa.txt
Set HPath=H:\aaa

For /F "tokens=*" %%i In ('dir/b %OName%') Do ((For /F "tokens=1* delims=:" %%j In ('Findstr /n .* "%%i"') Do (
  Set SS=%%k
  If "!SS!"=="" (Echo.) Else Set SS=!SS:%%x_y%%=%HPath%!&Echo !SS!))>SS.txt
  Move /y SS.txt "%%i")

pause
复制代码

另外，有没有更精简的写法？

apang

用第三方工具最精简、高效

sed -i "s/%%x_y%%/H:\\aaa/g" "H:\aaa\aaa.txt"
复制代码

不想用三方的话，试试这样：

@echo off
Set "OName=H:\aaa\aaa.txt"
Set "HPath=H:\aaa"

(For /F "delims=" %%j In ('Findstr /n .* "%OName%"') Do (
      Set "SS=%%j"
      Setlocal Enabledelayedexpansion
      Set "SS=!SS:%%x_y%%=%HPath%!"
      Set "SS=!SS:*:=!"
      Echo,!SS!
))>SS.txt
Move SS.txt "%OName%"
pause
复制代码

yuanyannian

回复 2# apang

好用，谢谢！！！