[原创] 批处理命令连接符号优先级证明

qzwqzw

@echo off
echo.
echo.    已经确认命令连接符号优先级从低到高如下：
echo.            ^&       	命令分隔符
echo.            ^|^|          逻辑或操作符
echo.            ^&^&          逻辑与操作符
echo.            ^|           管道操作符
echo.            ^< ^> ^>^>      I/O重定向操作符
echo.            ^(^)          命令分组
echo.
echo.证明过程如下：
pause
echo.
echo.  首先应当公认^(和^)作为命令分组符号有最高的优先级，可以改变任意命令组的优先级
echo.
echo.  另外需要注意的是，命令连接符号的优先级与语句的执行顺序不是直接对应的
echo.
echo.  命令行中的语句仍然是先执行左侧，再执行右侧
echo.
echo.  命令连接符只影响左侧与右侧语句的分组过程，而不会使右侧语句先执行
echo.
pause
cls
echo on
echo flag1 | echo flag2 > con
echo flag1 | (echo flag2 > con)
(echo flag1 | echo flag2) > con
@echo off
echo.
echo.前两句输出效果相同，说明第二句的分组符号可以省略，证明 ^> 优先级大于 ^|
pause

cls
echo on
echo flag1 && echo flag2 | echo flag3
echo flag1 && (echo flag2 | echo flag3)
(echo flag1 && echo flag2) | echo flag3
@echo off
echo.
echo.前两句输出效果相同，说明第二句的分组符号可以省略，证明 ^| 优先级大于 ^&^&
pause

cls
echo on
echo flag1 || echo flag2 && echo flag3
echo flag1 || (echo flag2 && echo flag3)
(echo flag1 || echo flag2) && echo flag3
@echo off
echo.
echo.前两句输出效果相同，说明第二句的分组符号可以省略，证明 ^&^& 优先级大于 ^|^|
pause

cls
echo on
echo flag1 || echo flag2 & echo flag3
(echo flag1 || echo flag2) & echo flag3
echo flag1 || (echo flag2 & echo flag3)
@echo off
echo.
echo.前两句输出效果相同，说明第二句的分组符号可以省略，证明 ^|^| 优先级大于 ^&
pause

cls
echo.综合测试示例：
echo.
echo on
echo flag1 & more flag2 || echo flag3 && echo flag4 | echo flag5 || echo flag6
echo flag1 & ((more flag2 || (echo flag3 && (echo flag4 | echo flag5))) || echo flag6)
(echo flag1 & (more flag2 || (echo flag3 && echo flag4) | echo flag5)) || echo flag6
@echo off
echo.
echo.前两句输出效果相同，说明符合优先级和分组优先级相同，第三句是个反例
pause
复制代码

qzwqzw

实际上那两个字符就是你的ID的“原形”
用这种方法还能显示出0x08 0x09等字符

qzwqzw

版主再仔细推敲一下你的证明代码
我觉得逻辑上似也有问题

至于我的证明代码
一方面因为我是先通过其它方法确认了这个优先级
再去寻求从代码角度证明的
另一方面为了追求代码的优雅
设计上主要考虑了前后代码的连贯性
所以有些逻辑上的疏忽在所难免

当然重定向符号的细节还比较多
包括句柄复制符号也没有展开来

qzwqzw

现在基本可以确定
| 和>这些符号会影响cmd的控制台IO模式
而这些模式会影响等控制台标准IO函数的行为
主要包括ReadFile/ReadConsole，WriteFile/WriteConsole
3，8，9楼的代码
主要是因为ENABLE_PROCESSED_OUTPUT模式被置假
导致WriteFile/WriteConsole不再特殊处理屏幕缓冲区中的控制区字符

可用的模式共

ENABLE_ECHO_INPUT                        0x0004
ENABLE_EXTENDED_FLAGS                0x0080
ENABLE_INSERT_MODE                        0x0020
ENABLE_LINE_INPUT                        0x0002
ENABLE_MOUSE_INPUT                        0x0010
ENABLE_PROCESSED_INPUT                0x0001
ENABLE_QUICK_EDIT_MODE                0x0040
ENABLE_WINDOW_INPUT                        0x0008
                        
ENABLE_PROCESSED_OUTPUT                0x0001
ENABLE_WRAP_AT_EOL_OUTPUT        0x0002
复制代码

参考链接
http://msdn.microsoft.com/en-us/library/ms686033(VS.85).aspx

qzwqzw

