[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

【练习-003】批处理实现文本左右对齐排版

如1.txt内容如下。
  1. 111111111111111111111    98912 张三
  2. 222222222222222222    150020 李四四
  3.   333333333333333333333    360000 王五
  4. 444444444444444444    2332 赵六六
  5.   555555555555555555    222 田七
  6. 666666666666666666666    999999 舞吧
复制代码
通过批处理输出为:
  1. 111111111111111111111      98912 张三
  2. 222222222222222222        150020 李四四
  3. 333333333333333333333     360000 王五
  4. 444444444444444444          2332 赵六六
  5. 555555555555555555           222 田七
  6. 666666666666666666666     999999 舞吧
复制代码
代码要求,不生成任何临时文件。
代码简洁,视思路与代码加分!
------------------------------------------------------------------------------------------
本题只是给出一个简单的文本通过批处理排版,而要求代码的通用,正如batman版主所说,会是一个繁琐的过程,于是就题解题,不必考虑代码的通用。

[ 本帖最后由 batman 于 2008-7-27 23:57 编辑 ]
心绪平和,眼藏静谧。

我来帮大家理思路吧:
所有的列其实都是左右对齐,大家想下为什么吧。

[ 本帖最后由 batman 于 2008-7-26 01:25 编辑 ]
***共同提高***

TOP

@echo off
Setlocal Enabledelayedexpansion
set n=0
for /f "tokens=1,2*" %%i in (1.txt) do (
      set "ke=%%i %%j"
      set m=0
      call :1              
)
for /f "tokens=1,2*" %%i in (1.txt) do (
      set "ke1=%%i %%j"
      set ke2=%%i            
      set m1=0
      call :2
      echo !ke2! %%j %%k            
)
pause
goto :eof
:1
  if not "!ke:~%m%,1!"=="" set /a m+=1&goto 1
  if %m% gtr %n% set n=%m%
  goto :eof  

:2
  if not "!ke1:~%m1%,1!"=="" set /a m1+=1&goto 2
  set /a dd=n-m1
  for /l %%a in (1,1,%dd%) do set "ke2=!ke2! "     
  goto :eof
1

评分人数

TOP

不知道大家发现没?其实cmd文本排版是有潜规则的!

TOP

呵呵,是

TOP

是。^_^
心绪平和,眼藏静谧。

TOP

我本人的解,还是很繁琐,思路跟浅默的差不多。望更多人参与此题,求得更多的解!

  1. @echo off&setlocal enabledelayedexpansion
  2. set length=0
  3. for /f "tokens=1,2" %%a in (1.txt) do (
  4.      set x=0
  5.      call :lp %%a%%b
  6.      if !x! gtr !length! set length=!x!
  7. )
  8. set/a length+=4
  9. for /f "tokens=1,2,*" %%a in (1.txt) do (
  10. set x=0
  11. set/p=%%a <nul
  12. call :lp %%a%%b
  13. set/a s=length-x
  14. for /l %%i in (1 1 !s!) do set/p= <nul
  15. set/p=%%b<nul
  16. set/p= %%c<nul
  17. echo.
  18. )
  19. pause&exit/b
  20. :lp
  21. set str=%1
  22. :lp1
  23. if defined str set str=!str:~1!&set/a x+=1&goto lp1
复制代码
心绪平和,眼藏静谧。

TOP

这个是潜规则默认排版方式
  1. @echo off
  2. for /f "delims=*" %%a in (1.txt) do call :xxx %%a
  3. pause&exit
  4. :xxx
  5.     set "str=%*"
  6.     REM 注意:等号左侧是制表符
  7.     set "str=%str: = %"
  8.     echo.%str%
  9. goto:eof
复制代码
1

评分人数

TOP

原帖由 fastslz 于 2008-7-26 18:11 发表
这个是潜规则默认排版方式
@echo off
for /f "delims=*" %%a in (1.txt) do call :xxx %%a
pause&exit

:xxx
    set "str=%*"
    set "str=%str: =        %"
    echo.%str%
goto:eof


第一次看到如此的方法,还没弄明白怎么回事,在我电脑上测试着不正确。但仍旧学习了!~
心绪平和,眼藏静谧。

TOP

是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符,替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件
2

评分人数

TOP

原帖由 fastslz 于 2008-7-26 18:35 发表
是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符,替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

测试文本:
  1. 1111111    aaaaaaaaaaaa 张三
  2. 222222sdf222222222222    150020 李四四
  3.   3333333sfd33333333333333    0 王五
  4. 44444444444aa4444444    2332 赵sdfafa六六
  5.   555555555    222 田七
  6. 666666666666666666666asaaaaaaaaa    9999999999999 舞
复制代码
心绪平和,眼藏静谧。

TOP

就题解题

个人认为如本题要充分考虑代码通用性的话,就会是一个相当复杂的过程,
于是,就题解题:
  1. @echo off&setlocal enabledelayedexpansion
  2. set "kong=           "
  3. for /f "delims=" %%a in (1.txt) do (
  4.     for %%i in (%%a) do (
  5.         set "str=%%i"&set /a n+=1
  6.         if !n! equ 2 (
  7.            set "str=%kong%!str!"
  8.            set /p=!str:~-10! <nul
  9.            ) else (
  10.            set "str=!str!%kong%"
  11.            set /p=!str:~,20! <nul
  12.     ))
  13.     set "n=0"&echo.
  14. )
  15. pause>nul
复制代码
1

评分人数

***共同提高***

TOP

原帖由 fastslz 于 2008-7-26 18:35 发表
是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符,替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

使用制表符是默认的左对齐分列,主要用来从文本向excel中导数据。
***共同提高***

TOP

我是最最新手,向你们学习

  1. @echo off & setlocal enabledelayedexpansion
  2. for /f "tokens=1-3 delims= " %%a in (1.txt) do (
  3. set /a n+=1
  4. if !n!==1 echo %%a      %%b   %%c
  5. if !n!==2 echo %%a         %%b  %%c
  6. if !n!==3 echo %%a      %%b  %%c
  7. if !n!==4 echo %%a         %%b    %%c
  8. if !n!==5 echo %%a         %%b     %%c
  9. if !n!==6 echo %%a      %%b  %%c
  10. )
  11. pause
复制代码
1

评分人数

TOP

可以直接这样。。
echo 111111111111111111111      98912 张三
echo 222222222222222222        150020 李四四
echo 333333333333333333333     360000 王五
...
...
加分鼓励!一同进步!
心绪平和,眼藏静谧。

TOP

返回列表