[数值计算] 数字矩阵随机黑洞

batman

写下这段代码主要目的是让大家都了解下数值计算的相关技巧：

 @echo off
:begin
setlocal enabledelayedexpansion
cls&set "code= xy"
:again
set /a a=%random%%%7+2,b=%random%%%7+2,c=a-b
if %c:~-1% leq 1 goto again
set /a n+=1
if "%c:~,1%" equ "-" (
   set "!code:~%n%,1!min=%a%"&set "!code:~%n%,1!max=%b%"
   ) else (
   set "!code:~%n%,1!max=%a%"&set "!code:~%n%,1!min=%b%"
)
if %n% neq 2 goto again
for /l %%a in (%xmin%,1,%xmax%) do (
    for /l %%i in (%ymin%,1,%ymax%) do set "_%%a%%i=a"
)
for /l %%a in (1,1,9) do (
    for /l %%i in (1,1,9) do (
        set /a num+=1
        if !num! lss 10 set "num= !num!"
        if not defined _%%a%%i (
           set /p=!num! <nul
           ) else (
           set /p=   <nul
        )
    )
    echo.
)  
ping /n 2 127.1>nul&endlocal&goto begin
复制代码

[ 本帖最后由 batman 于 2008-8-28 22:53 编辑 ]

flyinspace

@echo off & setlocal EnableDelayedExpansion
        mode con:cols=100 lines=100
echo.
echo 利用批处理绘制圆形，BETA 1.00 版。2008年8月10日编译完成。
echo.
echo ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
        set "DrawPoint=○"
        set "Radius=19"
        set /a "Square=%Radius%*%Radius%"
        set /a "Diameter=%Radius%*2"
        set "Interval=  "
        set /a "y=%Diameter%"
        set /a "x=0"
        set /a "ADD=15"
        set /a "Area1=%Square%+%ADD%"
        set /a "Area2=%Square%-%ADD%"
        for /l %%i in (%Diameter%,-1,0) do Call :Draw_Point "%%i"
        goto :End
:Draw_Point _y_
        set "Line=┃"
        for /l %%i in (0,1,%Diameter%) do (
                call :Compute_Deuce_Length "%%i" "%1"
                call :Draw_Line "!CResult!"
                )
        echo %Line%┃
        goto :EOF
:Draw_Line _rst_
        set "res=%~1"
        if '%res% LSS %Area2%' (
                set "Line=%Line%%Interval%"
                goto :EOF
                )
        if '%res% GTR %Area1%' (
                set "Line=%Line%%Interval%"
                goto :EOF
                )
        set "Line=%Line%%DrawPoint%"
        goto :EOF
:Compute_Deuce_Length _x_ _y_
        set "Cx=%~1"
        set "Cy=%~2"
        if "%Cx%" LEQ "%Radius%" (
                set /a "Factor1=%Radius%-%Cx%"
                ) else (
                set /a "Factor1=%Cx%-%Radius%"
                )
        if "%Cy%" LEQ "%Radius%" (
                set /a "Factor2=%Radius%-%Cy%"
                ) else (
                set /a "Factor2=%Cy%-%Radius%"
                )
        set /a "Factor1=%Factor1%*%Factor1%"
        set /a "Factor2=%Factor2%*%Factor2%"
        set /a "CResult=%Factor1%+%Factor2%"
        goto :EOF
:End
echo ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
echo.
echo 本演示由 Flyinspace 发表于 http://www.cn-dos.net/forum ，转载请注明.
pause>nul
复制代码

[ 本帖最后由 pusofalse 于 2008-8-29 00:16 编辑 ]

batman

效率上存在问题，感觉还可简洁点。。。