batman

我还是喜欢用纯批处理，代码先不发了，先看看别人的吧。。。

batman

思路说明：
以下代码是充分findstr命令的示例，使用findstr /n来取得行号同时兼容空行，
并将行号进行变量赋值；使用findstr /o来取得第行的字符偏移量，但要通过
上、下行的字符偏移差，因为字符偏移值是类计递加的，同时每行回车增加
两个字符偏移，所以不可避免要对最后一行强加回车，在不破坏原文件的情
况下只好生成临时文件；利用findstr /o能够一次性获得文本所有行的字符偏
移量也就是字符总数，效率和逐字符判断相比肯定是高得多了。
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－

@echo off
copy /y 1.txt 2.txt>nul
echo.>>2.txt&echo end>>2.txt
for /f "tokens=1,2* delims=: " %%i in ('findstr /n /o .* 2.txt') do (
    set "_%%i=%%j"&set ".%%i=%%k"
　　if %%i geq 2 call :lp %%i
)
del /q 2.txt&pause>nul&goto :eof
:lp
set /a n=%1-1
set /a num=_%1-_%n%-2
set /a kl=(80-num)/2
for /l %%i in (1,1,%kl%) do set /p= <NUL
call,set /p=%%.%n%%%<NUL&ECHO.
 
复制代码

batman

再来一个更简单的（no findstr  no 逐字符 no tempfile no 变量延迟）：

@echo off
for /l %%i in (1,1,80) do call,set "kong=%%kong%% "
for /f "delims=" %%i in (1.txt) do (
     set "str=%%i%kong%"
     call,set "str=%%str:~,80%%"
     call,set "str=%%str:%%i=%%"
     call,set "str=%%str:  = %%"
     call,echo %%str%%%%i
)
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-8-2 12:04 编辑 ]

batman

楼上的没考虑空行，同时逐字符效率是大问题，还有最后的goto :eof是多余的。