[文本处理] CrLf 文本新增行批处理不能显示新增行内容

wh1234567

@echo off

::这里是先统计原文本总行数
set outfile=文本.txt
for /f "delims=" %%i in (%outfile%) do (
echo %%i>nul
set /a a1=a1+1
)

::这里是追加内容命令例子
echo ============%date:~4% %time:~0,-3%============ >>%outfile%
echo 开始vcbcv232 大飞梭 城市的称得上nnv 序列2001年 >>%outfile%

::这里是统计当前文本总行数并计算差值和显示新增行内容、新增行数
for /f "delims=" %%i in (%outfile%) do (
echo %%i>nul
set /a b1=b1+1
)
echo.
echo 新增行内容：
set /a new=b1-a1
if %%a neq %%b (
        more +%b1% %outfile%&&echo 新增%new%行
) 2>nul


pause
复制代码

为什么只能计算出新增%new%行，而不能显示新增行内容？哪里出错了？
%outfile%这个咋写，是不是缺少代码

wh1234567

就是运行批处理后，先统计原文本内容行数，再进行追加行，最后再统计新增加的行内容和新增加的行数

lllsoslll

@echo off
for /f %%a in ('type a.txt^|find /c /v ""')do set old=%%a
echo %date%>>a.txt
echo %time%>>a.txt
more +%old% a.txt
pause
复制代码

wh1234567

回复 3# lllsoslll

能显示新增加的行内容，能不能再增加个显示新增加的行数的代码

apang

@echo off
::这里是先统计原文本总行数，包括空行
set outfile=1.txt
for /f "delims=:" %%i in ('findstr /n .* %outfile%') do set/a a1+=1

::这里是追加内容命令例子
(for /f "tokens=1* delims=:" %%i in ('findstr /n .* %outfile%') do echo,%%j
echo ============%date:~4% %time:~0,-3%============ 
echo 开始vcbcv232 大飞梭 城市的称得上nnv 序列2001年)>$
move $ %outfile%>nul

::这里是统计当前文本总行数并计算差值和显示新增行内容、新增行数
for /f "delims=:" %%i in ('findstr /n .* %outfile%') do set/a b1+=1
echo 新增行内容：
set/a new=b1-a1
if %a1% neq %b1% (more +%a1% %outfile%&&echo 新增%new%行) 2>nul
pause
复制代码