[文本处理] [已解决]批处理怎样改变文件字符串排列？

iotalinen

有一批 *.txt 或 *.asc   文件，每个文件 内容大致相同
例如   2.000000.00.0-2.00000123456.123456654321.654321
修改为  

2.00
0.0
0.0
-2.00
123456.123
654321.654

补充
1、每个文件，各部分相关内容的字符串长度是固定，也就是说，可拆开看做    2.00000   0.0    0.0   -2.00000   123456.123456   654321.654321
2、当然，可能文件不一定是上面举例字符个数，所以，可以这样处理，就是  从第几个字符开始 到第几字符结束 作为一行， 再从第几个字符到几个字符再一行。

ArdentMan

@Echo Off&SetLocal EnableDelayedExpansion
For %%a In (*.txt *.csv) Do (
  (For /F %%b In (%%a) Do (
    Set "Str=%%b"
    Echo !Str:~,4!
    Echo !Str:~4,3!
    Echo !Str:~7,3!
    Echo !Str:~10,4!
    Echo !Str:~14,10!
    Echo !Str:~-10!
  ))>$
  move $ %%a
)
复制代码

iotalinen

怎么没有效果啊
只是多了个名称为  “$”   文件  也没有后缀，0KB 大小

iotalinen

@Echo Off&SetLocal EnableDelayedExpansion
For %%a In (1.txt) Do (
  (For /F %%b In (%%a) Do (
    Set "Str=%%b"
    Echo !Str:~,4!
    Echo !Str:~7,3!
    Echo !Str:~10,3!
    Echo !Str:~13,5!
    Echo !Str:~21,10!
    Echo !Str:~34,10!
  ))>$
  move $ %%a
)
复制代码

我又细琢磨了一下，试了一下，将原文件 改为 “1.txt”  并把 原来代码的 For %%a In (1.txt) Do (     改为       For %%a In (1.txt) Do (
（ 其余的只是改了一下具体截取字段的位置，小问题而已）
然后就可以执行了，将  “1.txt”  这一个文件 修改为我原来希望的效果

所以，问题是，我如果有一批呢， “1.txt”  “2.txt”  “3.txt” 呢，还是说  我没有搞懂  ArdentMan 上尉的代码呢

find

回复 4# iotalinen

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    (for /f %%b in (%%a) do (
        set "str=%%b"
        echo !str:~,4!
        echo !str:~4,3!
        echo !str:~7,3!
        echo !str:~10,4!
        echo !str:~14,10!
        echo !str:~-10!
    ))>$
    move $ %%a.new
)
复制代码

iotalinen

哈哈哈
问题解决了，感谢ArdentMan 上尉  感谢 find  大校

其实 ArdentMan 上尉 的代码是好的，只是我试验的时候偷懒，新建的文本是 “ 新建 文本文档.txt” 中间有空格，所以没有执行。
find  大校  代码  相当于为我 提供了一个做备份的 考虑，  感谢啊。
个位 高手若有兴趣 可否 解释一下  文件命名有空格，致使代码没有执行的原因啊。

apang

回复 6# iotalinen

如果文件名含有空格，可以写成这样的形式：

for /f "usebackq" %%b in ("%%a") do (...)
复制代码

或者

for /f  %%b in ('type "%%a"') do (...)
复制代码

find

回复 6# iotalinen

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    (for /f "usebackq" %%b in ("%%a") do (
        set "str=%%b"
        echo !str:~,4!
        echo !str:~4,3!
        echo !str:~7,3!
        echo !str:~10,4!
        echo !str:~14,10!
        echo !str:~-10!
    ))>$
    move $ "%%a.new"
)
复制代码

iotalinen

十分感谢

代码实验执行成功

感谢
ArdentMan 上尉
find  大校
apang 上尉