【练习-063】根据原始文本分配数据并生成xsl文件

batman

出题目的：
　　综合考查大家的变量计算及文本处理能力
解题要求：
　　代码高效并尽可能简洁
　　请老手们暂不出手，但可跟贴讨论指导新手
加分原则：
　　满分30分，视情况加分（思路为重）
题目如下：
　　有文本文件char.txt（见附件），四列n行，每一行都是一个客户的信息（区域　姓名　费用　关系人），现在用批处理将这些客户按150户/每人的原则分配到九个人手中（王冬 刘通 文娟娟 马宇芊 候国强 毛远锋 易湛慧 李楠 池茜）并以xls文件保存，同时在分配时要同时满足以下原则：
　　1、每人150户不可多也不可少；
　　2、王冬 刘通 文娟娟 马宇芊四个人只能分配B区的客户，候国强 毛远锋 易湛慧 李楠 池茜这五人只能分配A区的客户；
　　3、每个人要优先分配关系人是自己的客户，如果少于150的则从其他关系人中补足150条；
　　4、计算每个人分配到的客户的总费用并标在文件名中，如易湛慧-9865.42；
　　5、没有分配完的用户统一放在char.xsl中；
　　6、所有xls文件要求全信息输入（区域　姓名　费用　关系人），并且都要在第一行输入这个表头。
说明：
　　原始数据足够满足题目的条件，这点不要多虑。
附件char.txt:
链接: https://pan.baidu.com/s/1QhbUKzsuT21ZA9WLSCNj2g 提取码: refu

batman

小知识：批可以直接生成xls文件，也可对生成的xls进行重操作，前提是你装了office。。。

batman

怎么没有人解题了，是太难了吗？这就是一道批的实际应用题啊，相信很多人在工作中会遇到的。。。

如果新手觉得计算难了点，可以不完成计算这一步。。。

唉，要是新手望而怯步，老手们就出手吧。。。

batman

唉望眼欲穿啊，下面是本人出题前的解（注意替换tab）：

@echo off&setlocal enabledelayedexpansion
set "names=b-王冬 b-刘通 b-文娟娟 b-马宇芊 a-候国强 a-毛远锋 a-易湛慧 a-李楠 a-池茜"
rd /s /q char 2>nul&md char&set "tab=	"
for /f "tokens=1-4 delims=%tab%" %%a in (char.txt) do (
    if not defined hard (
       set "hard=a"
       for %%i in (%names%) do (
           for /f "tokens=1-2 delims=-" %%j in ("%%i") do (
               set "%%k=%%j"&echo %%a%tab%%%b%tab%%%c%tab%%%d>char\%%k.xls
               set /a _%%k=0
           )
       )
       ) else (
       if /i "%%a" equ "!%%d!区" if !_%%d! lss 150 set "flag=a"
       if defined flag (
          echo %%a%tab%%%b%tab%%%c%tab%%%d>>char\%%d.xls
          set "flag="&set /a _%%d+=1
          for /f "tokens=1-2 delims=." %%x in ("%%c") do (
              set "a=%%y00"&set /a .%%d+=%%x,..%%d+=1!a:~,2!%%100
              if !..%%d! geq 100 set /a ..%%d-=100,.%%d+=1
          )
          ) else (
          echo %%a %%b %%c %%d>>char\char.xls
       )
   )
)
set "flag="
for %%a in (%names%) do (
    for /f "tokens=1-2 delims=-" %%b in ("%%a") do (
        for /f "tokens=1-4" %%d in (char\char.xls) do (
　　　　　　if !_%%c! lss 150 if /i "%%d" equ "%%b区" set "flag=a"
            if defined flag (
               echo %%d%tab%%%e%tab%%%f%tab%%%g>>char\%%c.xls
　　　　　　　 set /a _%%c+=1&set "flag="
               for /f "tokens=1-2 delims=." %%x in ("%%f") do (
                   set "a=%%y00"&set /a .%%c+=%%x,..%%c+=1!a:~,2!%%100
                   if !..%%c! geq 100 set /a ..%%c-=100,.%%c+=1
               )
               ) else (
               echo %%d%tab%%%e%tab%%%f%tab%%%g>>char\tem
            )  
        )
        if !..%%c! lss 10 set "..%%c=0!..%%c!"
        ren char\%%c.xls %%c-!.%%c!.!..%%c!.xls
        if exist char\tem del /q char\char.xls&ren char\tem char.xls 
    )
)
start char
复制代码