[文件操作] 批处理怎样批量压缩文件夹？

leap

请问这样可以吗？
还有更好的吗？谢谢指导
还有这么指定压缩文件的存放位置rar里有这个参数吗？

@echo off
set mm=
set/p mm=请输入压缩密码：
echo 首先寻找您的系统中RAR程序的完整路径保存在RAR.TXT，如果c盘找不到，请把c改成其它盘
for /r c:\ %%i in (rar.exe) do (if exist %%i echo %%~fi>rar.txt)
echo 定义RAR.EXE路径为aa
for /f "delims=, tokens=1" %%1 in (rar.txt) do (set aa=%%1)
echo 复制RAR到系统system32下，也可以复制到和该批处理同一目录下
copy "%aa%" "%systemroot%\system32\"
echo 最后批量执行压缩文件夹
for /d %%i in (*) do start rar a -hp%mm% %%i.rar %%i
del rar.txt
exit
复制代码

[ 本帖最后由 leap 于 2010-9-24 20:36 编辑 ]

skdu7e

@echo off&color a&title 拖放式解压文件及压缩文件
for /f "tokens=2 delims==" %%a in ('ftype WinRAR') do set a=%%a
set "winrar=%a: "%1"=%"
if "%~x1"==".rar" (%winrar% x %~nx1) else %winrar% a %~n1.rar %~nx1
复制代码

skdu7e

这个只能一次压缩或解压一个，建议用变量数组保存拖放的文件绝对路径以及另外一个变量数组存放文件扩展名

Batcher

@echo off
set "rar=C:\Program Files\WinRAR\rar.exe"
"%rar%" a "C:\test\a.rar" "C:\test\a.txt"
复制代码

@echo off
for /f "tokens=2 delims==" %%a in ('ftype WinRAR') do (
    set "rar=%%~dparar.exe"
)
"%rar%" a "C:\test\a.rar" "C:\test\a.txt"
复制代码

@echo off
for /f "tokens=1,2 delims=:" %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\WinRAR.exe" /v Path') do (
    set RarPathL=%%a
    set RarPathR=%%b
)
set "rar=%RarPathL:~-1%:%RarPathR%\rar.exe"
"%rar%" a "C:\test\a.rar" "C:\test\a.txt"
复制代码