neorobin

楼主顶楼的竖排文字很难读

以下代码中 /mo 后面的数字 即为 时间间隔, 单位 分钟
ipa, ipb, mask, gateway 各变量请楼主根据自己的要求自行改动, 我在自己机器上已测试可正常运行.

@echo off & setlocal enabledelayedexpansion
set "taskName=IP_Switch"
if not exist "%windir%\tasks\!taskName!.job" (
   rem 确保 Task Scheduler 服务启动
   sc config Schedule start= Auto>nul
   (sc query Schedule | find "RUNNING">nul) || (
   ((sc query Schedule | find "PAUSED">nul) && sc continue Schedule) || sc start Schedule
   )
   rem 建立计划任务运行本程序
   schtasks /create /tn "!taskName!" /sc minute /mo 2 /tr %~s0 /ru system
)
rem 要运行的任务的实体
set "ipa=192.168.1.101" & set "ipb=192.168.1.102" & set "mask=255.255.255.0" & set "gateway=192.168.1.1"
for /f "tokens=2 delims=[]" %%i in ('ping -n 1 %computername% ^| find "["') do (
  for /f %%a in ('wmic nicconfig where "ipenabled='true'" get index') do (
    if /i "%%a" neq "index" (
      for /f "delims=}{" %%b in ('wmic nicconfig where "index=%%a" get ipaddress') do (
        if "%%~b"=="%%i" for /f "skip=1" %%c in ('wmic nic where "index=%%a" get NetConnectionID') do (
          if "%%~b"=="!ipa!" (netsh interface ip set address name="%%c" source=static addr=!ipb! mask=!mask! gateway=!gateway! 1
          ) else (
            netsh interface ip set address name="%%c" source=static addr=!ipa! mask=!mask! gateway=!gateway! 1
          )
        )
      )
    )
  )
)
复制代码

neorobin

4 楼是利用的计划任务, 不够完善, 下面给出直接批处理循环, 但批处理程序不能关闭

@echo off & setlocal enabledelayedexpansion
call :foundACName ACName
set "ipa=192.168.1.101" & set "ipb=192.168.1.102" & set "mask=255.255.255.0" & set "gateway=192.168.1.1"
set /a mm=1!time:~3,2!-100, ms=2 & rem ms 为时间间隔
for /l %%k in (0 0 0) do (
  set /a "diff=1!time:~3,2!-100+60-mm, diff%%=60"
  if !diff! geq !ms! ( set /a mm=1!time:~3,2!-100
    for /f "tokens=2 delims=[]" %%i in ('ping -n 1 %computername% ^| find "["') do (
      if "%%i"=="!ipa!" (netsh interface ip set address name="!ACName!" source=static addr=!ipb! mask=!mask! gateway=!gateway! 1
      ) else (
        netsh interface ip set address name="!ACName!" source=static addr=!ipa! mask=!mask! gateway=!gateway! 1
      )
      for /f "tokens=2 delims=[]" %%a in ('ping -n 1 %computername% ^| find "["') do echo %%a
    )
  )
)
exit /b

:foundACName ACName rem 找出当前活动连接的名称
for /f "tokens=2 delims=[]" %%i in ('ping -n 1 %computername% ^| find "["') do (
  for /f "skip=1" %%a in ('wmic nicconfig where "ipenabled='true'" get index') do (
    for /f "delims=}{" %%b in ('wmic nicconfig where "index=%%a" get ipaddress') do (
      if "%%~b"=="%%i" for /f "tokens=1-2 delims==" %%c in ('wmic nic where "index=%%a" get NetConnectionID /value') do (
        for /f "delims=" %%z in ("%%d") do set "_%%c=%%z"
      )
    )
  )
)
set %1=!_NetConnectionID!&echo 当前活动连接为: "!%1!"
exit /b
复制代码

另给出一个实时监控显示 IP 的代码:

@echo off & setlocal enabledelayedexpansion& set "color=02"& color !color!&mode con lines=1 cols=28
for /l %%i in (0 0 0) do for /f "tokens=2 delims=[]" %%a in ('ping -a -n 1 %computername% ^| find "["') do (
  if "%%a" neq "!ip!" set ip=%%a&set color=!color:~1!!color:~0,-1!&color !color!
  cls&set /p=!time! %%a<nul
)
复制代码

[ 本帖最后由 neorobin 于 2010-6-24 21:54 编辑 ]

neorobin

取消 变量 mm 的第一次赋值即可,即 把这行

set /a mm=1!time:~3,2!-100, ms=2 & rem ms 为时间间隔
复制代码

改为

set /a ms=2 & rem ms 为时间间隔
复制代码

另外 11 楼的代码重新编辑过的, 发 11 楼帖时的代码是不支持 连接名称中含有 空格的, 现在修改过的可兼容含 空格 的连接名称, 请重新复制代码

[ 本帖最后由 neorobin 于 2010-6-24 22:10 编辑 ]

neorobin

这个我不会, 但有一种隐藏运行的技术

