[分享]批处理分段法计算字符串长度

netbenton

受到拆半算法的启发，突然想到这种分段法。与大家分亨，不知道是否已有先例。
此方法无论是通用性和速度,都具有很大的优越性。

 
@echo off&setlocal enabledelayedexpansion
set str=
:rep
 
:::::串长度计算代码:::::::::
set/a end=8189,add=end
:lp
if %add%==1 goto :ok
set /a ben=end-add,add=^(end-ben^)/30+1
for /l %%a in (%ben%,%add%,%end%) do (if "!str:~%%a,1!"=="" set end=%%a&goto :lp)
set end=0
:ok
:::::::::::::::::::::::::::::::
 
 
::测试用代码
echo %end%
set str=!str!a
pause
goto :rep
复制代码

netbenton

改了一下，减少了一次goto :lp循环，并且for /l 次数也从30降为21,速度有所提升

@echo off&setlocal enabledelayedexpansion
set str=
:rep


set/a end=8189,add=end
:lp
if %add%==1 goto :ok
set /a ben=end-add,add=^(end-ben+20^)/21
for /l %%a in (%ben%,%add%,%end%) do (if "!str:~%%a,1!"=="" set end=%%a&goto :lp)
set end=0
:ok
echo %end%



set str=!str!a
pause
goto :rep
复制代码

二楼说的最简单的方法应该是这个吧：
str 为字符串变量

 
if not defined str set num=0&goto :ok
for /l %%a in (0,1,8189) do (if "!str:~%%a,1!"=="" set num=%%a&goto :ok)
:ok
复制代码

此法并非不可用，只是效率一般，串越长越慢
虽然只有一个for ，并且for /l的速度很快，但是也需要时间的
因为在系统在解释for /l时已经分配了8189次if "!str...命令行

[ 本帖最后由 netbenton 于 2009-4-23 17:56 编辑 ]

netbenton

又改了一下，把8189改成了8190，否则最后一段取不到结果
写成函数如下：

:::::::::::::::::::::::::::::::::::::::::
:getstrlen  分段法取字符串长度
::  用法用途：
::  把代码放到批处理中作为函数使用
::  取指定字答串的长度
::  调用方法：
::  call :getstrlen 字符串变量名 结果变量名
::::::::::::::::::::::::::::::::::::::::::

setlocal enabledelayedexpansion
set "str=!%1!"
:rep
set/a end=8190,add=end
:lp
if %add%==1 goto :ok
set /a ben=end-add,add=^(end-ben+20^)/21
for /l %%a in (%ben%,%add%,%end%) do (if "!str:~%%a,1!"=="" set end=%%a&goto :lp)
set end=0
:ok
endlocal&set %2=%end%&goto :eof
复制代码

netbenton

 
@echo off&setlocal enabledelayedexpansion
set str=
:rep
 
::变量ds用来指定分段数,可随意指定（2到8190）都可以。
set/a ds=4,ds1=ds-1
 
if not defined str set end=-1&goto :ok
set/a end=0,add=8190
for /l %%a in (0,1,14) do (
 if !add!==1 goto :ok
 set /a end+=add,ben=end-add,add=^(end-ben+ds1^)/ds
 for /l %%b in (!ben!,!add!,!end!) do (if not "!str:~%%b,1!"=="" set end=%%b)
)
:ok
set /a end+=1
echo !end! !str!
 
set str=!str!a
pause
goto :rep
复制代码

可以做到随意n分段，分为2段时，就像随风版主的拆半法了，到底分多少段才是最快速的呢？