[数值计算] [已解决]批处理怎样实现数值排序处理？

guaiwu

setlocal enabledelayedexpansion
for /f %%i in (22.txt) do (
set /a n+=1
for /f "skip=!n!" %%a in (22.txt) do (
set m=%%a
for /f %%b in (22.txt) do (
if !m! gtr %%b (set x=!m!)
)
echo !x!
))
pause
复制代码

22.txt

4100
100
555000
1313
56565984
131389949
复制代码

求解skip=n，n不能是变量吗。  头都大了

需求：想要实现22.txt文档中数值按gtr排序。希望能照着次代码的思路做下去，我不想断了自己这段代码、

bluewing009

想写冒泡排序么？sort命令？

545810831

按照楼主代码思路只能找到最大值或最小值,

wc726842270

LZ是想升序（ASC）么？如果有兴趣看一下我写的 http://www.bathome.net/thread-13976-1-1.html
利用了ASCII字符表，进行了适当的极值，只要知道最大值的位数和最小的就差不多了

冷玉公子

批处理通用排序代码，大家来看哦。
http://www.bathome.net/viewthread.php?tid=13997&extra=

楼主的题我拿出来演示了 哈哈

冷玉公子

@Echo Off&SetLocal EnableDelayedExpansion
@Rem 关闭回显并打开变量延迟

Set /P Var_Filepach=请讲要处理的文件，拖入此框中。
@Rem 这个我觉得不用作解释吧 哈哈

@Rem 检测要处理文件的行数，并将每一行赋值于一个数组中。
For /f %%a in (%Var_Filepach%) do (
	Set /a NumValue+=1
	Set "StrLine!NumValue!=%%a"
)

@Rem 处理过程 具体看下面的注释
For /l %%z in (1,1,%NumValue%) do (
@Rem 第一个For循环，循环次数为文本的总行数。
	
	For /l %%a in (1,1,%NumValue%) do (
	@Rem 第二个循环，循环次数为文本的总行数，其实是为第一次排序。
	
		For /f "tokens=* delims=." %%b in ("!StrLine%%a!") do Set StrLineNumValueA=%%b
		@Rem 找出排序依序值，本例中处理的是C类IP地址。所以取的值为最后一个IP地址.
		
		Set "Var_Stepvalue=%%a"
		Set /a Var_Stepvalue+=1
		If !Var_Stepvalue! GEQ %NumValue% Set Var_Stepvalue=%NumValue%
		@Rem 这个IF只是用来限制判断行数不能超出最大的行数
		Echo !Var_Stepvalue! > %Temp%\Temp
		@Rem 因批处理没有办法或者说本人还没有发现更好的方法来实现真正的数组，所以只能利用局部变量来代替数组编号。
		@Rem 所以将这个位置的值用所需要的值，加1然后输出到一个文本中。方便让下一个For来将其作为局部变量来使用
		
		For /f %%b in (%Temp%\Temp) do (
		@Rem 读取所需要的数组代号并赋值于局部变量%%b
			For /f "tokens=* delims=." %%b in ("!StrLine%%b!") do Set StrLineNumValueB=%%b
			@Rem 提取出于第一个数值做比较的第二个数值
			
			If !StrLineNumValueA! GTR !StrLineNumValueB! (
			@Rem 判断第二个数值是否大于第一个数值
				Set "StrLineT=!StrLine%%a!"
				Set "StrLine%%a=!StrLine%%b!"
				Set "StrLine%%b=!StrLineT!"
				@Rem 这三个命令其实就是说，如果第二个大于第一个就将两个数组中的数值做一个替换
			)
		)
	)
)
For /l %%a in (1,1,%NumValue%) do (
		Echo !StrLine%%a!
)
@Rem 将排序好的数组显示出来
Pause
复制代码

guaiwu

@echo off
setlocal enabledelayedexpansion
for /f %%i in (22.txt) do (
set /a n+=1
set _!n!=%%i
)
for /l %%i in (1,1,!n!) do (
for /l %%j in (%%i+1,1,!n!) do (
                if !_%%i! gtr !_%%j! (
                        set var=!_%%i!
                        set _%%i=!_%%j!
                        set _%%j=!var!
                ))
echo !_%%i!
)
pause
复制代码

Batcher

回复 6# 冷玉公子


排序一般都是两层for循环，你这个四层for循环优势在何处？

Batcher

常见几种排序的批处理写法
http://bbs.bathome.net/thread-4196-1-1.html

CrLf

回复 6# 冷玉公子


    有想法，不过这样一来，命令的执行次数以指数级增长，效率会比较低...

冷玉公子

回复 8# Batcher


    因为这样的排序会有一个通病，就是前三个数值的排序问题，例如
   5
   7
   3
   6
   8
    这样的话第一次的结果就会是：53678。  5还是会在第一个。
    所以我多加了一次循环只是为了，避免这个错误发生。

其实14行的For完全可以改成循环两次就OK了，但是这不为了通用就复杂了一点。哈哈

Batcher

回复 11# 冷玉公子


本来是O(n^2)的排序算法，被你“改良”成了O(n^4)，方向完全是搞反了嘛，哈哈。