[文件操作] [已解决]有多个文件夹 每个里面都有一些图片 要求批量剪切到一个文件夹

001011

有多个文件夹  每个里面都有一些图片 要求批量剪切到一个文件夹  对这些图片集中处理  然后再还原到原来的文件夹里面

001011

举例说明一下  我现在有1、2、3三个文件夹  每个里面都有10001.tif、10002.tif、10003.tif、10004.tif、10005.tif五张图片。全部剪切到A文件夹  图片名可以是1 10001.tif、1 10002.tif、1 10003.tif、1 10004.tif、1 10005.tif、2 10001.tif、2 10002.tif、2 10003.tif、2 10004.tif、2 10005.tif...........。然后我在A文件夹做图片处理。处理完了  再根据图片名空格前面的数字还原到原来的文件夹   图片名  固定是五位的1000**格式

awk

移动.bat

@echo off
setlocal enabledelayedexpansion
cd /d "C:\test"
for /l %%a in (1,1,3) do (
    for %%b in ("%%a\*.tif") do (
        set "newname=%%b"
        set "newname=!newname:\=_!"
        move "%%b" "A\!newname!"
    )
)
复制代码

awk

还原.bat

@echo off
setlocal enabledelayedexpansion
cd /d "C:\test"
for /f "tokens=1-2 delims=_" %%a in ('dir /b A\*.tif') do (
    move "A\%%a_%%b" "%%a\%%b"
)
复制代码

001011

谢谢啦  你这个脚本是不是只能移动1、2、3这样的文件夹名呀  但是我们的文件夹名  不一定是1、2、3呀

001011

而且 还不一定是顺号的

awk

回复 6# 001011


你咋不早说啊？

001011

呵呵 抱歉了  麻烦您咯

001011

还是按路径取文件夹的名字吧  自动建立“A”文件夹 呵呵

awk

移动.bat

@echo off
set "src=C:\Test\处理前"
set "dst=C:\Test\处理后"
for /f "delims=" %%a in ('dir /b /ad %src%') do (
    for %%b in ("%src%\%%a\*.tif") do (
        move "%%b" "%dst%\%%a_%%~nxb"
    )
)
复制代码

001011

我给了路径

@echo off
set "src=F:\佳美园20 21"
set "dst=F:\A"
for /f "delims=" %%a in ('dir /b /ad %src%') do (
    for %%b in ("%src%\%%a\*.tif") do (
        move "%%b" "%dst%\%%a_%%~nxb"
    )
)
复制代码

001011

怎么不能剪切呢  移动和复制 是同一个BAT吗

awk

回复 11# 001011

@echo off
set "src=F:\佳美园20 21"
set "dst=F:\A"
for /f "delims=" %%a in ('dir /b /ad "%src%"') do (
    for %%b in ("%src%\%%a\*.tif") do (
        echo move "%%b" "%dst%\%%a_%%~nxb"
    )
)
pause
复制代码

你运行这个，把结果给我看看。

001011

提示  找不到文件   但是我发现造成错误的原因是 佳美园20 21  文件名中有个空格

001011

删掉空格就没有问题了