【出题】批处理给文本文件ab cd.txt每行前加上日期

随风

出题：给ab cd.txt每行前加上日期
已知：
   ab cd.txt 文件名含空格。（不能改文件名）
   ab cd.txt 行数不确定 （大约5万行左右），无空行，且不含特殊符号。
.
要求：
   1、给ab cd.txt每行前面加上日期，将结果写入 c.txt
   2、最后一行为当前日期，倒数第二行为昨天的日期，倒数第三行为前天的日期，依此类
推。。。。
   3、并在跨月份时插入空行。
   如：09月30日 和 10月01日 之间需插入一空行。

   2008年09月28日 为什么要学习批处理
   2008年09月29日 1.源自于批处理的简单
   2008年09月30日 我想没有多少人愿意花上一个月甚至更多的时间

   2008年10月01日 去绞尽脑汁的专门学习一个编程语言来写一个删除系统垃圾的程序，
   2008年10月02日 因为对于一个不是专门学习计算机或者将来从事这方面工作的人来说，
   2008年10月03日 这样的投入与产出实在是不值得的，
   2008年10月04日 而用我们的批处理只要几分钟就可以解决这个问题，
复制代码

代码要求：
  1、不产生临时文件
  2、用纯p解决。
  3、必须考虑跨年度、跨月份、及闰年的情况。
  4、代码运行耗时不能超过一分钟。
.
加分条件：
   1、效率高   +5
   2、代码简洁 +3
   3、满分    +10
.

假设ab cd.txt内容为：

为什么要学习批处理
1.源自于批处理的简单
我想没有多少人愿意花上一个月甚至更多的时间
去绞尽脑汁的专门学习一个编程语言来写一个删除系统垃圾的程序，
因为对于一个不是专门学习计算机或者将来从事这方面工作的人来说，
这样的投入与产出实在是不值得的，
而用我们的批处理只要几分钟就可以解决这个问题，
这样的方便性让任何对计算机望而生畏的人来说是多么的有吸引力。 
2.通过批处理的编写，会逐渐的熟悉windows操作系统的一些细节问题，
仅此一点就能让你在众多菜鸟中脱颖而出。 
3.通过diy自己的“程序”让自己有种成就感，
这种感觉绝对不是使用别人的工具所能言语的，
自己能写出来东西就是对自己最好的证明。 
4.强大性，baidu，google里不可能搜索到能帮你解决掉所有问题的程序，
如果你不会写那些.exe程序，
那么你要完成你的目标可能就要花些银子让一些软件工作室帮你写咯。
其实决大部分系统的问题，.bat都可以轻松的帮你解决掉了。 
说了这么多，到底为什么要学习批处理就是很简单的一句话： 
程序是写出来满足绝大部分人的，而批处理是满足我们自己的。 
每个拥有计算机和懂计算机的人都应该学习批处理。 
因为世界上任何一个人都能通过简单的学习掌握批处理这门“编程语言” 
复制代码

假设当前日期为： 2008年10月18日
要求 c.txt 结果如下：

2008年09月28日 为什么要学习批处理
2008年09月29日 1.源自于批处理的简单
2008年09月30日 我想没有多少人愿意花上一个月甚至更多的时间

