leaparde

但是还是有一点疑问，为什么我从后往前去判断的时候，他就不停下来呢？？

如果有高手指点一下就好了，谢谢。

lhjoanna

此例你还是没仔细思考啊，再运行过后看你的这句：
if "!str1:~-%n%,1!" neq "" goto loop
循环能停止吗？

@echo off
setlocal enabledelayedexpansion
set str=12345678
echo !str:~-7,1!
echo !str:~-8,1!
echo !str:~-10,1!
echo !str:~-10,1!
echo !str:~-15,1!
echo !str:~-20,1!
echo !str:~-100,1!
pause>nul
复制代码

p05401144

@echo off & setlocal EnableDelayedExpansion
set str=！好你，nc.emohtab.sbb
for /l %%i in (17,-1,0) do set /p=!str:~%%i,1!<nul
echo.
pause

zcy85611

按本题的要求：

@echo off
set str=！好你，nc.emohtab.sbb
set m=1
:loop
set /a n+=1
if "%m%"=="" (echo.&pause) else (
set /p t=!str:~-%n%,1!<nul
set m=!str:~%n%!
goto loop
)
复制代码

任意输入字符串，反向输出

@echo off
set /p a=请输入字符串：
set str=%a%
set m=1
:loop
set /a n+=1
if "%m%"=="" (echo.&pause) else (
set /p t=!str:~-%n%,1!<nul
set m=!str:~%n%!
goto loop)
复制代码

我总感觉我写的代码麻烦了一点，不知道有没有按我这个思路，更简单一点的代码

[ 本帖最后由 zcy85611 于 2009-2-3 15:38 编辑 ]

keen

我的：

@echo off
set str=!好你，nc.emohtab.sbb
:loop
call, set /p=%%str:~-1%%<nul
set str=%str:~0,-1%
if "%str%"=="" goto end
goto loop
:end
pause>nul
复制代码

keen

再来：

@echo off
set str=!好你，nc.emohtab.sbb
for /l %%i in (17 -1 0) do call, set /p=%%str:~%%i,1%%<nul
pause>nul
复制代码

keen

输入任意字符：

@echo off
set /p a=please input:
set b=%a%
echo.
set /p=你输入的是:<nul
:loop
call, set /p=%%a:~0,1%%<nul
set a=%a:~1%
if "%a%"=="" goto zh
set /a n+=1
goto loop
:zh
echo.
echo.
set /p=倒序后是：<nul
for /l %%i in (%n% -1 0) do call, set /p=%%b:~%%i,1%%<nul
pause>nul
复制代码

rat

@mshta vbscript:alert(StrReverse("！好你，nc.emohtab.sbb"))(close)

keen

任意字符串：

@echo off
del a.txt>nul 2>nul
set /p a=please iput:
echo %a%>a.txt
echo.>>a.txt
for /f "tokens=1 delims=:" %%i in ('findstr /o .* a.txt') do set /a l=%%i-2
for /l %%k in (%l% -1 0) do call, set /p=%%a:~%%k,1%%<nul
del a.txt>nul 2>nul
pause>nul
复制代码

[ 本帖最后由 keen 于 2009-3-29 15:50 编辑 ]

rat

 @set /p s=Plz input:&&more /e +1 "%~f0"|call debug t %%s%%|findstr "^[^I\-0P]"&pause>nul&exit/b
a100
MOV     CL,[0080]
DEC     CX
MOV     AH,02
MOV     BX,CX
MOV     DL,[BX+0081]
INT     21
LOOP    0107
INT     20

g
q
复制代码

[ 本帖最后由 rat 于 2009-3-29 17:52 编辑 ]

Lumiere

for /l %%a in (17 -1 0) do call set /p=%%str:~%%a,1%%<nul
谁给解释一下上面一句啊？后面的set怎么不符合语法规则呢？可是运行是对的

Batcher

为什么说不符合语法规则？

cainiao736

@echo off&setlocal enabledelayedexpansion
set str=！好你，nc.emohtab.sbb
for /l %%i in (-1,-1,-18) do (
set a=!str:~%%i,1!
set b=!b!!a!)
echo %b%
pause
复制代码

sjzong

@echo off
set "str=！好你，nc.emohtab.sbb"
set "var="
:loop
if not "%str:~1,1%"=="" (set "var=%str:~0,1%%var%"&set "str=%str:~1%"&goto loop)
echo %str:~0,1%%var%
Pause>nul
复制代码

[ 本帖最后由 sjzong 于 2009-5-5 23:06 编辑 ]

scarcr

回复 1# wxcute

@echo off
setlocal enabledelayedexpansion
set "a=！好你，nc.emohtab.sbb"
for /l %%i in (17 -1 0) do (
    set b=!a:~%%i,1!
	set /p=!b!<nul
	)
pause>nul
复制代码