批处理显示输入的两个字母中的所有字母

随风

新手晋级练习题 1
要求：
    输入任意两个字母，显示这两个字母中间的所有字母。
如：  输入 af 则显示英文字母a至f  如： a  b c d e f

[ 本帖最后由 随风 于 2008-1-3 23:52 编辑 ]

懒虫阿布

贴个笨方法，但是顺序不受限制

@echo off
setlocal enabledelayedexpansion

set letterstr=a b c d e f g h i j k l m n o p q r s t u v w x y z
echo 请按先后顺序输入两个字母 如：af 
set /p input=
set index=0

for %%i in (%letterstr%) do (
	if /i "%%i"=="%input:~0,1%" (
		set start=!index!
	) 
	if /i "%%i"=="%input:~1,1%" (
		set end=!index!
	) 
	set /a index+=2
)

echo !start!-!end!
if !end! lss !start! (
	set /a len=!start!-!end!+1
	set start=!end!
) else (
	set /a len=!end!-!start!+1
)

call echo %%letterstr:~!start!,!len!%%
复制代码

taofan712

各位前辈都没有用到delims=，我也来交个答案。

@echo off
set "var=abcdefghijklmnopqrstuvwxyz"
set /p input=请按先后顺序输入两个字母（如 af ，不能输入 fa）：
for /f "tokens=2 delims=%input:~0,1%%input:~1,1%" %%a in ("%var%") do echo;%%a&pause>nul
复制代码

wutarnow

@echo off
setlocal enabledelayedexpansion
set /p ch=按字母顺序输入两个字母: 
set result=这两个字母中间是:
set table=a b c d e f g h i j k o m n o p q r s t u v w x y z
for %%I in (%table%) do (
    if /i %%I GTR %ch:~1,1% goto Finish
    if /i %%I GEQ %ch:~,1% set result=!result! %%I
)
:Finish
echo %result%
复制代码

尘丶

@echo off&setlocal enabledelayedexpansion
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set /p zimu=输入两个字母
for %%a in (%str%) do (
if not %%a==%zimu:~1% (echo;%%a) else (echo;%%a&pause&exit)
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set n=
set /p zimu=输入任意两个字母:
set zimu1=%zimu:~,1%
set zimu2=%zimu:~1%
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
if %%a==%zimu1% set n=dui
if !n!==dui echo;%%a
if %%a==%zimu2% set n=cuo
)
复制代码

pause&exit

dizimotong

@echo off&setlocal enabledelayedexpansion

set char=abcdefghijklmnopqrstuvwxyz
set /p str= "请输入英文字母:"
set c1=%str:~0,1%
set c2=%str:~1,1%

for /l %%a in (0,1,25) do (
	set c3=!char:~%%a,1!
	if !c1!==!c3! set start=""
	if defined start set /p= !c3! <nul
	if !c2!==!c3! goto end
	
)
	
:end
pause
复制代码

keiamy

參考以上前輩做的

@echo off&setlocal enabledelayedexpansion
set /p var=Input Alphabet: 
set n=-2
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%str%) do (
 set /a n+=2
 set %%i=!n!)
set "star=%var:~,1%"
set "end=%var:~-1%"
set /a end1=!%end%!-!%star%!+1
call echo %%str:~!%star%!,%end1%%%
pause
复制代码

Batcher

自己单步运行一下，看看过程，思考一下。

echo 请按先后顺序输入两个字母 如：af ，不能输入 fa
set /p input= 
cls
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
  if /i "%input:~0,1%"=="%%b" set ok=ok
  if /i "%input:~1,1%"=="%%b" set ok=&echo %%b
  if defined ok echo %%b
  pause
)
echo.&pause
复制代码

yangyuankui

@echo off
echo 请按先后顺序输入两个字母 如：af ，不能输入 fa
set /p input=
cls
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
if /i "%input:~0,1%"=="%%b" set ok=ok
if /i "%input:~1,1%"=="%%b" set ok=&echo %%b
if defined ok echo %%b
)
echo.&pause&exit
set ok=ok和set ok=&echo %%b
能帮忙解释 随风

[ 本帖最后由 yangyuankui 于 2009-5-1 16:09 编辑 ]

swungod

学习学习！！！暂时！不会！

sjzong

思路：先截取第二个字母前的字符串（包括该字母），然后把第一个字母前的字符串（包括这个字母）删除，最后补上第一个字母即可

@echo off
setlocal enabledelayedexpansion
set "str= abcdefghijklmnopqrstuvwxyz"
set/p input=请按先后顺序输入两个字母（如 af ，不能输入 fa）：
cls
set/a n=0
:a
if not "%input:~1,1%"=="!str:~%n%,1!"  (set/a n+=1&goto :a)
set str=!str:~1,%n%!
set str=!str:*%input:~0,1%=!
echo %input:~0,1%!str!
echo.&pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-25 00:32 编辑 ]

energy2009

看了两天终于吧这个帖子的代码都读懂了，确实写的不错。
呵呵！谢谢版主的耐心解答！

rat

@set/ps=Plz input:&(call echo e102 '%%s%%'&more /e +1 "%~f0")|debug|findstr "^[^I\-0P]"&pause>nul&exit/b
a100
jmp 104

a104
MOV     BL,[0103]
MOV     AL,[0102]
SUB     BL,AL
LEA     CX,[BX+01]
MOV     AH,02
MOV     DL,[0102]
INT     21
INC     DL
LOOP    0116
INT     20

g
q
复制代码

Batcher

set截取字符详解
http://bbs.bathome.net/viewthread.php?tid=996

set变量字符截取点点通
http://bbs.bathome.net/viewthread.php?tid=40

新手set截取字符练习工具
http://bbs.bathome.net/viewthread.php?tid=1149

energy2009

大家都写的比较好。
我是新来的，看了几天论坛。
发现如 set var=!str:%%a=! 或者var1=%var:~0,1%，var2=%var:~-1,1%。等语句在很多地方都出现过。
不知道在这个赋值语句中后面的“：”或者“：~0，1”“：~-1，1”到底表示的什么意思。
希望前辈指点，谢谢！