CrLf

也想过类似的思路，但是当时思维惯性，只想到了二分回溯补位，并没有用变量偏移，一墙之隔啊，可惜当时没想这么深入，呵呵。

CrLf

我的想法：

@echo off
set "$=%1"
setlocal enabledelayedexpansion
set len=8192
(for %%a in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1)do (
	set /a len-="%%a!$:~%%a,1!"||set $=!$:~%%a!
))2>nul
echo %len%
::未考虑字符串包含数字、特殊字符的情况
复制代码

稍加改进后仍然难以克服特殊字符的难关：

@echo off
set "$=%1"
setlocal enabledelayedexpansion
set len=8192
(for %%a in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1)do (
	set /a len-="%%a*^!(1-1!$:~%%a,1!)"||set $=!$:~%%a!
))2>nul
echo %len%
pause
::不惧怕数字了，但是仍然没有办法在set /a中很好地转义特殊字符，看来要想通用，那个if是不能省的了
复制代码

CrLf

回复 13# wankoilz


    看来个人有个人的习惯写法，我比较倾向用其他手段代替补位，这样可以兼容最长的变量（除了 , 这个变态的变量名），不过代码就稍显冗长了：

@echo off&setlocal enabledelayedexpansion

for /l %%a in (1 1 8189) do set s=!s!;
call :strlen s len

echo len=%len%
pause&exit/b

:strlen <stringVarName> [retvar] 
:: 思路： 二分回溯联合查表法
:: 说明： 所求字符串大小范围 0K ~ 8K；
::    stringVarName ---- 存放字符串的变量名
::    retvar      ---- 接收字符长度的变量名
setlocal enabledelayedexpansion&set $=!%1!&set N=0
if defined $ (
	for %%a in (4095 2047 1023 511 255 127 63 31 15)do if !$:~%%a!. NEQ . set/aN-=~%%a&set $=!$:~%%a,-1!
	set $=!$!fedcba987654321&set/aN+=0x!$:~15,1!
)
endlocal&If %2. neq . (set %2=%N%)else echo %N%
复制代码

CrLf

回复 16# xxpinqz


    他应该是回复14楼的...

CrLf

回复 28# nwm310


    挺好的思路
    把变量拆分成7份分别查询，就可以查8191字符长度内的所有变量了