随风

以下代码会修改INTL.INF，先备份INTL.INF文件。。。

@echo off
(for /f "delims=" %%i in ('findstr /iv "simsun.ttc,,,65536" INTL.INF') do (
   set "str=%%i"
   setlocal enabledelayedexpansion
   set str=!str:e00e0804=e0860804!
   set str=!str:pintlgnt.ime=sun86.ime!
   set num=!str:pintlgnt=!
   if "!num!"=="!str!" echo;!str!
   if /i "!str!"=="[sourcedisksfiles]" (
      echo Sun86.IME    = 107,,,,,,,0,0
      echo Sun86.mb     = 107,,,,,,,0,0
      echo Sun86.chm    = 107,,,,,,,0,0
   )
   endlocal
))>tem
move tem INTL.INF
start "" "INTL.INF"
复制代码

随风

把内容加到第一个[sourcedisksfiles]后面
:

@echo off
(for /f "delims=" %%i in ('findstr /iv "simsun.ttc,,,65536" INTL.INF') do (
   set "str=%%i"
   if /i "%%i"=="[sourcedisksfiles]" set /a flag+=1
   setlocal enabledelayedexpansion
   set str=!str:e00e0804=e0860804!
   set str=!str:pintlgnt.ime=sun86.ime!
   set num=!str:pintlgnt=!
   if "!num!"=="!str!" echo;!str!
   if !flag! equ 1 (
      echo Sun86.IME    = 107,,,,,,,0,0
      echo Sun86.mb     = 107,,,,,,,0,0
      echo Sun86.chm    = 107,,,,,,,0,0
   )
   endlocal
))>tem
move tem INTL.INF
start "" "INTL.INF"
复制代码

随风

11楼代码确实会导致在[sourcedisksfiles]之后，下一个[sourcedisksfiles]之前的每一行都插入内容，代码未测试，大意了 ^_^

还真没主意，是要加在[sourcedisksfiles]段的最后面，一直以为是加在它下面呢
如果要加在[sourcedisksfiles]段的最后，则必须知道它的下一个段名，应该很容易解决

随风

为了能处理文本中的半角！号，还真费了翻功夫。。。

@echo off
set wjm=a.txt
(for /f "delims=" %%i in ('findstr /ivn "simsun.ttc,,,65536" %wjm%') do (
   set "str=%%i"
   if defined h set "h="
   if not defined v (
      for /f "tokens=1* delims=:" %%j in ("%%i") do (
         if /i "%%k"=="[sourcedisksfiles]" set s=1
         if defined s if /i "%%k"=="[Locales]" set h=a&set v=a&set "s="
       )
    )
   setlocal enabledelayedexpansion
   set str=!str:*:=!
   if not defined str (echo;) else (
      set str=!str:e00e0804=e0860804!
      set str=!str:pintlgnt.ime=sun86.ime!
      set num=!str:pintlgnt=!
      if defined h (
         echo Sun86.IME    = 107,,,,,,,0,0
         echo Sun86.mb     = 107,,,,,,,0,0
         echo Sun86.chm    = 107,,,,,,,0,0
       )
      if "!num!"=="!str!" echo;!str!
   )
   endlocal
))>tem
move tem "%wjm%"
start "" "%wjm%"
复制代码

[ 本帖最后由 随风 于 2011-1-10 16:04 编辑 ]

随风

也说说我的代码，得到代码后能认真研读的好像真不是很多，赞一个先 ^_^
先说说代码功能：
由于不懂inf文件的特性，所以是把它当作任意文本来处理的，所以就必须考虑某些特殊情况
比如：
1、文本内容含半角！符号
2、[sourcedisksfiles]和[Locales]段名有可能出现在文本的任意位置，且不一定是成对出现。

if defined v 是判断变量名为v的是否被定义过，自然 if not defined 则是判断v是否没被定义过
所以 set h=a&set v=a 只是为了给这两个变量定义，值是什么不重要，重要的是这两个变量被定义了，也就是这两个变量存在，而set "v="则是清空变量v的值，也就是变量v不存在了。
for 循环到[sourcedisksfiles]行时，变量 s 被定义，这相当一个开关，告诉代码在这之后若遇到[Locales]则插入新内容，也就是执行if defined h 里的命令，也就是在此后遇到[Locales]时需给变量h定义，if defined h 里的命令才会执行。
if defined s if /i "%%k"=="[Locales]" set h=a&set v=a&set "s="
当变量s被定义，也就是已经找到[sourcedisksfiles]后，若该行为[Locales]则set h=a&set v=a&set "s="定义h的作用前面已经说了，那定义 v和清空s呢？
定义v是为了配合if not defined v 这句，否则在下次遇到这两个段名时，又会重复执行。清空变量s，这句好像多余了，应该可以不要，因为定义了变量v，里面的代码就不会在执行了。