【练习-028】批处理根据输入的日期格式输出当前日期

pusofalse

出题目的：
             综合运用批处理各语句，提高综合运用的水平。
加分规则：
    1、思路独特基分5分
    2、代码高效基分4分
    3、代码简洁基分3分
    4、代码通用基分2分
    5、无临时文件基分1分
    6、完美代码加分15分

题目内容：

根据输入的日期格式输出当天的日期。用y代表年份，m代表月份，d代表当前的日值。
比如今天日期是2008年10月21日：
输入mm dd yyyy，输出10 21 2008
输入yyyy/mm/dd，输出2008/10/21
输入mm-dd/yyyy，输出10-21/2008
输入md-md-yyyy，输出12-01-2008
输入ymydymyd，输出21020081
输入ydmydm-yy，输出221010-08
输入dd---/m/m/ y y y y， 输出21---/1/0/ 2 0 0 8

请先认真发现其中的规律。

相关条件：

1、不同的操作系统，日期格式会有不同。现在的题目中，未知%date%所扩展出的日期的格式，可以是以下的其中一种格式：
星期二 2008-10-21
2008-10-21 星期二
10/21/2008 Tue
Tue 10/21/2008
(只考虑用4位数表示的年份，暂时不必考虑用两位数表示的年份。)
获取当前标准格式的日期的方法不限，不必非要从%date%取值，可以用系统自带的reg.exe读取注册表等方法，只是不能借助第三方工具。
2、日期中各元素之间的连接符只需用/、-或空格，不必考虑用&、|、>等这类的特殊字符。
3、输入的格式中总是有4个y，2个m，2个d，不必考虑格式中只有3个y，1个m，或4个d等不合法的日期格式。而连接符（-、/或空格），可以没有，也可以有1个或多个。-、/、空格可以同时出现。
4、如果是2008-01-01、2000-12-12这样的日期，输入mmddyyyy虽然同ddmmyyyy是一样的结果，都是01012008、12122000，但第一个01确实是月份。ddmmyyyy格式的01012008，第一个01则是当前的日值。一切都以用户输入的为准。输入mdmdyyyy，输出00112008 等。。。
5、用纯批解决。

我的系统是xp_sp2，没有其他的测试环境，只能通过修改代码来测试。还请其他朋友帮忙测试答题人的代码。

[ 本帖最后由 pusofalse 于 2008-10-21 22:56 编辑 ]

neorobin

题目中列出的用户输入格式示例显乱, 题意不好理解, 表达年月日的数字被混插打乱已无实际意义, 偶没了解题欲望

qzwqzw

感觉出题和解题的思路已经过于学究了
研究的目的仍然是应用

而从应用的角度来讨论
各种奇怪的日期格式
其实应该是被抛弃的
而不是被鼓励的
况且题目中出现了任何应用系统都不支持和不会出现的日期格式
那讨论的价值和意义也就失去了

至于练习题的限制条件
我觉得不必强调简洁、高效、无临时文件
也许对于本题不简洁高效的代码和思路
换一个应用环境也许就是唯一适用的
所以思路和创意是最值得鼓励的

从Windows的应用角度来解题的话
这是我的思路
写代码的宗旨是
简单而不必简洁
适用而不必通用
有效而不必高效

@echo off & setlocal
set/p DateFmt=输入日期格式(MM,yyyy,dd)：
set Regkey="HKEY_CURRENT_USER\Control Panel\International"
reg export %Regkey% %temp%\~DateFmt.reg > nul
reg add %Regkey% /v sShortDate /d "%DateFmt%" /f >nul
echo.%date%
reg import %temp%\~DateFmt.reg > nul
for %%f in (%temp%\~DateFmt.reg?) do del %%f
复制代码

netbenton

真的很难！
不过还是做出来了，纯批的，适用多种情况