2008年10月01日 去绞尽脑汁的专门学习一个编程语言来写一个删除系统垃圾的程序，
2008年10月02日 因为对于一个不是专门学习计算机或者将来从事这方面工作的人来说，
2008年10月03日 这样的投入与产出实在是不值得的，
2008年10月04日 而用我们的批处理只要几分钟就可以解决这个问题，
2008年10月05日 这样的方便性让任何对计算机望而生畏的人来说是多么的有吸引力。 
2008年10月06日 2.通过批处理的编写，会逐渐的熟悉windows操作系统的一些细节问题，
2008年10月07日 仅此一点就能让你在众多菜鸟中脱颖而出。 
2008年10月08日 3.通过diy自己的“程序”让自己有种成就感，
2008年10月09日 这种感觉绝对不是使用别人的工具所能言语的，
2008年10月10日 自己能写出来东西就是对自己最好的证明。 
2008年10月11日 4.强大性，baidu，google里不可能搜索到能帮你解决掉所有问题的程序，
2008年10月12日 如果你不会写那些.exe程序，
2008年10月13日 那么你要完成你的目标可能就要花些银子让一些软件工作室帮你写咯。
2008年10月14日 其实决大部分系统的问题，.bat都可以轻松的帮你解决掉了。 
2008年10月15日 说了这么多，到底为什么要学习批处理就是很简单的一句话： 
2008年10月16日 程序是写出来满足绝大部分人的，而批处理是满足我们自己的。 
2008年10月17日 每个拥有计算机和懂计算机的人都应该学习批处理。 
2008年10月18日 因为世界上任何一个人都能通过简单的学习掌握批处理这门“编程语言” 
复制代码

[ 本帖最后由 随风 于 2008-10-18 22:33 编辑 ]

wzyqwdl

2008-11-5号  23：18分左右测试的，
CPU ：AMD 双核3800+
内存：2G DDR2

估计剩下的就和操作系统有关了。（我先前用计算π 的软件弄的机器很卡。）
应该和内存没什么关系了吧？
顺便新手来报道下，各位 午夜好。
[attach]1494[/attach]

terse

pusofalse

我512M内存，1.6G双核CPU，机器配置也不怎么样。
测试最长的耗时时间正好是8秒。
这次测试结果：

随风

看代码真是累，若想完全看懂各位的代码太需要时间了。
略看了一下，发现大家都忽略了一个问题，就是代码中for循环时你们都用了 call  命令
5万行，即使只运行10分之一次，效率也是会被明显拖慢的。
在庞大的数据面前，即使是 set str=!str:~-2! 这样的语句都会对效率有一定影响。
另外：pusofalse 测试真的是7秒吗？
    我测试最好的都是 13 秒，难道真的和电脑有这么大的关系？
    各位测试的结果也贴出来看看好吗/？

[ 本帖最后由 随风 于 2008-10-20 17:58 编辑 ]

pusofalse

简直无敌了，测试随风兄的代码：

随风

::递加日期，以处理5万行的文本为例
::本机测试   耗时： 0 小时 0 分钟 14 秒 72 毫秒
::这次测试怎么都要14秒。。郁闷！难道是电脑不同的原因？
代码效率关键是，for 内部运行的命令越少越好。
:

@echo off&setlocal enabledelayedexpansion
set ttime=%time%&set wjm=ab cd.txt
for /f "tokens=2 delims=:" %%a in ('find /v /c "" "%wjm%"') do set /a tian=%%a-1
call :Date2Day "%date:~0,10%" %tian% sy sm sd
echo  %tian% 天前的日期是：%sy%年%sm%月%sd%日
set /a sm+=100,sd+=100,n=100,yue113=131
for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set /a n+=1&set /a yue!n!=1%%a
set /a yue102="^!(sy%%4)&^!(^!(sy%%100))|^!(sy%%400)+128",py=yue!sm!
echo.1>nul 3>c.txt
for /f "usebackq delims=" %%a in ("%wjm%") do (
   echo !sy!年!sm:~-2!月!sd:~-2!日 %%a
   set /a sd+=1
   if !sd! gtr !py! (
     set /a sd=101,sm+=1&set /a py=yue!sm!&echo.
     if !sm! gtr 112 (
        set /a sy+=1,sm=101,yue102="^!(sy%%4)&^!(^!(sy%%100))|^!(sy%%400)+128"
)))

echo.1>nul 4>con
call :time0 "%ttime%" "%time%" ok
echo  耗时： %ok%&title ok
echo.&pause
start notepad "c.txt"&exit  

:Date2Day 获取指定天数的日期 （封装）
setlocal&rem by Will Sort @cn-dos
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%~1') do (
set /a yy=%%a,mm=100%%b%%100,dd=100%%c%%100)
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
set /a i=j-%~2,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
endlocal&set %3=%yy%&set %4=%mm%&set %5=%dd%&goto :EOF

