batman

以下代码没有考虑特殊字符的情况，所取分隔符为每行最后一个（考虑了一行有10个以内相同分隔符的情况），楼主先测试吧：

@echo off&setlocal enabledelayedexpansion
set /p zx=请输入最小字符数：
set /p zf=请输入分隔符：
set /a n+=1
for /f "delims=" %%a in (a.txt) do (
    set "str=!var!%%a"&set /a min=0,pin=8190&set "var="
    for /l %%a in (1,1,14) do (
        for %%a in (!pin!) do (
            if "!str:~%%a!" equ "" (
               set /a max=pin
               ) else (
               set /a min=pin
            )
            set /a "pin=(max+min),y=pin%%2,pin=pin/2+y"
        )
    )
    set /a num+=pin
    if !num! geq %zx% (
       if "!str:%zf%=!" neq "!str!" (
          set "var=!str!"
          for /l %%a in (1,1,10) do set "var=!var:*%zf%=!"
       )
    )
    if defined var (
       for %%a in (!var!) do echo !str:%%a=!>>!n!.txt
       set /a n+=1,num=0
       ) else (
       echo !str!>>!n!.txt
    )
)    
echo 搞定。&pause>nul
复制代码

[ 本帖最后由 batman 于 2011-2-27 15:47 编辑 ]

batman

我测试了可以用，我的代码也不可向原文件输出任何内容，可不可以把你的文件内容贴出来一部分，估计是特殊字符的问题。。。

[ 本帖最后由 batman 于 2011-2-27 19:13 编辑 ]

batman

我晕，整个文章就是一行啊，这个用批是解决不了的。。。。

batman

还是纯批，请选择好合适的分隔符，要求分隔符在文字中出现总次数不大于31次，同时每两个分隔符间的文字不大于4096个：

@echo off&setlocal enabledelayedexpansion
del /q part_*.txt 2>nul
set /p zx=请输入最小字符数：
set /p zf=请输入分隔符：
set /a n=1,m=1
:lp
for /f "tokens=%n%* delims=%zf%" %%a in (a.txt) do (
    set "str=%%a"&set /a min=0,pin=8192
    for /l %%c in (1,1,14) do (
        for %%c in (!pin!) do (
            if "!str:~%%c!" equ "" (
               set /a max=pin
               ) else (
               set /a min=pin
            )
            set /a "pin=max+min,y=pin%%2,pin=pin/2+y"
        )
    )
    set /a num+=pin
    if !num! geq %zx% (
       >>part_!m!.txt echo !var!!str!
       set /a m+=1,num=0&set "var="
       ) else (
       set "var=!var!!str!"
    )
    set /a n+=1&goto lp         
)
>>part_%m%.txt echo !var!
echo 搞定。&pause>nul
复制代码

batman

附上测试文本，分隔符为#（我自己加上去的—|—）

batman

。号在文本中出现次数在31次以内？（因为for中tokens不能大于32），你没看清我的说明吧，请用#做分隔符试试我上传的文本吧。。。

batman

批一次性能处理的字节数上限是8192，换算成汉字就是4096个，你如果真要用批来解决的话，你的文本字符数就要受到限制，要不就要先手动分解成多个文本（每个应小于8000个字节，4000个汉字）再处理了。。。。