523066680

在cn-dos做过
arrangement

@echo off
setlocal enabledelayedexpansion
set /p inp="仅支持排列几个普通字符，不要乱输哦:"
call :func "%inp%" ""
pause
exit

:func
if "%~1"=="" (echo _%~2 &goto :eof)
setlocal
set strnow=%~1
set /a lp=0,lpb=lp+1
 :lp
  call :func "!strnow:~0,%lp%!!strnow:~%lpb%!" "%~2!strnow:~%lp%,1!"
  if not "!strnow:~%lpb%!"=="" (
   set /a lp+=1,lpb=lp+1
   goto :lp
  )
endlocal
复制代码

combination

@echo off
call :func "abcd" ""
pause &exit

:func
 setlocal
 if %1=="" (
    if not %2=="" (echo %2)
    goto :eof
 )
 set strnow=%~1
   call :func "%strnow:~1%" "%~2%strnow:~0,1%"
   call :func "%strnow:~1%" "%~2"
 endlocal
复制代码

本来利用批处理可以用变量作为语句执行的特点可以用变量构造多层for ,这样速度很快。
但是排列方面整起来不容易，组合的话倒可以：

@echo off &setlocal enabledelayedexpansion

set element=a b c

:gettitle
for %%x in (%element%) do (
  set "fo=for %%%%x in ("%%x" "") do (!fo!"
  set end="!end!)"
  set result=!result!%%~%%x
)

%fo%
  echo "%result%"
%end:"=%
pause
复制代码

523066680

哪位能把for 语句构造到变量里边去，然后替换执行的。
会很有戏哦
@echo off
for %%a in (a b c) do (
for %%b in (a b c) do (
for %%c in (a b c) do (
        if not %%a==%%b (
        if not %%b==%%c (
        if not %%a==%%c (
        echo %%a%%b%%c
        )))
)))
pause
)

523066680

回复 35# ahighhand

26选3
组合

@echo off
call :func "abcdefghijklmnopqrstuvwxyz" "" 0
pause &exit

:func
    setlocal
    set /a v=%3
    if %v% equ 3 (echo %~2 &goto :eof)
    if %1  == "" (goto :eof)
    set strnow=%~1
    call :func "%strnow:~1%" "%~2%strnow:~0,1%" %v%+1
    call :func "%strnow:~1%" "%~2" %v%
    endlocal
复制代码

排列

@echo off &setlocal enabledelayedexpansion
set alphabet=abcdefghijklmnopqrstuvwxyz
for /l %%a in (0,1,25) do set eles=!eles! !alphabet:~%%a,1!
call :func "%eles%" "" 0
pause &exit

:func
    setlocal
    set /a v=%3
    if %v% equ 3 ( echo %~2 &goto :eof)
    set eles=%~1
    for %%a in ( %eles% ) do call :func "!eles:%%a=!" "%~2%%a" %v%+1
    endlocal
复制代码

523066680

回复 37# 老刘1号

    那个帖子，我转发了一段迭代解法（摘自《高阶Perl》），若想要第N个结果、或者想要从第N个排列开始排，可以直接算，而不需要从头开始。
不过没什么人留意
http://www.bathome.net/redirect. ... 3749&pid=198745
http://www.code-by.org/viewtopic.php?p=814#p814

如果做多线程并行，这种迭代法就很好用，8核的CPU，8线程分别从不同的起点开始迭代。
如果是跑GPU，并发量就更大了，若是简单的加密应该可以利用这种方法，大量并发加速碰撞。