@echo off&setlocal enabledelayedexpansion
set n=1
for /f "tokens=2 delims=:" %%a in ('echo^;^|date') do (set str!n!=%%a&set/a n+=1)
set str2=!str2:~2,-2!
for %%a in (!str1!) do (set var=%%a
        if "!var:-=!" neq "!var!" set fen=-&set str=%%a
        if "!var:/=!" neq "!var!" set fen=/&set str=%%a

)
set n=3
for %%a in (!str2:%fen%^= !) do (set str!n!=%%a&set/a n+=1)
set n=3
if not defined str4 for %%a in (0 1 2) do (set str!n!=!str2:~%%a,1!&set/a n+=1)
set n=3
for %%a in (!str:%fen%^= !) do (
        for %%b in (str!n!) do (
                set !%%b!=%%a&set/a n+=1
        )
)

for %%a in ("年 月 日" "yyyy mm dd" "yy mm dd") do (
        for /f "tokens=1,2,3" %%b in (%%a) do (
                if defined %%b (
                for /f "tokens=1,2,3" %%e in ("!%%b! !%%c! !%%d!") do (
endlocal&setlocal enabledelayedexpansion
                        set #y=%%e
                        set #m=%%f
                        set #d=%%g
                ))
        )
)

:loop
set in=
set str=
set/p in=输入日期格式：
for %%a in (y m d) do (set in=!in:%%a=" "%%a" "!)
set/a .y=0,.m=0,.d=0
for %%a in ("!in!") do (
        if defined #%%~a (
                for %%b in (!.%%~a!) do (
                        set str=!str!!#%%~a:~%%b,1!
                )
                set/a .%%~a+=1
        ) else (set str=!str!%%~a)
)
echo 分解："!in!"
echo 处理结果：!str!
goto :loop
复制代码

keen

只能显示三种格式：1.用空格隔开的格式，例如mm dd yyyy;2.用/隔开的格式，例如：dd/mm/yyy;3.用-隔开的格式，例如：yyyy-dd-mm

@echo off&setlocal enabledelayedexpansion
set "str=%date%"
for /f "delims=0123456789-/" %%i in ("%str%") do set var=!str:%%i=!
for /f "tokens=1-3 delims=-" %%i in ("%var%") do (
    if "%%j" neq "" (
       set yyyy=%%i&set mm=%%j&set dd=%%k
    ) else (
       for /f "tokens=1-3 delims=/" %%a in ("%var%") do (set mm=%%a&set dd=%%b&set yyyy=%%c)
    )
)
set /p input=请输入：
for /f "tokens=1-3" %%i in ("%input%") do if "%%j" neq "" call,echo %%%%i%% %%%%j%% %%%%k%%
for /f "tokens=1-3 delims=-" %%i in ("%input%") do if "%%j" neq "" call,echo %%%%i%%-%%%%j%%-%%%%k%%
for /f "tokens=1-3 delims=/" %%i in ("%input%") do if "%%j" neq "" call,echo %%%%i%%/%%%%j%%/%%%%k%%
pause>nul
复制代码

shqf

　　先从注册表获得日期格式，把它保存到一个文件,再设置日期格式为yyyy-mm-dd,然后再交由主体程序按输入的格式去输出，最后恢复原先的日期格式。这样可不管原系统是什么日期格式了（3句语句可解决）。这样应该可行吧？可惜　按输入的格式去输出　我理解错了。

[ 本帖最后由 shqf 于 2008-10-22 19:57 编辑 ]

pusofalse

贴出我的代码，可能存在通用性问题。希望大家测试并指出其中问题：

@echo off&setlocal enabledelayedexpansion
for /f %%a in ('wmic path win32_operatingsystem get localdatetime') do set "CurrentDate=%%a"
rem 用wmic获取日期标准格式(yyyymmdd)，代码、思路来自于论坛巡查BATCHER。
rem 标准化获取当前日期：http://www.cn-dos.net/forum/viewthread.php?tid=41857&fpage=1&highlight=%2Bhat
set "CurrentDate=%CurrentDate:~0,8%"
set "Format=yyyymmdd"
for %%a in (Y M D) do set "%%a=defined"
for %%a in (4 2 2) do call :LOOP %%a
set /p DateFormat=Input the format：
:LP
set "Char=%DateFormat:~,1%"
if defined !Char! (
   set /a !Char! += 1
   <nul call call set /p=%%%%!Char!%%!Char!%%%%%%
   ) else (
   <nul set /p=!DateFormat:~,1!
)
set "DateFormat=!DateFormat:~1!"
if defined DateFormat goto :LP
pause>nul &exit /b

