[注册表类] [已解决]批处理监视注册表项

wh1234567

当监视某个注册表项名称数值为29时就执行我的命令，如果监视数值不是29就不执行命令，如何写？
例如
注册表项"HKEY_LOCAL_MACHINE\333" 里右边的名称"444" 里的数值29

我的命令放在下面

wh1234567

完全搞定，谢谢powerbat

powerbat

Hive = "HKEY_LOCAL_MACHINE"
KeyPath = "Software\333"
ValueName = "444"
shuzhi = 29
gaiwei = 20
Hive2 = "HKEY_LOCAL_MACHINE"
KeyPath2 = "Software\2012"
ValueName2 = "0610"
shuzhi2 = 98
gaiwei2 = 70
strTitle = "注册表监视"
nShowTime = 3

WQL = "Select * from RegistryValueChangeEvent Where (" & _
    "Hive = '"&Hive&"' and " & _
    "KeyPath = '"&Replace(KeyPath,"\","\\")&"' and " & _
    "ValueName = '"&ValueName&"') OR (" & _
    "Hive = '"&Hive2&"' and " & _
    "KeyPath = '"&Replace(KeyPath2,"\","\\")&"' and " & _
    "ValueName = '"&ValueName2 & "') "

Set ws = CreateObject("WScript.Shell")
CheckReg ValueName
CheckReg ValueName2
Set Sink = WScript.CreateObject("WbemScripting.SWbemSink", "SINK_")
Set objWMIServices = GetObject("winmgmts:" & _
    "{impersonationLevel=impersonate}!\\.\root\default")
objWMIServices.ExecNotificationQueryAsync Sink, WQL
ws.Popup "Listening for Registry Change Events...", nShowTime, strTitle, 4096
Do : WScript.Sleep 1000 : Loop

Sub SINK_OnObjectReady(wmiObject, wmiAsyncContext)
    'WScript.Echo wmiObject.GetObjectText_()
    CheckReg wmiObject.ValueName
End Sub

Sub CheckReg(VName)
  On Error Resume Next
  RegFullPath = Hive & "\" & KeyPath & "\" & ValueName
  RegFullPath2 = Hive2 & "\" & KeyPath2 & "\" & ValueName2
  if VName=ValueName then
      Value = ws.RegRead(RegFullPath)
      if Err then
        ws.RegWrite RegFullPath, gaiwei, "REG_DWORD"
        Err.Clear
      end if
      if CStr(Value)=CStr(shuzhi) then
        ws.Popup RegFullPath & " 变成了 " & shuzhi, nShowTime, strTitle, 4096
        ws.RegWrite RegFullPath, gaiwei, "REG_DWORD"
      end if
  end if
  if VName=ValueName2 then
      Value = ws.RegRead(RegFullPath2)
      if Err then
        ws.RegWrite RegFullPath2, gaiwei2, "REG_DWORD"
        Err.Clear
      end if
      if CStr(Value)=CStr(shuzhi2) then
        ws.Popup RegFullPath2 & " 变成了 " & shuzhi2, nShowTime, strTitle, 4096
        ws.RegWrite RegFullPath2, gaiwei2, "REG_DWORD"
      end if
  end if
End Sub
复制代码

wh1234567

回复 62# powerbat


    另外一个数值的注册表路径是：
Hive2 = "HKEY_LOCAL_MACHINE"
KeyPath2 = "Software\2012"
ValueName2 = "0610"
shuzhi2 =98（这里是指要监视的数值）
gaiwei2 =70（这里是指要修改为的数值）

powerbat

另外一个数值的注册表路径是什么？

wh1234567

回复 60# powerbat


    很感谢您，最后请求了

另外：
Hive = "HKEY_LOCAL_MACHINE"
KeyPath = "Software\333"
ValueName = "444"
shuzhi =29
gaiwei =20
这样的话
    if CStr(Value)="29" then
        ws.Popup "注册表值变成了29", 3, "通知"
        ws.RegWrite Hive&"\"&KeyPath&"\"&ValueName, 20, "REG_DWORD"
这里该如何修改呢？
如果想同时这样监视2个数值的话，不知道如何添加代码？
最后的求助了实在不好意思，完美后我就关闭问题了

powerbat

Hive = "HKEY_LOCAL_MACHINE"
KeyPath = "Software\333"
ValueName = "444"

On Error Resume Next
Set ws = CreateObject("WScript.Shell")
SINK_OnObjectReady 0, 0
Set Sink = WScript.CreateObject("WbemScripting.SWbemSink", "SINK_")
Set objWMIServices = GetObject("winmgmts:" & _
    "{impersonationLevel=impersonate}!\\.\root\default")
objWMIServices.ExecNotificationQueryAsync Sink, _
    "Select * from RegistryValueChangeEvent Where " & _
    "Hive = '"&Hive&"' and " & _
    "KeyPath = '"&Replace(KeyPath,"\","\\")&"' and " & _
    "ValueName = '"&ValueName&"'"
WScript.Echo "Listening for Registry Change Events..." & vbCrLf
Do : WScript.Sleep 1000 : Loop

Sub SINK_OnObjectReady(wmiObject, wmiAsyncContext)
    Value = ws.RegRead(Hive&"\"&KeyPath&"\"&ValueName)
    'WScript.Echo Value
    if CStr(Value)="29" then
        ws.Popup "注册表值变成了29", 3, "通知"
        ws.RegWrite Hive&"\"&KeyPath&"\"&ValueName, 20, "REG_DWORD"
    end if
End Sub
复制代码

wh1234567

回复 53# powerbat

你好，辛苦您了，不知道你还能不能再按照56楼的更新下这个vbs 呢？

zqz0012005

不听老人言，吃亏在眼前！
此帖可以说是最长最无聊的帖子！
人家早就说了让你把代码帖出来，你偏不听，非说自己代码和别人一样，结果怎样？而且自己有什么需求、碰到什么问题都不描述清楚，靠别人像挤牙膏似的问一点你才说一点，把大家的耐心都耗尽了，最终没人愿意回答你的问题了。楼主应该好好学一下提问的方法。
提问的智慧 http://www.bathome.net/thread-4054-1-1.html

forfiles

回复 55# bluewing009


    我表示看不懂。目测楼主更看不懂。

wh1234567

回复 53# powerbat

不好意思，我找到错误的原因了，是因为自动执行a.bat，这个批处理将444删除了导致会弹出那个错误窗口
你修正下那个当第一次运行时如果原数值就是29的话无法执行a.bat的问题吧
另外，我想能不能将第一次运行时弹出的窗口和数值变化时弹出的窗口过3秒钟后自动关闭，不需要手动点击确定的那种，还有与其发现数值是29时执行a.bat还不如直接用vbs将数值29自动修改为20，你看行不行，那个a.bat就不需要了。
标题能不能显示为：注册表监视小工具

bluewing009

我记得我写了一个例子，监控注册表的……………………如果你看那个有问题再问我。

wh1234567

打开一个cmd，按37楼的步骤把那些红色的命令逐条运行一次，确认没问题能正常执行，也不弹出错误窗口。
但是如果直接运行a.vbs的话当数值变化成29时就会弹出那个错误窗口，同时也会自动执行a.bat。
为什么？

powerbat

你说按37楼的步骤测试能行，那为什么还会出现第2个问题“弹出错误窗口”？出现错误了就说明不可行，你为什么要说测试可行呢？
不知道该说你可爱呢还是天真。。。

wh1234567

在线等......