caruko

楼上是字符插入的方法啊。

CrLf

【该思路已有先例，523066680较早提出】
我认为for嵌套递归始终是最快的方案，所以构思了一个基于for /l递归的新思路，唯一的缺陷是for嵌套理论上限62层[A-Za-z0-9]，本代码由于作者偷懒，功能不够强大，仅兼容低于10层，而且不能有重复项...

@echo off&setlocal enabledelayedexpansion
set str= a b c d e f g
set t=%time%
for %%a in (%str%) do (
	set /a n+=1,"tmp+=^!tmp"
	set "echo=%%!n! !echo!"
)
::初始化
set "for=for /f %%1 in ("^^!tmp1:%%2 =^^!") do (set /a z+=1)&echo %echo%"
for /l %%a in (2 1 %n%) do (
	set /a last=%%a-1
	set "for=for %%%%a in (^!tmp%%a^!) do ((set tmp!last!=^!tmp%%a: %%%%a = ^!)&!for!)"
)
::为str构建相应层数的for嵌套
set tmp%n%=%str% 
%for%
::执行组装而成的for嵌套
echo 共有%z%种组合 开始于%t% 结束于%time%
pause
复制代码

wankoilz

既然老帖被挖出来了，俺也来凑热闹。
支持重复字符，我这里测试8个字母40320种组合耗时近4秒：

@echo off&setlocal enabledelayedexpansion
set/p s=请输入，用一个空格分开:
echo %time%
set f1=a.txt
set f2=b.txt
>!f1! echo !s:~,1!&set s=!s:~1!
set len=1
for %%a in (%s%) do (
    (for /f %%b in (!f1!) do (
        set tmp=%%b
        for /l %%c in (0,1,!len!) do echo !tmp:~,%%c!%%a!tmp:~%%c!
    ))>!f2!
    set t=!f1!
    set f1=!f2!
    set f2=!t!
    set/a len+=1
)
echo %time%
start %f1%&del/f %f2%
pause
复制代码

caruko

效率还可以，但不支持重复字符。
7个字符，5040组合，用时不到15秒。

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION
set "str=a b c d e f g"
set time1=!time!
for %%i in (%str%) do (
    set /a n+=1,_%%i=n
)
echo, !str!
for /l %%a in (1,1,10000000) do (
    set "last="&set "flag="&set "pos=0"
    for %%b in (!str!) do (
        set /a pos+=1
        if defined last (
            set /a n1=_%%b,n2=_!last!
            if !n1! gtr !n2! set flag=!last! !pos!
            set "last=%%b"
        ) else (
            set "last=%%b"
        )
    )
    if not defined flag call :end %%a
    for /f %%b in ("!flag!") do for %%c in (!str!) do if !_%%c! gtr !_%%b! set "th=%%c"
    for /f "tokens=1,3" %%b in ("!flag! !th!") do (
        set "temp=!str:%%b=#!"
        set "temp=!temp:%%c=%%b!"
        set "str=!temp:#=%%c!"
    )
    set "ppos="&set "cut1="&set "cut2="&set "array="
    for %%b in (!str!) do (
        set /a ppos+=1
        for /f "tokens=2" %%c in ("!flag!") do (
            if !ppos! geq %%c (
                set "cut2=!cut2! %%b"
            ) else (
                set "cut1=!cut1! %%b"
            )
        )
    )
    for %%i in (!cut2!) do (
        set "array=%%i !array!"
        for %%j in (!array!) do (
            if %%i gtr %%j (
                set "array=!array:%%i=#!"
                set "array=!array:%%j=%%i!"
                set "array=!array:#=%%j!"
            )
        )
    )
    set str=!cut1! !array!
    echo,!str!
)
:end
echo,一共%1个排列. !time1!--^>!time!
pause>nul&exit
复制代码

pusofalse

terse前辈是不是输入空格了 abad 要这样的。

terse

想给多点分  怎么总是错误啊

batman

要生成个临时文件b.bat：

