xczxczxcz

太简单了，大神不愿写。

xczxczxcz

偶不是大神，不过这个确实简单

不考虑txt文件的排名顺序：

@echo off
setlocal EnableDelayedExpansion
set /p 添加尾数= 输入你要在每行末尾添加的字符并回车：
del /q "%~dp0合并.txt">nul 2>nul
cd.>"%temp%\合并.txt"
for /f "delims=" %%a in ('dir/b "*.txt"') do (
      for /f "delims=" %%i in ('type "%%a"') do (
	      for /f "delims=" %%m in (%temp%\合并.txt) do if /i "%%i" == "%%m" set "真假=TRUE"
		  if /i "!真假!" neq "TRUE" echo %%i>>"%temp%\合并.txt"
		  set "真假="
		)
	)
cd.>"%~dp0合并.txt"
for /f "delims=" %%a in (%temp%\合并.txt) do echo %%a%添加尾数%>>"%~dp0合并.txt"
del /q "%temp%\合并.txt"
pause
复制代码

把批处理放在你的放txt的，txt文件名可以有空格
如要考虑顺序的话前面要改一改。

xczxczxcz

给你来个好点的

文件夹 文件名 都支持空格，可以随意起名。把下面命令保存为 【合并文本.cmd】即可。也可任意取。
批处理放在电脑的任意位置，把你的文件夹拖到该批处理上即可。
新方法比原来的要快些。

@echo off & setlocal EnableDelayedExpansion

for /f "delims=" %%a in ("%~1\..") do set "保存位置=%%~fa"
del /q "%保存位置%\合并.txt">nul 2>nul
cd.>"%temp%\合并.txt"
set /p 添加文字= 输入你要在每行末尾添加的字符并回车：
for /f "delims=" %%a in ('dir/b "%~1\*.txt"') do (
      for /f "delims=" %%i in ('type "%~1\%%a"') do (
	      set/p=合并文本   → %%i <nul
	      call :LOOP %%i
		  if /i "!重复!" neq "TRUE" (echo. & echo %%i%添加文字%>>"%temp%\合并.txt") else echo ——重复
		  set "重复="
		)
	)
echo.
move /y "%temp%\合并.txt" "%保存位置%\"
set/p=文件保存在 [%保存位置%] 目录下<nul & pause & exit

:LOOP
for /f "delims=" %%m in (%temp%\合并.txt) do if /i "%%i%添加文字%" == "%%m" (set "重复=TRUE" & goto :eof )
goto :eof
复制代码

==================================

xczxczxcz

回复 16# 修修的想法

乱码一般是你的TXT文件不是ANSI编码的。 偶测试没问题，没有乱码。

现用 版主优化的。用not defined 代替 for 遍列循环。

@echo off & setlocal EnableDelayedExpansion

for /f "delims=" %%a in ("%~1\..") do set "保存位置=%%~fa"
del /q "%保存位置%\合并.txt">nul 2>nul
cd.>"%temp%\合并.txt"
set /p 添加文字= 输入你要在每行末尾添加的字符并回车：
for /f "delims=" %%a in ('dir/b "%~1\*.txt"') do (
      for /f "delims=" %%i in ('type "%~1\%%a"') do (
	      set/p=合并文本   → %%i <nul
		  if not defined %%i (echo.&echo %%i%添加文字%>>"%temp%\合并.txt") else echo ——重复
		  set "%%i=#"
		)
	)
echo.
move /y "%temp%\合并.txt" "%保存位置%\"
set/p=文件保存在 [%保存位置%] 目录下<nul & pause & exit
复制代码

偶测试 速度嗖嗖的。

xczxczxcz

回复 12# Batcher

用 defined 代替 loop那个 for 循环后，速度快了好多。

xczxczxcz

回复  xczxczxcz


感谢 感谢 一个个测试了 确实是 格式的问题
修修的想法 发表于 2018-8-10 18:49

@echo off

for /f "delims=" %%a in ("%~1\..") do set "保存位置=%%~fa"
cd.>"%保存位置%\合并.txt"
set /p 添加文字= 输入你要在每行末尾添加的字符并回车：
for /f "delims=" %%a in ('dir/b "%~1\*.txt"') do (
   iconv -c -s -f utf-8 -t gbk "%~1\%%a">"%~1\%%a.tmp"
      for /f "delims=" %%i in ('type "%~1\%%a.tmp"') do (
	      set/p=合并文本   → %%i <nul
		  if not defined %%i (echo.&echo %%i%添加文字%>>"%保存位置%\合并.txt") else echo ——重复
		  set "%%i=#"
		)
	)
echo.
del /q "%~1\*.tmp"
set/p=文件保存在 [%保存位置%] 目录下<nul & pause & exit
复制代码

这个带了转码的。到官网下载 iconv.exe 或在本坛下载 win_iconv.exe 放到 系统 system32目录下。或与批处理放在一起。
。

xczxczxcz

回复 24# 修修的想法

不要用于违法活动。虽然偶很少用 qq

@echo off
for /f "delims=" %%a in ("%~1\..") do set "保存位置=%%~fa"
cd.>"%保存位置%\合并.txt"
set /p 添加文字= 输入你要在每行末尾添加的字符并回车：
for /f "delims=" %%a in ('dir/b "%~1\*.txt"') do (
   iconv -c -s -f utf-8 -t gbk "%~1\%%a">"%~1\%%a.tmp"
      for /f "delims=" %%i in ('type "%~1\%%a.tmp"') do (
	      set/p=合并文本   → %%i <nul
		  if not defined %%i (echo.&echo %%i%添加文字%>>"%保存位置%\合并.txt") else echo ——重复
		  set "%%i=#"
		)
	)
echo.
del /q "%~1\*.tmp"
setlocal EnableDelayedExpansion
set/a file+=1
for /f "delims=" %%a in (%保存位置%\合并.txt) do (
  set/a number+=1
  if !number! LEQ 1 set/p var=请输入第 !file! 文本的名称，回车继续：
  if !number! LEQ 1000 echo %%a>>!var!.txt
  if !number! EQU 1000 (set/a number=0 & set/a file+=1)
  )
Endlocal
pause & exit
复制代码

xczxczxcz

回复 26# 修修的想法

把你要处理的那个文件夹拖上来，是一起处理的。不是单个运行的。