[网络连接] [已解决]IP获取类型判断的批处理为什么出错？

xieqingx

@echo off
setlocal EnableDelayedExpansion
for /f "tokens=14" %%a in ('ipconfig /all^|find /I "Dhcp Enabled"') do (
set dhcp=%%a
echo dhcp=!dhcp!
if !dhcp!== No (echo 固定IP) else (echo 动态IP)
pause
)
复制代码

我想通上面那段代码判断，本机的IP获取类型。可以结果却判断错误。
我的电脑是设的固定IP  DHCP ENABLE是为No
我就搞不懂了，!dhcp!这个变量是等于No啊，为什么
if !dhcp!== No (echo 固定IP) else (echo 动态IP)  这个条件会不成立呢？
结果总是输出动态IP，在这里为什么!dhcp!== No 不成立啊
echo !dhcp!显示是为No，头大啊，弄不懂了??????
兄台帮帮解释一下

[ 本帖最后由 xieqingx 于 2010-3-13 22:31 编辑 ]

BatCoder

if "!dhcp!" equ "No" (echo 固定IP) else (echo 动态IP)
复制代码

xieqingx

也是一样不行啊也是一样不行啊

BatCoder

@echo off
setlocal EnableDelayedExpansion
for /f "tokens=14" %%a in ('ipconfig /all ^| find /i "Dhcp Enabled"') do (
    set "dhcp=%%a"
    set "dhcp=!dhcp:~0,2!"
    if "!dhcp!" equ "No" (
        echo 固定IP
    ) else (
        echo 动态IP
    )
    pause
)
复制代码

xieqingx

set "dhcp=%%a"    此时值已经是No
    set "dhcp=!dhcp:~0,2!"    重新截取字符No

楼上正解，请问为什么要重新截取字符呢？解释一下可以吗

BatCoder

你把ipconfig /all的结果输出到一个文本文件里面，用十六进制编辑器打开，就会发现行尾有个多余的回车符，而不仅仅是通常的回车+换行。

hfg1977

@echo off&setlocal enabledelayedexpansion&cls
for /f "tokens=14" %%a in ('ipconfig /all^|find /I "Dhcp Enabled"') do (
set dhcp=%%a
echo !dhcp!rt
set "dhcp=!dhcp:~0,2!"
echo !dhcp!rt
)
复制代码

楼上正解!  "NO"后面还存在不可见的控制字符!

xieqingx

原来如此啊，这个问题弄的我头大的很。谢谢各位