:LOOP
for /l %%a in (1 1 %1) do (
     set "!Format:~,1!%%a=!CurrentDate:~,1!"
     for %%i in (Format CurrentDate) do set "%%i=!%%i:~1!"
)
复制代码

[ 本帖最后由 pusofalse 于 2008-10-22 17:43 编辑 ]

Batcher

Win2k没有reg.exe
^_^

batman

@echo off&setlocal enabledelayedexpansion
set "d=%date%"
:lp1
set "a=!d:~,1!"&set "d=!d:~1!"
for %%i in (0 1 2 3 4 5 6 7 8 9) do if "%%i" equ "%a%" set "str=!str!%a%"&goto next
:next
if defined d goto lp1
set "com=reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate"
for /f "skip=4 tokens=3" %%i in ('%com%') do set "ymd=%%i"
set "ymd=%ymd:mm=m%"&set "ymd=!ymd:dd=d!" 
set "ymd=%ymd:m=mm%"&set "ymd=!ymd:d=dd!"
:lp2
set "a=!ymd:~,1!"&set "ymd=!ymd:~1!"
for %%i in (y m d) do (
    if /i "%%i" equ "%a%" (
       set /a .%%i+=1&set "%%i!.%%i!=!str:~,1!"&set "str=!str:~1!"
    )
)
if defined ymd goto lp2
set /p code=请输入格式：
:lp3
set "a=!code:~,1!"&set "code=!code:~1!"&set "ok=a"
for %%i in (y m d) do (
    if /i "%%i" equ "%a%" set /a _%%i+=1&call,set /p=%%%%i!_%%i!%%<nul&set "ok="
)
if defined ok set /p=%a%<nul
if defined code goto lp3
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-10-22 17:39 编辑 ]

batman

@echo off&setlocal enabledelayedexpansion
for %%a in (y1#0#1 y2#1#1 y3#2#1 y4#3#1 m1#5#1 m2#6#1 d1#8#1 d2#9#1) do (
    for /f "tokens=1,2,3 delims=#" %%i in ("%%a") do set "%%i=!date:~%%j,%%k!"
)
set /p code=请输入格式：
:lp
set "a=!code:~,1!"&set "code=!code:~1!"
set /a n+=1
for %%i in (d m y) do (
    if /i "%%i" equ "%a%" set /a .%%i+=1&call,set "_%n%=%%%%i!.%%i!%%"
)
if not defined _%n% set "_%n%=%a%"    
if defined code goto lp
for /l %%i in (1,1,%n%) do set /p=!_%%i!<nul
pause>nul
复制代码

测试格式为d/m m-y y,d y-y

terse

恩  可以试 DATE 改
不知道这样行得通否？

发现有错误  修改
复制代码

[ 本帖最后由 terse 于 2008-10-22 02:26 编辑 ]

随风

还有个办法就是通过改变系统日期来实现判断 月或日。

pusofalse

有变化的判断为日？
特意把日期改为10月1日后再运行，虽然也能正确输出。但“有变化的判断为日”这种说法是否不严谨？因为10月1日前一天是9月30日，月份也变化了。或许是我误解了。
------------------------------------------------------------------
明白了~只看到-1，没看到+1。

[ 本帖最后由 pusofalse 于 2008-10-21 23:49 编辑 ]

terse

这个问题用纯P 有点复杂了
因为毕竟要考虑日期格式的全面性 虽然有的格式并不会出现
就象 我开始问的  2008-01-03 也可以说是一月三号  也可以理解三月一号
我上面的代码 就是取得当天日期的前一天或后一天 有变化的判断为日
判断YYYY的方法是大于4位 余下是年
期待完善版本了

pusofalse

VBS那里能知道个大概意思。lp1标签里的变量嵌套实在太经典了。
出这题的有一部分目的也在于熟悉“变量的嵌套”吧。