apang

1.

@echo off
%1(for /f "delims=" %%a in ('%~s0 :^|sort /r') do del/a/f/q %%a&rd/q %%a)&exit /b

set "folder=D:\BatHome"
echo,"%folder%\"
call :GetSubFolder "%folder%"
exit /b

:GetSubFolder
for /f "delims=" %%a in ('dir /ad/b "%~1\"') do (
    echo,"%~1\%%a\"
    call :GetSubFolder "%~1\%%a"
)
复制代码

2.

@echo off
set "wmic=wmic useraccount get name /value"
(for /f "tokens=2delims==" %%a in ('%wmic%^|find "="') do (
    for /f "tokens=*" %%b in ("%%a") do echo,%%b
))>$

for /f "delims=" %%a in ('findstr/ixvg:"D:\BatHome_User_List.txt" $') do (
    echo,增加的用户：%%a
)
for /f "delims=" %%a in ('findstr/ixvg:$ "D:\BatHome_User_List.txt"') do (
    echo,减少的用户：%%a
)
del $
pause
复制代码

3.

:~!@#$%^&*()+-=<>?/\|
@echo off&setlocal enabledelayedexpansion
set "str=QWERTYUIOPASDFGHJKLZXCVBNM qwertyuiopasdfghjklzxcvbnm"
set "str1=1234567890"
set /p str2=<%0
for /l %%a in (1001 1 1100) do (
    set "pwd=" & set "Name=%%a"
    for %%b in (%str%) do (
        set "a=%%b"
        set /a r=!random! %% 26
        for %%c in (!r!) do set "pwd=!pwd!!a:~%%c,1!"
    )
    set /a r1=!random! %% 10,r2=!random! %% 21
    for %%a in (!r1!) do set "pwd=!pwd!!str1:~%%a,1!"
    for %%a in (!r2!) do set "pwd=!pwd!!str2:~%%a,1!"
    Net User "BatHome!Name:~1!" "!pwd!%%a" /add
    echo,用户名：BatHome!Name:~1! 密码：!pwd!%%a>>List.txt
)
pause
复制代码

4.

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2*" %%a in ('systeminfo') do (
    if "%%a"=="物理内存总量:" set "mem=%%b"
    if "%%a"=="可用的物理内存:" set "freemem=%%b"
    if "%%a"=="系统启动时间:" (
        for /f "tokens=1-8" %%i in ("%%b %%c") do (
            set /a "st=%%i*24*3600+%%k*3600+%%m*60+%%o"
        )
    )
)

set /a "mem1=%mem:,=%0/1024,mem2=100*(%mem:,=%-%freemem:,=%)/%mem:,=%"
>D:\BatHome_OS.txt echo,已运行时间：%st%秒
>>D:\BatHome_OS.txt echo,物理内存总量：%mem1:~,-1%.%mem1:~-1%GB
>>D:\BatHome_OS.txt echo,内存使用率：%mem2%%%

set wmic=wmic logicaldisk where "DriveType='3'"
(for /f "tokens=1-3" %%i in ('%wmic% get freespace^,name^,size^|find ":"') do (
    call :GetSize %%k00
    set /a a=Size/1024
    set /p=%%j容量：!a:~,-1!.!a:~-1!GB <nul
    call :GetSize %%i00
    set /a "b=100*(a-Size/1024)/a"
    set /p=使用率：!b!%%<nul
    echo,
))>>D:\BatHome_OS.txt
pause&goto :eof

:GetSize
set "num=%1"&set "Size="&set "n="
for %%a in (16 8 4 2 1) do (
    if not "!num:~%%a!"=="" set /a n+=%%a&set "num=!num:~%%a!"
)
set "num=%1"
set /a n-=6
for /l %%a in (!n! -1 1) do (
    set "s=!num:~,-%%a!"
    if "!s:~,1!"=="0" set "s=!s:~1!"
    set /a m=s%%1048576,s/=1048576
    set "Size=!Size!!s!"
    set "num=!m!!num:~-%%a!"
)
if "!Size:~,1!"=="0" set "Size=!Size:~1!"
复制代码

5.

@echo off
::需要更改 Name 和 PWD 为实际的登录用户名和密码
more +6 "%~0">"%~dp0Back.bat"
schtasks /create /tn FulBack /tr "cmd /cxcopy /shcy \"D:\www.bathome\*\" \"D:\bbs.bathome\\"" /sc weekly /d sun /ru Name /rp PWD
schtasks /create /tn IncBack /tr \""%~dp0Back.bat"\" /sc weekly /d mon,tue,wed,thu,fri,sat /ru Name /rp PWD
pause&goto :eof

