77七

回复 8# qixiaobin0715


   谢谢大佬指点！没考虑文件夹过多情况，如果文件夹数量成百上千、甚至过万，可能使用dir 都会影响效率；如果文件夹过多，目标文件且多存在于末级文件夹，使用dir /a-d 初步筛选可能符合条件的文件夹，可能更快点，具体看楼主实际情况吧:lol

aloha20200628

回复 16# 77七

单论判断一个指定目录（例如 C:\0\1\2\3）是否包含子目录，至少有三个方法如下
如果指定目录中确实没有子目录，各方法耗时差别几乎无感，但若真有好多多子目录，那差别就不一般了，方法三可是要用纯P去逐个遍历啊 所以中外老帖中还是用方法一或方法二为多。

::方法一
dir /b/ad "C:\0\1\2\3" | find /v "">nul || echo,是末级目录
::方法二
dir /b/ad "C:\0\1\2\3" | findstr ".">nul || echo,是末级目录
::方法三
set "n=" &for /f "delims=" %%j in ('dir /b/ad ""C:\0\1\2\3"') do set "n=1"
if not defined n echo,是末级目录
复制代码

77七

回复 17# aloha20200628


    谢谢大佬指点！
如果某目录下子目录众多，使用call + for /d 及时退出遍历应该也行，不过没有dir 灵活，不能识别隐藏目录

@echo off
call :1 "C:\0\1\2\3"
if %errorlevel% equ 2 (
	echo "C:\0\1\2\3" 是末级目录
)
pause & exit

	:1
	for /r "%~1" /d %%e in (*) do (
		exit /b 1
	)
	exit /b 2
复制代码

aloha20200628

回复 12# mmm8422616

以下代码会处理当前目录下所有末级目录，但假设 “仅当末级目录中确实有文件被移动后” 才删除该末级目录...
代码中第3行可增减多个被空格分隔的用双引号包裹的文件扩展名字段

@echo off &setlocal
(for /d /r %%d in (*) do dir /b/ad "%%~d\*" |find /v "">nul || (
	for %%F in ( "symlink" "jpg" "nfo" "mkv" "mp4") do if exist "%%d\*.%%F" (set/a "n=1"&move /y "%%d\*.%%F" "%%d\..")
	if defined n (set "n="&rd /s/q "%%d")
)) 2>nul
pause &exit/b
复制代码

aloha20200628

回复 18# 77七

老帖中对call的用法议论多多，其中还有慎用甚至不用的说法... 也难为了call先生，要对调用关键词在 "行首标签/内部命令/系统命令/外部（第三方）可执行脚本和程序文件/..." 中逐一匹配择取，也不知其匹配优先权如何，反正够累的

qixiaobin0715

回复 16# 77七
1.dir是内部命令，运行速度比我们想象的要快得多，定位到C:\，试了一下，25万多个文件夹也就是5分钟之内就解决问题。不知使用for /f+dir会如何；
2.文件夹超多的情况下，如果批处理使用6楼的思路，自定义变量设置数量可能会很多，甚至超限，效率可能更容易受到影响。记得win7系统变量设置最多可能8千多个，win10，win11不知是否放宽了限制。

terse

这里可以call一下 ，虽说不太喜欢用

@echo off
set exr="symlink" "txt" "jpg" "doc"
call :listdir "%cd%"
pause
exit
:listdir
for /d %%d in ("%~1\*") do set "d=%%d"&call :listdir "%%d"
if defined d (
        set "n="
        for %%i in ( %exr%) do if exist "%d%\*.%%i" set n=1&move /y "%d%\*.%%i" "%d%\.." >nul 2>nul
        if defined n rd /s /q "%d%"
)
set "d="
复制代码

77七

我测试了一下，只判断、打印、计数末级目录，以我的c盘实际情况为例，共有末级目录2200个

17楼方法一
11:05:21.13
11:05:54.99
耗时 33s

17楼方法二
10:56:52.10
10:57:31.35
耗时 39s

17楼方法三
10:55:53.43
10:56:24.59
耗时 31s

18楼方法
10:59:32.28
10:59:45.13
耗时 13s
复制代码

77七

回复 22# terse


   大佬，我在测试效率的时候发现，遇到文件夹名称，如 新建文件夹 (2)，则会出错