:time0  计算批处理运行时间（封装）
setlocal&set /a n=0&rem by 随风 @bbs.bathome.net
for /f "tokens=1-8 delims=.: " %%a in ("%~1:%~2") do (
set /a n+=10%%a%%100*360000+10%%b%%100*6000+10%%c%%100*100+10%%d%%100
set /a n-=10%%e%%100*360000+10%%f%%100*6000+10%%g%%100*100+10%%h%%100)
set /a s=n/360000,n=n%%360000,f=n/6000,n=n%%6000,m=n/100,n=n%%100
set "ok=%s% 小时 %f% 分钟 %m% 秒 %n% 毫秒"
endlocal&set "%~3=%ok:-=%"&goto :eof
复制代码

[ 本帖最后由 随风 于 2008-10-20 17:04 编辑 ]

pusofalse

@echo off&setlocal enabledelayedexpansion
cd.>c.txt
echo %time%
for %%a in (1 3 5 7 8 10 12) do set _%%a=31
for %%a in (4 6 9 11) do set _%%a=30
for /f "tokens=1-3 delims=- " %%a in ("%date%") do set/a "Year=%%a,Month=100%%b%%100,Day=100%%c%%100+1"
for /f "delims=:" %%a in ('findstr /n /v $ "ab cd.txt"') do set /a "Line=%%a,Feb=28+^!(year%%4)"
set "Monthes=1#31 2#%Feb% 3#31 4#30 5#31 6#30 7#31 8#31 9#30 10#31 11#30 12#31"
for %%i in (%Monthes%) do for /f "tokens=1,2 delims=#" %%a in ("%%i") do if %%a leq %Month% set /a DayCount+=%%b
for /f "tokens=%month%" %%a in ("%Monthes%") do for /f "tokens=1,2 delims=#" %%i in ("%%a") do set/a DayCount-=%%j-Day
set /a LineTemp=Line-DayCount
:loop
set/a "LineTemp-=365+(^!(year%%4)&^!(^!(year%%100))|^!(year%%400)),Year-=1"
if %LineTemp% geq 365 goto loop
set/a "Year-=1,Month=12,Feb=28+^!(Year%%4)"
:loop1
if %LineTemp% gtr !_%Month%! (
   for /f "tokens=%Month%" %%a in ("1#31 2#%Feb% 3#31 4#30 5#31 6#30 7#31 8#31 9#30 10#31 11#30 12#31") do (
        for /f "tokens=1,2 delims=#" %%i in ("%%a") do set/a LineTemp-=%%j
        set/a month-=1&goto loop1
))
set /a Day=_%Month%-LineTemp
for /f "usebackq delims=" %%a in ("ab cd.txt") do (
      if !Month! lss 10 (set "Mon=0!Month!") else (set "Mon=!Month!")
      if !Day! lss 10 (set "Da=0!Day!") else (set "Da=!Day!")
      echo !Year!年!Mon!月!Da!日 %%a
      set/a Day+=1
      if !Day! GTR 28 CALL :MonitorMonthCount
)>>c.txt
echo %time%
pause>nul&exit/b
:MonitorMonthCount
if %day% gtr !_%month%! set/a "day=1,month+=1"&echo.
if !month! equ 13 set /a "month=1,year+=1,_2=28+(^!(year%%4)&^!(^!(year%%100)) | ^!(year%%400))"
复制代码

钻了一个空子，用findstr /n /v $ "ab cd.txt"来计算行数，当然最末行不能是空行。

batman

下面是我对自己16楼代码的测试结果：

但13秒多的速度，确实让人期待。。。

terse

原帖由 随风 于 2008-10-20 15:09 发表
呵呵，对效率的考验。。
各位都出了精彩的代码了。
暂时没时间细看代码，下回去慢慢看。。。
初步做了下测试。


16楼 batman 耗时 0 小时 1 分钟 5 秒 31 毫秒

14楼 rat 耗时 0 小时 0 分钟 57 秒 40 毫秒 ...

