[挑战]查询北京地铁线路

随风

a.txt
内容一行为一条地铁线路站名，每站以空格隔开，第一个为线路名，第二个为起点站

1号线 苹果园 古城 八角游乐园 八宝山 玉泉路 五棵松 万寿路 公主坟 军事博物馆 木樨地 南礼士路 复兴门 西单 天安门西 天安门东 王府井 东单 建国门 永安里 国贸 大望路 四惠
八通线 四惠 四惠东 高碑店 传媒大学 双桥
2号线 安定门 雍和宫 东直门 东四十条 朝阳门 建国门 北京站 崇文门 前门 和平门 宣武门 复兴门 阜成门 车公庄 西直门 积水潭 鼓楼大街
大兴线 天宫门 生物医药基地 义和庄 黄村火车站 黄村西大街 清源路 枣园 高米店南 高米店北 西红门 新宫 公益西桥
4号线 公益西桥 角门西 马家堡 北京南站 陶然亭 菜市口 宣武门 西单 灵境胡同 西四 平安里 新街口 西直门 动物园 国家图书馆 魏公村 人民大学 海淀黄庄 中关村 北京大学东门 圆明园 西苑 北宫门 安河桥北
房山线 苏庄 良乡南关 良乡大学城西 良乡大学城 良乡大学城北 广阳城 篱笆房 长阳 稻田 大葆台
亦庄线 次渠 次渠南 经海路 同济南路 荣昌东街 荣京东街 万源街 亦庄文化园 亦庄桥 旧宫 小红门 肖村 宋家庄
5号线 宋家庄 刘家窖 蒲黄榆 天坛东门 磁器口 崇文门 东单 灯市口 东四 张自忠路 北新桥 雍和宫 和平里北街 惠新西街南口 惠新西街北口 大屯路东 北苑路北 立水桥南 立水桥 天通苑南 天通苑 天通苑北
8号线 森林公园南门 奥林匹克公园 奥体中心 北土城
10号线 劲松 双井 国贸 金台夕照 呼家楼 团结湖 农业展览馆 亮马桥 三元桥 太阳宫 芍药居 惠新西街南口 安贞门 北土城 健德门 牡丹园 西土城 知春路 知春里 海淀黄庄 巴沟
13号线 西直门 大钟寺 知春路 五道口 上地 西二旗 龙泽 回龙观 霍营 立水桥 北苑 望京西 芍药居 光熙门 柳芳 东直门
昌平线 南邵 沙河高教园 沙河 巩华城 朱辛庄 生命科学园 西二旗
机场专线 东直门 三元桥 T2航站楼 T3航站楼
15号线 望京西 望京 崔各庄 马泉营 孙河 国展 花梨坎 后沙峪
复制代码

要求:
  输入出发地点和终点名  如: 奥体中心 西直门
  显示: 出发点到目的地的最少换乘，和最短线路(以过站数量决定距离) 以及过站数量
   或是列出所有能到达目的地的线路、换乘次数、过站数量。(北京地铁不建议如此，若是穷举的话随便就过百)
   附上地图辅助验证
代码要求: 要有通用性，即以后若要添加站名、线路只需更改a.txt内容即可，不需改代码。

随风

call 递归 应该是可以完成的，只是太绕，我实在绕不下去了。
思路：模拟列车开出，途中遇可换乘站自动换乘，这样就可以把所有线路都走一篇，计算下距离即可。
只是说起容易做起来难，计算时被call绕晕了。
换种思路
先得出a到b需要乘坐哪几条线，到哪些站中转，再模拟开一趟，计算出最近的

随风

jm的那个公共线路我只听过，从未看过，当初还以为只是查询单线路a到b的站名呢？难道jm早在N年前就做出来了？
不过你都没耐心看完，我想我就更没那耐心了 ^_^
看代码比写还累。

随风

输入 华强路 岗厦北
路线: "华强路 世界之窗 岗厦北"  "华强路 大剧院 岗厦北"
少了条 "华强路 世界之窗 岗厦北 会展中心 市民中心"