@echo off&setlocal enabledelayedexpansion
set /p num=请输入字符：
set "s=abcdefghijklnmopqrstuvwxyz"&set "nums=%num%"
:lp
set /a n+=1
set "str1=%str1% %n%"
set "ss=%ss%str%n%"&set "k=%k%)"
set "_%n%=%num:~,1%"&set "num=%num:~1%"
if defined num goto lp
echo ^@echo off^&setlocal enabledelayedexpansion>b.bat
for /f "skip=1 delims=" %%a in (%~fs0) do (
    set /a x+=1
    if !x! equ 9 goto loop
    if !x! equ 1 (
       echo set "num=%nums%">>b.bat
       ) else (
       if !x! neq 2 if !x! neq 6 echo %%a>>b.bat
    )
)
:loop
set "a=%%%%%s:~,1%"&set "b=%ss:~,4%"&set "c=%ss:~4,4%"
set "str=!str!^!_%a%^!"
if "%c%" equ "" set "c=flag"  
echo for %a% in (^^^!%b%^^^!) do (set "%c%=^!%b%:%a%=^!">>b.bat
set "s=%s:~1%"&set "ss=%ss:~4%"
if defined ss goto loop
echo echo !str!>>b.bat
echo %k%>>b.bat
echo pause^>nul>>b.bat
endlocal&b
复制代码

[ 本帖最后由 batman 于 2008-9-6 22:06 编辑 ]

523066680

哈哈 可以用来做概率题

terse

抛个砖  这样的处理效率肯定不是很高  后来者突破吧

@echo off&setlocal enabledelayedexpansion
set/p str=请输入(空格隔开)
for %%i in (!str!) do set/a n+=1&set !n!=%%i
    call:lp
    echo %mn% 个组合
    pause&exit
:lp
set/a m+=1
    if %m% leq %n% for /l %%i in (1 1 %n%) do (
    for %%j in (%~1) do set .%%j=%%j
    if not defined .%%i call :lp "%~1 %%i"
    for /l %%k in (1 1 %n%) do set .%%k=
    ) else (
    for /l %%l in (1 1 %n%) do set .%%l=
    for %%m in (%~1) do set/p=!%%m! <nul
    echo.
    set/a mn+=1
    )
    set/a m-=1
复制代码

pusofalse

这样的题用递归来做比较好些，否则用我这样的方法，还是一样只是穷举，而且不通用，太臃肿，4个字符只能再加一个for，若有5个字符就得用5个for。
完全是不通用的。

terse

原帖由 batman 于 2008-9-2 17:00 发表
一直觉得穷举法不是批处理的强项，尤其是在不知道有多少位数字或字母的情况下，更是难
以写出通用的代码，本人以前写过一个适用于9位内数字或字母排列的代码，实际上到了8位
就已经达到了效率的极限了。。。

穷举法确实不是批处理的强项  即便出一个通用的代码 也是效率的代价

terse

原帖由 pusofalse 于 2008-9-2 16:49 发表
@echo off&setlocal enabledelayedexpansion
set str=a b a
for %%a in (%str%) do set /a n+=1& set .!n!=%%a&set "var=!var!!n! "
for %%i in (!var!) do (
    set var1=!var:%%i=!
    for %%j in (!var1!) ...

输入4位  输出时少了一位
确切的是输入3位数上 输出仍输出3位

batman

一直觉得穷举法不是批处理的强项，尤其是在不知道有多少位数字或字母的情况下，更是难
以写出通用的代码，本人以前写过一个适用于9位内数字或字母排列的代码，实际上到了8位
就已经达到了效率的极限了。。。

pusofalse

@echo off&setlocal enabledelayedexpansion
set str=a b a
for %%a in (%str%) do set /a n+=1& set .!n!=%%a&set "var=!var!!n! "
for %%i in (!var!) do (
    set var1=!var:%%i=!
    for %%j in (!var1!) do (
    set var2=!var1:%%j=!
    for %%k in (!var2!) do (
    set/a flag+=1
    echo !.%%i! !.%%j! !.%%k!
    )))
    echo 共有%flag%个组合
pause
复制代码

terse

原帖由 pusofalse 于 2008-9-2 16:17 发表
有重复字符很简单啊。set var=a b c a b
for %%a in (%var%) do set/a nn+=1&set .!nn!=%%a
for /l %%a in (1 1 %nn%) do set "str=!str!%%a "
for %%i in (!str!) do (
....
....
echo !.%%i! !.%%j! !.%%k ...

啊？不会吧！
你的%%j  %%k 是预先写入的？前面虽然得到位数但 并没表示到%%K吧