13秒的处理 真高效
说实话 我想尽办法也没有让代码的效率的提高
我想我的以年递减 在确定日期方面一个也快的了
就是递加和判断方面  我想是少不了一条一条判断的
期待 随风兄的精彩代码

随风

呵呵，对效率的考验。。
各位都出了精彩的代码了。
暂时没时间细看代码，下回去慢慢看。。。
初步做了下测试。


16楼 batman 耗时 0 小时 1 分钟 5 秒 31 毫秒

14楼 rat 耗时 0 小时 0 分钟 57 秒 40 毫秒

12楼 terse 耗时 0 小时 1 分钟 7 秒 75 毫秒

本人目前的代码 耗时： 0 小时 0 分钟 13 秒 72 毫秒
代码在U盘，下次发出来。

其实思路很简单，先获取总行数，并得到N 天前的日期。再逐日递加日期。

batman

终于将效率问题解决了，但代码确实难读了。。。
说明一下：先计算出文本的总行数，然后用渐近法计算出第一个日期（先算年再算月和日）
，然后再用for在按行读取数据时进行日期的累加和输出到新文本。

@echo off&setlocal enabledelayedexpansion
set "t=%time%"&echo.>c.txt
rem 提出当前的年月日数值
set /a year=%date:~,4%,month=1%date:~5,2%%%100,day=1%date:~8,2%%%100
rem 设置变量
for %%i in (31 29 31 30 31 30 31 31 30 31 30 31) do (
    set /a num+=1&set "_!num!=%%i"
    set "code1=!code1! %%i"&set "code2=!code2! !num!#%%i"
)
rem 获取文本总行数
for /f "usebackq delims=" %%i in ("ab cd.txt") do set /a n+=1
rem 计算并减去本年已过的天数
set /a n=n-day
for %%a in (%code1%) do (
    if "!m!" neq "%month%" (
       set /a n-=%%a,m+=1
       ) else ( 
       goto lp1
   )
)
:lp1
rem 计算初始年份
set /a year-=1,n-=365
set /a a=year%%4,b=year%%100,c=year%%400,yun=28,_2=28
if %b% equ 0 (
   if %c% equ 0 set /a n-=1,yun+=1,_2+=1
   ) else (
   if %a% equ 0 set /a n-=1,yun+=1,_2+=1
)
if %n% geq 0 goto lp1
set "code1=!code1:29=%yun%!"&set "code2=!code2:29=%yun%!"
rem 计算初始月份和日期
for %%a in (%code2%) do (
    for /f "tokens=1,2 delims=#" %%i in ("%%a") do (
        set /a n+=%%j
        if !n! geq 0 set /a month=%%i-1,day=%%j-n&goto next
    )
)
:next
rem 核心代码部分，读取文本内容并递加日期，输出到新文本
for /f "usebackq delims=" %%i in ("ab cd.txt") do (
    set /a n=day-_!month!
    if !n! gtr 0 call :lp2
    if !month! geq 10 (
       if !day! geq 10 ( 
          echo !year!年!month!月!day!日 %%i>>c.txt
          ) else (
          echo !year!年!month!月0!day!日 %%i>>c.txt
       )
       ) else (
       if !day! geq 10 (
          echo !year!年0!month!月!day!日 %%i>>c.txt
          ) else (
          echo !year!年0!month!月0!day!日 %%i>>c.txt
       )
    )
    set /a day+=1
)
echo 开始时间：%t% 
echo 结束时间：%time%
pause>nul&goto :eof
:lp2
rem 子程序：跨月、跨年的计算和判断
echo.>>c.txt
set /a month+=1,day=1
if %month% equ 13 (
   set /a year+=1,month=1,a=year%%4,b=year%%100,c=year%%400,_2=28
   if !b! equ 0 (
      if !c! equ 0 set "_2=29"
      ) else (
      if !a! equ 0 set "_2=29"
   )
)
复制代码

[ 本帖最后由 batman 于 2008-10-20 03:40 编辑 ]

terse

