[网络工具] 批处理实现WIN7创建无线热点。虚拟WIFI(Virtual WIFI)创建。

zhouyongjun

让WIN7笔记本成为WIFI热点，其他设备不需要无线路由器就可以通过笔记本无线共享上网。这是WIN7提供的一个功能。由于本人比较喜欢这个功能，特写了个批处理来方便实现，并将开启开关动态添加到桌面右击菜单中，使用更加方便。相信其他朋友也会有需要，特分享给大家。

@echo off
title Win7虚拟WIFI[Z-Y-J]
::判断是否创建了虚拟WIFI，若创建了则运行删除部分，否则运行创建部分。（若注册表中无记录也将重新创建）
reg query hkcr\DesktopBackground\Shell\VirWifi >nul 2>nul && goto DelVirtualWifi || goto CreateVirtualWifi
::创建虚拟WIFI
:CreateVirtualWifi
set /p SSID=SSID（请设置无线ID）:
echo 安全密钥应为 8 到 63 个 ASCII 字符组成的字符串.
set /p PassWord=PassWord（请设置无线密码）:
::启用虚拟WIFI，密匙默认为永不过期。
netsh wlan set hostednetwork mode=allow ssid=%SSID% key=%PassWord% >nul 2>nul
echo 已经启用虚拟WIFI.
::将虚拟WIFI的状态添加到桌面快捷菜单，并关联一句复合CMD命令，让其动态改变虚拟WIFI的状态。
reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d "开启虚拟WIFI" /f >nul 2>nul
reg add hkcr\DesktopBackground\Shell\VirWifi\command /ve /t reg_sz /d "cmd /c reg query hkcr\DesktopBackground\Shell\VirWifi /ve | find """关闭虚拟WIFI""" >nul 2>nul && (netsh wlan stop hostednetwork >nul 2>nul & reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d """开启虚拟WIFI""" /f >nul 2>nul) || (netsh wlan start hostednetwork >nul 2>nul & reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d """关闭虚拟WIFI""" /f >nul 2>nul)" /f >nul 2>nul
::添加计划任务，系统每次开机都重新初始化虚拟WIFI的显示状态。
schtasks /create /ru system /tn RestVirWIFI /sc onstart /tr "cmd /c reg add hkcr\DesktopBackground\Shell\VirWifi /ve /t reg_sz /d """开启虚拟WIFI""" /f >nul 2>nul" /f >nul 2>nul
echo 已将开关虚拟WIFI添加到桌面右击菜单中.
echo 虚拟WIFI创建成功！请确定已经连接到Internet的网络是否已对虚拟WIFI共享。
echo 【设置共享的方法】
echo 右击已连接到Internet的网络连接，选择“属性”→“共享”，
echo 勾上“允许其他...连接”并选择已创建好的虚拟WIFI。
echo 确定之后，提供共享的连接图标旁会出现“共享的”字样，表示已共享至虚拟WIFI。
echo 共享完成后，在桌面右击菜单中就可以选择开启或关闭虚拟WIFI了。
echo 按任意键退出！
pause >nul
goto :eof
::删除虚拟WIFI
:DelVirtualWifi
echo 确定真的要删除虚拟WIFI？按任意键继续删除，放弃请直接关闭窗口。
pause >nul
::停用虚拟WIFI
netsh wlan set hostednetwork mode=disallow >nul 2>nul
::清除注册表记录
reg delete hkcr\DesktopBackground\Shell\VirWifi /f >nul 2>nul
::删除计划任务
schtasks /delete /tn RestVirWIFI /f >nul 2>nul
echo 删除成功，按任意键退出。
pause >nul
goto :eof
复制代码

zhouyongjun

回复 2# cjiabing


    XP貌似没有这个功能。
但是好像有其他方法可以连。

zhouyongjun

回复 4# cjiabing


   网络连接设置共享了没有。如果不行桥接一下本地连接与无线连接，看看是否可以。