pushd "%~dp0"
(for %%a in ("\logs\" "\img\" ".zip" ".bak") do echo,%%~a)>$
xcopy /shcdy /exclude:$ "D:\www.bathome\*" "D:\bbs.bathome\"
del $
复制代码

6.

@echo off&setlocal enabledelayedexpansion
set /p Num1=输入被除数（正整数）：
set /p Num2=输入除数（小于9位数的正整数）：
set "x=100"

set /a Len1=Len2=0&set "tmp=%Num1%"
for %%a in (64 32 16 8 4 2 1) do (
    if "!tmp:~%%a!" neq "" set /a Len1+=%%a&set "tmp=!tmp:~%%a!"
)

set "tmp=%Num2%fedcba9876543210"
set /a Len2=0x!tmp:~15,1!

for /l %%a in (1 10 %x%) do set "str=!str!0000000000"
set "str=%Num1%%str%0"
set /a n = Len1 - Len2 + x + 1

for /l %%a in (!n! -1 1) do (
    set "s=!str:~,-%%a!"
    if "!s:~,1!"=="0" set "s=!s:~1!"
    set /a m=s %% Num2,s/=Num2
    set "Size=!Size!!s!"
    set "str=!m!!str:~-%%a!"
)

if %Len1% lss %Len2% (
    set "Size=0000000000!Size!" & set "Size=!Size:~-%x%!"
) else if "!Size:~,1!"=="0" set "Size=!Size:~1!"

echo,%Num1% ÷ %Num2% = !Size:~,-%x%!.!Size:~-%x%!
pause
复制代码

7.

@echo off&setlocal enabledelayedexpansion
::需要第三方工具 wget 和 geturls
set "url=http://www.zhuoku.com/zhuomianbizhi/show/index-1.htm"
set "str=tool.zhuoku.com/tool/dyw_size.php?width=1440&height=900&corp_x=center&corp_y=top&picurl=.."
wget -O "%tmp%\$1" "%url%" 2>nul
md show 2>nul
for /f "delims=" %%a in ('geturls /s:"zhuomianbizhi"^<"%tmp%\$1"^|findstr /i "\/[0-9]*\.htm$"') do (
    if not defined %%~na (
        wget -O "%tmp%\$2" "http://www.zhuoku.com/%%a" 2>nul
        for /f "delims=" %%b in ('geturls^<"%tmp%\$2"^|findstr /i "\.jpg$"')do (
            set "a=%%b"
            set "a=!a:/thumbs/tn_=/!"
            for /f "delims=" %%c in ("!a:img.zhuoku.com=%str%!") do (
                wget -O "show\%%~nxc" "%%c"
            )
        )
        set "%%~na=1"
    )
)
del "%tmp%\$*"
复制代码

8.

@echo off&setlocal enabledelayedexpansion
%1(for /f "tokens=2delims=." %%a in ('%~s0 :^|sort') do echo,%%a)>b.txt&exit /b

for /f "delims=" %%a in (a.txt) do (
    set "a=%%a" & set /a n=0
    for %%b in (整 角 分) do set "a=!a:%%b=!"
    for %%b in (捌 玖 拾) do set "a=!a:零%%b=%%b!"
    set "a=!a:拾=*10+!"
    set "a=!a:佰=*100+!"
    set "a=!a:仟=*1000+!"
    for %%b in (零 壹 贰 叁 肆 伍 陆 柒 捌 玖) do (
        for %%c in (!n!) do set "a=!a:%%b=%%c!"
        set /a n+=1
    )
    set "a=!a:+万=万!" & set "a=!a:+圆=圆!"
    if "!a:万=!" neq "!a!" set "a=(!a:万=)*10000+!"
    if "!a:圆=!"=="!a!" set "a=0圆!a!"
    set "a=!a:+圆=圆!"
    set "b=!a:*圆=!00"
    set "b=!b:~,2!"
    for /f "delims=圆" %%b in ("!a!") do set /a "a=%%b"
    set "str=..........!a!!b!"
    echo,!str:~-11!.%%a
)
复制代码

9.

@echo off&setlocal enabledelayedexpansion
md "%tmp%\~tmp\" 2>nul
for /d /r "f:\" %%a in (*) do (
    set /a n+=1
    set "_!n!=%%a"
    (for %%b in ("%%a\*") do echo,%%~nxb)>"%tmp%\~tmp\!n!.tx"
)

pushd "%tmp%\~tmp\"
(for /l %%a in (1 1 !n!) do (
    for /f "delims=" %%b in ('findstr/imxg:%%a.tx *.tx 2^>nul')do (
        if /i not "%%a.tx"=="%%b" (
            fc /c %%a.tx %%b|find /i "FC: 找不到">nul && (
                if not defined #%%a (
                    echo,!_%%a!&type %%a.tx&echo,
                    set #%%a=1
                )
                if not defined #%%~nb (
                    echo,!_%%~nb!&type %%b&echo,
                    set #%%~nb=1
                )
            )
        )
    )
))>"%~dp0List.txt"
popd&rd "%tmp%\~tmp\" /s /q
pause
复制代码

10.

@echo off
(echo,^<html^>&echo,^<body^>)>a.html
(for /f "delims=" %%a in ('findstr/ivn "^图[0-9]*\.[0-9]*" a.txt') do (
    set "str=%%a"
    setlocal enabledelayedexpansion
    set "str=!str:*:=!"
    if "!str:~,1!"=="第" if "!str:章=!" neq "!str!" set flag=1
    if defined flag (
        echo,^</br^>
        set "str=<p>!str!</p>"
    ) else (
        if "!str!" neq "" (
            set "str=&nbsp;&nbsp;&nbsp;&nbsp!str!</br>"
        ) else set "str=!str!</br>"
    )
    echo,!str!
    endlocal
))>>a.html
(echo,^</body^>&echo,^</html^>)>>a.html
pause
复制代码

apang

啊啊啊，居然是我拿第一？感觉像做梦，嗯嗯，高兴ing
感谢斑竹！感谢管理员！！！

apang

回复 24# PowerShell


   

敢问6楼apang：你这脚本测试时运行了多少小时？我这初步看貌似得2---3天！

此代码运行速度与分区中目录总数及文件总数有关，与相同的目录个数有关，而与硬盘数据大小没有直接关系。本人代码没有考虑分区中目录总数几千几万，文件总数几万几亿的情况。

在我的本本上（acer aspire 4750g，Win7 sp1），d:盘 1018个目录，7859个文件，测试用时10分14秒，生成List.txt大小44.9KB，List.txt中相同目录个数为451个

-------------------------------------------------------------------------------------------------------------

今天又测试，代码第12行改成： if /i not "%%a.tx"=="%%b" if not "!#%%a!!#%%~nb!"=="11" (
同样测试D盘，效率有所提高，用时=4分38秒，生成的List.txt与修改前相同