@echo off & setlocal enabledelayedexpansion
if /i "%1" equ "hide" goto begin
if /i "%1" equ "show" goto begin

set /p show=需要显示窗口界面吗^(y/n^)[直接回车=不显示]:)
if /i "%show:~0,1%" equ "y" goto begin
(call :showWindow hide)

:begin

call :foundACName ACName
set "ipa=192.168.1.101" & set "ipb=192.168.1.102" & set "mask=255.255.255.0" & set "gateway=192.168.1.1"
set /a ms=2 & rem ms 为时间间隔
for /l %%k in (0 0 0) do (
  set /a "diff=1!time:~3,2!-100+60-mm, diff%%=60"
  if !diff! geq !ms! ( set /a mm=1!time:~3,2!-100
    for /f "tokens=2 delims=[]" %%i in ('ping -n 1 %computername% ^| find "["') do (
      if "%%i"=="!ipa!" (netsh interface ip set address name="!ACName!" source=static addr=!ipb! mask=!mask! gateway=!gateway! 1
      ) else (
        netsh interface ip set address name="!ACName!" source=static addr=!ipa! mask=!mask! gateway=!gateway! 1
      )
      for /f "tokens=2 delims=[]" %%a in ('ping -n 1 %computername% ^| find "["') do echo %%a
    )
  )
)
exit /b

:foundACName ACName rem 找出当前活动连接的名称
for /f "tokens=2 delims=[]" %%i in ('ping -n 1 %computername% ^| find "["') do (
  for /f "skip=1" %%a in ('wmic nicconfig where "ipenabled='true'" get index') do (
    for /f "delims=}{" %%b in ('wmic nicconfig where "index=%%a" get ipaddress') do (
      if "%%~b"=="%%i" for /f "tokens=1-2 delims==" %%c in ('wmic nic where "index=%%a" get NetConnectionID /value') do (
        for /f "delims=" %%z in ("%%d") do set "_%%c=%%z"
      )
    )
  )
)
set %1=!_NetConnectionID!&echo 当前活动连接为: "!%1!"
exit /b

:showWindow
if /i "%1" equ "hide" (set intWindowStyle=0) else (set intWindowStyle=5)
mshta vbscript:createobject("wscript.shell").run("%~snx0 %1",!intWindowStyle!)(window.close)&&exit
exit /b
复制代码

要想关闭隐藏的 cmd , 可以用一种野蛮的方式关闭所有的 cmd

taskkill /f /t /im cmd.exe
复制代码

[ 本帖最后由 neorobin 于 2010-6-24 23:07 编辑 ]

neorobin

@echo off & setlocal enabledelayedexpansion
if /i "%1" equ "hide" goto begin
if /i "%1" equ "show" goto begin
rem 直接隐藏运行的方法: 删除或注解下面的一行
set /p show=需要显示窗口界面吗^(y/n^)[直接回车=不显示]: 
if /i "%show:~0,1%" equ "y" goto begin
(call :showWindow hide)

:begin
set "ACName=本地连接"
(call :findACName ACName) & rem 不用搜索活动连接的话, 删除或注解本行.
set /a ipts=2,ipte=9,ipt=3& rem ipts--ipte 指定可用的 ip 地址范围, 例如: 192.168.0.2--192.168.0.9, ipt 取范围中的任一值.
set "iph=192.168.0." & set "mask=255.255.255.0" & set "gateway=!iph!1" & set ms=120 & rem ms: 时间间隔秒数
netsh interface ip set address "!ACName!" static !iph!!ipt! !mask! !gateway! 1
for /l %%k in (0 0 0) do (
  set /a "ipt=(ipt+1-ipts)%%(ipte-ipts+1)+ipts"
  netsh interface ip set address "!ACName!" static !iph!!ipt! !mask!
  for /f "tokens=2 delims=[]" %%a in ('ping -n 1 %computername% ^| find "["') do echo %%a
  ping -n !ms! 127.1>nul
)
exit /b

:findACName ACName rem 找出当前活动连接的名称
for /f "tokens=2 delims=[]" %%i in ('ping -n 1 %computername% ^| find "["') do (
  for /f "skip=1" %%a in ('wmic nicconfig where "ipenabled='true'" get index') do (
    for /f "delims=}{" %%b in ('wmic nicconfig where "index=%%a" get ipaddress') do (
      if "%%~b"=="%%i" for /f "tokens=1-2 delims==" %%c in ('wmic nic where "index=%%a" get NetConnectionID /value') do (
        for /f "delims=" %%z in ("%%d") do set "_%%c=%%z"
      )
    )
  )
)
set %1=!_NetConnectionID!&echo 当前活动连接为: "!%1!"
exit /b

:showWindow
if /i "%1" equ "hide" (set intWindowStyle=0) else (set intWindowStyle=5)
mshta vbscript:createobject("wscript.shell").run("%~snx0 %1",!intWindowStyle!)(window.close)&&exit
exit /b
复制代码