输入 岗厦 岗厦北
路线:"岗厦 岗厦北" "岗厦 世界之窗 岗厦北"  "岗厦 大剧院 岗厦北"  "岗厦 世界之窗
岗厦北"  "岗厦 大剧院 岗厦北"  "岗厦 市民中心 岗厦北"  "岗厦 黄贝岭 岗厦北"
"岗厦 岗厦北" 少了两站
"岗厦 市民中心 岗厦北" 少了"市民中心"
"岗厦 黄贝岭 岗厦北" 少了"大剧院"

随风

也考虑过坐标，可是批处理不知道如何弄啊
现在是获取出发点的车次到目的地的车次，只要在交接点中查询就可以了
call 在语句块中递归，能最终找到目的，但无法正确计算途中经过的节点，抓狂中。。

随风

总算搞出来了，基本符合要求，复杂路线还没测试.

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims= " %%i in (dt.txt) do (
    set max=0
    for %%a in (%%j) do (
         set xian.%%i=!xian.%%i! %%a
         if defined zan.%%a set jie.%%a=!zan.%%a! %%i
         set zan.%%a=!zan.%%a! %%i
         set /a max+=1
         set /a ###%%i.%%a=!max!
    )
)
:: 获取所有线上的节点站名
for /f "tokens=2,3 delims=.=" %%i in ('set jie.') do (
    for %%a in (%%j) do set #%%a=!#%%a! %%i
)
:start
setlocal&cls
set /p xxx=输入起点站和终点站如: 华强路 岗厦北
for /f "tokens=1,2 delims= " %%a in ("!xxx!") do (
    set qix=!zan.%%a!&set "zx=!zan.%%b!"
    set qidian=%%a&set "zongdian=%%b"
    for %%i in (!zan.%%b!) do set zd.%%i=%%i
)
echo !qidian! --- !zongdian!     !qix!  ---  !zx!
echo;.............................................&echo;
:: 判断是否在同一条线
for %%a in (!qix!) do (
    for %%b in (!zx!) do if "%%a"=="%%b" (
        set tong=!tong! %%a
        call :tong !qidian! !zongdian!
        echo !ok!  共 !zzu! 站
        echo;.............................................
    )
)
if defined tong echo;&pause&endlocal&goto :start
rem        起点线    终点线  
call :kai "!qix!"
for /f "tokens=1* delims==" %%i in ('set $') do (
    set "%%i="&set /a mmm=0
    set tong=!qix!&set L1=!qidian!
    for %%k in (%%j) do (
        for /f "tokens=1,2 delims=/" %%a in ("%%k") do (
            set num=%%a&set tong2=%%b
        )
        call :tong !L1! !num!
        set /a mmm+=zzu,%%i+=1
        set tong=!tong2!&set L1=!num!
        echo            !ok! !zzu! 站
    )
    set tong=!zx!
    call :tong !num! !zongdian!
    set /a mmm+=zzu&set "mmm=  !mmm!"
    echo 累计!mmm:~-3!站  !ok! !zzu!站              
    echo;.............................................&echo;
)
echo;&pause&endlocal&goto :start
:kai
for %%a in (%~1) do (
    set t.%%a=a
    for %%b in (!#%%a!) do (rem %%b为%%a线上的节点站名
        for %%c in (!jie.%%b!) do (rem %%c为节点站上的线名
            if not defined t.%%c (
                if not defined zd.%%c (
                    set @=!@! %%b/%%c
                    call :kai "%%c"
                    set "t.%%c="
                    set @=!@: %%b/%%c=!
                    ) else (
                        set /a fl.+=1
                        set $!fl.!=!@! %%b/%%c
                )
            )
        )
    )
)
goto :EOF
:tong
for %%a in (!tong!) do (
    set strq=!###%%a.%1!
    set strz=!###%%a.%2!
    set /a zzu=strq-strz
    set zzu=!zzu:-=!
    set ok=%%a/%1 --- %%a/%2
)
goto :EOF
复制代码

随风

已在顶楼更新北京地铁

随风

经验证11楼的比我23楼的精确百倍，也高效百倍..