[游戏娱乐] 批处理随机游动粒子

523066680

也在cn-dos发表:http://www.cn-dos.net/forum/viewthread.php?tid=43059&sid=GXasLb

@echo off
setlocal enabledelayedexpansion
mode con cols=60 lines=30
for /l %%a in (1,1,60) do (set space= !space!)
set /a line=14,col=29
:loop
 set /a linenext=%random%%%30
 set /a colnext=%random%%%60
 for %%a in (line col) do (
   if !%%a! lss !%%anext! (set %%aadd=+) else (set %%aadd=-)
 )
   :loop-1
    if %line% neq %linenext% (
        set /a line%lineadd%=1
    ) else (
        set /a col%coladd%=1
    )
    cls
    for /l %%a in (1,1,%line%) do echo,
    echo,!space:~0,%col%!*
    for /l %%a in (1,1,200) do (echo,>nul)
   if %col% neq %colnext% (goto :loop-1)
goto :loop
复制代码

523066680

一个小虫子

@echo off
title made by 523066680
setlocal enabledelayedexpansion
mode con cols=61 lines=31
for /l %%a in (1,1,60) do (set space= !space!)
for /l %%a in (1,1,30) do (set L%%a=%space%)
set /a line=15,col=29,i=0
:loop
set /a linenext=%random%%%30+1,colnext=%random%%%60
for %%a in (line col) do (
   if !%%a! lss !%%anext! (set %%aadd=+) else (set %%aadd=-)
)
   :loop-1
       if %i% lss 20 (set /a i+=1) else (set i=1)
       if defined cut%i% (
               !cut%i%:"=!
               set "L%a%=!L%a%:~0,%b%! !L%a%:~%c%!"
       )
    set /a C2=col+1
    set "L%line%=!L%line%:~0,%col%!*!L%line%:~%C2%!"
    set cut%i%="set /a a=%line%,b=%col%,c=%C2%"
    cls
    for /l %%a in (1,1,30) do echo,!L%%a!
    for /l %%a in (1,1,300) do (echo,>nul)
    if %line% neq %linenext% (
        set /a line%lineadd%=1
    ) else (
        set /a col%coladd%=1
    )
   if %col% neq %colnext% (goto :loop-1)
goto :loop
复制代码

[ 本帖最后由 523066680 于 2008-10-1 08:22 编辑 ]

523066680

不过一楼的思路和代码我都精简过哦 发现没有

523066680

贪吃蛇这种想法是从开始就有的，随机游动粒子是制作的一个阶段。
我不想说出来，要是最后没有完成就不好了

523066680

这个就技术拉……  可能是要先设置好位置
记下坐标   应该可以做到  但是代码应该蛮繁杂的
我不干这个……觉得很复杂