@echo off
call :listdir "%cd%"
pause
exit
:listdir
for /d %%d in ("%~1\*") do set "d=%%d"&call :listdir "%%d"
if defined d (
	echo %d%
)
set "d="
复制代码

echo %d%结果，右括号消失了

D:\\1\新建文件夹 (2
复制代码

77七

回复 24# 77七


   我找到原因了，去掉()则正确

if defined d echo %d%
复制代码

这个if 和 () 真是纠缠不清啊，这都能出错...这个直接颠覆了我的认知，以前一直以为明着写才会出错
再次验证

@echo off
set str=D:\\1\新建文件夹 (2)
if defined str (
        echo %str%
)
pause
复制代码

结果还是错的

幸好以前跟aloha20200628大佬学了一招，使用set /p=""<nul，保留特殊字符，双引号直接把()打出原形

@echo off
set str=D:\\1\新建文件夹 (2)
if defined str (
        set /p="%str%"<nul
        echo=
)
pause
复制代码

结果正确
想到aloha20200628大佬提到 set /p=""<nul无法保留前置空格，看来也不是个完美办法

@echo off
set str= D:\\1\新建文件夹 (2)
if defined str (
	for /f "delims=" %%x in ("%str%") do (
		echo %%x
	)
)
pause
复制代码

难道只能这样了？...

terse

回复 25# 77七
加引号
其实这里是开了延迟的，可以!str!这样!str!

77七

回复 26# terse


   谢谢大佬指点！引号确实能解决此例中的显示问题，但我想到遇到其它问题的时候可能不需要引号
我又试着开启变量延迟扩展，结果正确

@echo off
set str=D:\\1\新建文件夹 (2)
if defined str (
	setlocal enabledelayedexpansion
	echo !str!
	endlocal
)
pause
复制代码

terse

回复 27# 77七
是的，这里是开了延迟的，可以!str!

77七

回复 28# terse


   谢谢大佬指点！特殊字符与变量延迟扩展的关系真是奇妙！开启变量延迟扩展不当则会漏掉特殊字符“!”本身，但更多情况是成就了更多特殊字符。

aloha20200628

用本帖敲打一下 call 的功过，还是要看比较实际的测试结果，先看用于测试比对的四种方法，其各自代码如下
::方法1

set "n="&for /d /r %%d in (*) do (
	dir /b/ad "%%~d\*" 2>nul | find /v "">nul || set/a "n+=1"
)
echo,发现 %n% 个末级目录&exit/b
复制代码

::方法2

set "n="&for /d /r %%d in (*) do (
	dir /b/ad "%%~d\*" 2>nul | findstr ".">nul || set/a "n+=1"
)
echo,发现 %n% 个末级目录&exit/b
复制代码

::方法3

set "n="&for /d /r %%d in (*) do (
	set "k=" &for /f "delims=" %%a in ('dir /b/ad "%%~d\*" 2^>nul') do set "k=1"
	if not defined k set/a "n+=1"
)
echo,发现 %n% 个末级目录&exit/b
复制代码

::方法4

set "n="&for /d /r %%d in (*) do (
	set "k=" &(call :xxx "%%~d" k)
	if not defined k set/a "n+=1"
)
echo,发现 %n% 个末级目录&exit/b
:xxx
	for /r "%~1" /d %%e in (*) do (set "%~2=1"&exit/b)
	exit/b
复制代码

看如下测试结果
测试主目录及其文件和子目录体量                方法1耗时/方法2耗时/方法3耗时/方法4耗时（耗时单位=秒）
c:\a1 148,814 个文件，32,751 个文件夹  255/275/783/1149
c:\a2   30,262 个文件，  3,281 个文件夹  21/24/26/14
c:\a3   28,159 个文件，  2,114 个文件夹  13/15/15/6
c:\a4   16,916 个文件，  1,213 个文件夹  8/9/8/2
c:\a5     1,248 个文件，     717 个文件夹  4/5/4/1
从以上结果数据可见，小体量样本测试证明方法4有明显优势，但大样本比对就出现了逆转。
至少两点结论》
其一是用方法3即纯P跟读目录列表的效率会随样本体量增大锐减（此点其实是老生常谈不足为奇）；
其二是“call乃效率大杀器”的杀气要在足够大体量的数据样本中才会凸显，在a1和a2体量之间存在一个令call从“英雄变狗熊”的拐点...