回复 11# amwfjhh

    让我想起了批处理内幕：句柄 那篇帖子了，后面有一个句柄转换后把con重新指给1句柄的，那里面就出现了cls控制字符的显示，看来根源也在这里。

你说的应该是《重定向中的秘密（句柄备份）》的27楼的问题
http://www.bathome.net/redirect. ... 92&fromuid=3023

两个问题其实并非同源
那里的问题主要是因为con并非完全仿真的控制台
导致cls以及dir/p等命令识别出了这个特殊设备
所以在显示逻辑上做了例外处理
在真正的控制台上cls不会输出0x0c的字符

这里的问题主要是管道、重定向以及括号字符的联用
导致控制台的IO模式发生变化
最终忽略了缓冲区中控制字符的特殊处理

你可以注意到两个问题的命令行用法并不完全相同
echo.>con并不会输出0x0d 0x0a的图形字符
echo+0x0c(可以通过Ctrl-L输入)也不会执行清屏

qzwqzw

回复 13# amwfjhh


    你想通过这段代码说明什么？

代码中>con会将标准输出重定向到con
而cls执行时会探测到标准输出不再是原来的控制台
因此直接输出字符了事

qzwqzw

把以前的老帖翻出来炒冷饭

:: 句柄模拟.cmd - 模拟运算句柄操作后的句柄状态
:: qzwqzw - 2009-6-12
@echo off & setlocal EnableDelayedExpansion
if [%1]==[] (
    echo. 这是句柄操作示例, 模拟运算进行几次句柄操作后的句柄状态
    echo --------------------- call %~n0 ">nul" "2>nul" ---------------------
    call %0 ">nul" "2>nul"  
    set 句柄
    echo.
    echo --------------------- call %~n0 ">nul" "2>nul" "3>nul" ---------------------
    call %0 ">nul" "2>nul" "3>nul"  
    set 句柄
    echo.
    echo --------------------- call %~n0 ">nul" "2>&1" "3>&1" ---------------------
    call %0 ">nul" "2>&1" "3>&1"  
    set 句柄
    echo.
    echo --------------------- call %~n0 ">nul" "3>nul" "4>nul" ---------------------
    call %0 ">nul" "3>nul" "4>nul"  
    set 句柄
    echo.
    echo --------------------- call %~n0 "3>nul" "4>nul" ---------------------
    call %0 "3>nul" "4>nul"  
    set 句柄
    echo.
    pause
    goto :eof
)
set "0=con" & set "1=con" & set "2=con"
for %%h in (%句柄%) do set %%h
echo.----- 起始状态 Initiation state -----
for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
echo.

echo.----- 预处理 Pre-process -----
:loop
if [%1]==[] goto :end
echo.----- %1 -------
set "_tmp=%~1"
if "%_tmp:~0,1%"=="<" set "_tmp=0%_tmp%"
if "%_tmp:~0,1%"==">" set "_tmp=1%_tmp%"
set _句柄=%_tmp:~0,1%
set _句柄_2=
set _dev=
if "%_tmp:~2,1%"=="&" (set _句柄_2=%_tmp:~3%) else (set _dev=%_tmp:~2%)
for %%h in (0 1 2 3 4 5 6 7 8 9) do (
    if "!%%h!"=="" (
        set/p=b: %_句柄%[!%_句柄%!]=^>%%h[!%%h!] : <nul
        set "%%h=!%_句柄%!"
        set bak_%%h=%_句柄%
        goto :set
    )
)
:set
for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
echo.
if defined _dev (
    set/p=a: %_dev%=^>%_句柄%[!%_句柄%!] : <nul
    set %_句柄%=%_dev%
) else if defined _句柄_2 (
    set/p=a: %_句柄_2%[!%_句柄_2%!]=^>%_句柄%[!%_句柄%!] : <nul
    set %_句柄%=!%_句柄_2%!
)
for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
echo.
shift
goto :loop

:end
echo.----- 后处理 Post-process -----
for %%h in (0 1 2 3 4 5 6 7 8 9) do (
    if not "!bak_%%h!"=="" (
        set/p=r: !bak_%%h![]^<=%%h[!%%h!] : <nul
        set !bak_%%h!=!%%h!
        set %%h=
        set bak_%%h=
        for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
        echo.
    )
)
set 句柄=
for %%h in (0 1 2 3 4 5 6 7 8 9) do set 句柄=!句柄! "%%h=!%%h!"
endlocal & set 句柄=%句柄%
echo.----- 结束状态 End Status -----
for %%h in (%句柄%) do set/p=%%~h <nul
echo.
复制代码