原帖由 batman 于 2008-10-19 19:40 发表
看了这段代码，人都要晕了。。。。我也想过用这种方法，但这样效率肯定是上不去的，因
为这样要进行100000次日期计算，其中还要进行很多次的判断，但另一种平常好用的设置
变量法实践中效率更低（变量数量太大了） ...

其实没有进行100000次日期计算  假设50000行 就是50000次运算啊  其中判断少不了的

rat

@echo %time%

@echo off & setlocal enabledelayedexpansion
set sOldFile="ab cd.txt"
set sNewFile="c.txt"

for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set /a i += 1 && set iM!i!=%%a
for /f "tokens=1-3 delims=-" %%a in ("%date%") do set iThisYear=%%a & set iThisMonth=%%b & set iThisDay=%%c
set /a iLeapYearCount = (iThisYear - 1) / 4 - (iThisYear - 1) / 100 + (iThisYear - 1) / 400
call :GetFebDayCount %iThisYear% iM2
for /l %%a in (1, 1, %iThisMonth%) do if %%a lss %iThisMonth% set /a iThisMonthToDayCount += iM%%a
set /a iAllDayCount = 365 * (iThisYear - 1) + iLeapYearCount + iThisMonthToDayCount + iThisDay

for /f "usebackq delims=" %%a in (%sOldFile%) do set /a iDayDiff += 1
set /a iFirstDayCount = iAllDayCount - (iDayDiff - 1)
set /a iTempYear = iFirstDayCount / 365 - 1
:GetDate
set /a iTempLeapCount = iTempYear / 4 - iTempYear / 100 + iTempYear / 400
set /a iTempDayCount = iFirstDayCount - 365 * iTempYear - iTempLeapCount
if %iTempDayCount% lss 0 set /a iTempYear -= 1 && goto :GetDate
if %iTempDayCount% equ 0 set /a iYear = iTempYear, iMonth = 12, iDay = 31 && goto :WriteText
set /a iYear = iTempYear + 1
call :GetFebDayCount %iYear% iM2
for /l %%a in (1, 1, 12) do (
	set /a iTempDayCount -= iM%%a
	if !iTempDayCount! leq 0 set /a iMonth = %%a, iDay = iM%%a + iTempDayCount, iTempDay = iM%%a && goto :WriteText
)

:WriteText
cd.>%sNewFile%
for /f "usebackq delims=" %%a in (%sOldFile%) do (
	if !iMonth! lss 10 (set sMonth=0!iMonth!) else (set sMonth=!iMonth!)
	if !iDay! lss 10 (set sDay=0!iDay!) else (set sDay=!iDay!)
	>>%sNewFile% echo !iYear!年!sMonth!月!sDay!日 %%a
	if !iDay! lss !iTempDay! (
		set /a iDay += 1
	) else (
		>>%sNewFile% echo.
		if !iMonth! lss 12 (
			set /a iMonth += 1, iDay = 1
		) else (
			set /a iYear += 1, iMonth = 1, iDay = 1
			call :GetFebDayCount !iYear! iM2
		)
		set /a iTempDay = iM!iMonth!
	)		
)

echo %time%

pause
exit /b



:GetFebDayCount
for %%a in (4 100 400) do set /a r%%a=%1%%%%a
set %2=28
if %r400%==0 (set %2=29) else (if %r4%==0 if not %r100%==0 set %2=29)
复制代码

[ 本帖最后由 rat 于 2008-10-20 16:55 编辑 ]

batman

看了这段代码，人都要晕了。。。。我也想过用这种方法，但这样效率肯定是上不去的，因
为这样要进行100000次日期计算，其中还要进行很多次的判断，但另一种平常好用的设置
变量法实践中效率更低（变量数量太大了），所以一直未能达到小楼兄的要求。。。
用kip的方法可以将文本未行变成首行，但输出就整个是反过来的，即当前日期和未行成了第
一行，再用一次skip就可以按要求输出了，但这样既显得罗索，效率也达不到一分左右完成
这一要求，同时可能还要生成一次临时文件。。。
期待小楼兄的答案。。。