[文件操作] 求助，想请教一下批处理代码的意思

pxj

之前在网上找了一个清理文件的批处理，想针对性做一些修改，发现不知道具体命令的含义，百度也没能找到，想求助一下各位大神

set DaysAgo=14
rem 假设系统日期的格式为mm-dd-YYYY
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
rd /s /q C:\test\%DstMonth%-%DstDay%-%DstYear%
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

希望大神们能讲解一下，或者提点一下思路

Batcher

回复 4# pxj


    不是多余的

pxj

回复 3# Batcher


谢谢

pxj

回复 2# flashercs

谢谢，再问一下，我原来贴的代码的其他部分是多余的吗？

Batcher

回复 1# pxj


可以参考这个帖子里面的介绍：
http://bbs.bathome.net/thread-3330-1-1.html

flashercs

REM 删除过去DaysAgo天的日期为名的目录
REM 14天前
set DaysAgo=14
rem 假设系统日期的格式为mm-dd-YYYY
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
rd /s /q C:\test\%DstMonth%-%DstDay%-%DstYear%
goto :eof
复制代码

功能:删除14天以前的日期为名称的目录.