pusofalse

@echo off
set/p file=请把要处理的文件拖到此处：
for /f "delims=" %%a in ("%file:"=%") do (
     md "%%~na"
     split -a 3 -b 100k "%file:"=%" "%%~na\%%~na_"
     ren "%%~na\*" "*.txt"
)
pause
复制代码

借助了第三方工具split.exe，用最合适的代码做最合适的事情吧。
请先下载3楼提供的下载链接，再运行此批处理。

pusofalse

三楼BATCHER兄提供的链接中的split.exe没有-a参数，版本问题。。。
使用以下代码：

@echo off
set/p file=请把要处理的文件拖到此处：
for /f "delims=" %%a in ("%file:"=%") do (
     md "%%~na"
     split  -b 100k "%file:"=%" "%%~na\%%~na_"
     ren "%%~na\*" "*.txt"
)
pause
复制代码

pusofalse

不知这样可否：
第一个文件的尾部（最后出现的一个全角句号或问号到全文结束）会出现在第二个文件的头部。即：这段文本信息即出现在第一个文件中（尾部），也出现在第二个文本中（头部）。不过借助了两个第三方工具split.exe wfr.exe

@echo off
:loop
setlocal enabledelayedexpansion
set/p file=请把要处理的文件拖到此处：
for /f "delims=" %%a in ("%file:"=%") do (
     md "%%~na"
     split  -b 100k "%file:"=%" "%%~na\%%~na_"
     ren "%%~na\*" "*.txt"
     set "name=%%~na"
)
for /f "delims=" %%a in ('dir /b /s /on "%name%\*.txt"') do set/a n+=1&set "_!n!=%%a"
set/a n-=1
for /l %%i in (1 1 %n%) do (
     set/a x=%%i+1
     type "!_%%i!"|wfr /exp /r:"[\r\n]" /t|wfr /exp /r:".*[。？]" /t>"%name%\tmp.txt"
     (type "%name%\tmp.txt"&echo.&call,type "%%_!x!%%")>"%name%\tmp.tmp"
     call,move /y "%name%\tmp.tmp" "%%_!x!%%"
) 
del "%name%\tmp.txt"
endlocal
pause
复制代码

wfr.exe下载：http://bbs.bathome.net/thread-1909-1-2.html
从第二个文件开始，大小会大于100k。
先下载split.exe wfr.exe 放到此批处理所在目录中OK。

[ 本帖最后由 pusofalse 于 2008-10-9 22:07 编辑 ]

pusofalse

去掉了wfr.exe 只用SPLIT.EXE。应该可以了。

@echo off
:loop
setlocal enabledelayedexpansion
set/p file=请把要处理的文件拖到此处：
for /f "delims=" %%a in ("%file:"=%") do (
     md "%%~na"
     split -b 99k "%file:"=%" "%%~na\%%~na_"
     ren "%%~na\*" "*.txt"
     set "name=%%~na"
)
for /f "delims=" %%a in ('dir /b /s /on "%name%\*.txt"') do set/a n+=1&set "_!n!=%%a"
set/a n-=1
for /l %%i in (1 1 %n%) do (
     set/a x=%%i+1
     findstr /v $ "!_%%i!">tmp&findstr $ "!_%%i!">tmp1
     move /y tmp1 "!_%%i!"
     (type tmp&echo.&call type "%%_!x!%%")>tmp2
     call,move /y tmp2 "%%_!x!%%"
)
del tmp
endlocal
pause
复制代码

pusofalse

也发现了如此的问题，应该是是split.exe的BUG。对此无能为力~