批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求助BAT脚本批量替换不同目录同名文件 [打印本页]

作者: haichuan5121 时间: 2023-1-16 16:41 标题: 求助BAT脚本批量替换不同目录同名文件

大神好：
在桌面文件夹 A 下有数十个.exe类型文件；
需要把C盘下B文件夹及其子文件夹下查找与桌面A 内同名的文件并替换掉；怎么搞呢？

作者: 77七 时间: 2023-1-16 16:49

用文件夹A中的文件替换掉文件夹B中的文件，还是相反呢？
同名包括扩展名吗？

作者: haichuan5121 时间: 2023-1-16 16:58

回复 2# 77七

用A中的文件替换B的包括扩展名都是.EXE执行文件

作者: Batcher 时间: 2023-1-16 17:10

回复 1# haichuan5121

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
REM 从哪个文件夹复制
set "OldFolder=%userprofile%\桌面\A"
REM 复制到哪个文件夹
set "NewFolder=C:\B"

if not exist "%OldFolder%\" (
    echo 找不到文件夹 "%OldFolder%"
)
if not exist "%NewFolder%\" (
    echo 找不到文件夹 "%NewFolder%"
)
cd /d "%OldFolder%"
for /f "delims=" %%i in ('dir /b /a-d *.exe') do (
    echo 正在处理文件：%%i
    for /f "delims=" %%j in ('dir /b /s /a-d "%NewFolder%\%%i" 2^>nul') do (
        copy /y "%%i" "%%~dpj"
    )
)

:End
pause
复制代码

作者: 77七 时间: 2023-1-16 17:38

@echo off
set /p aDir=请拖动文件夹A到此处:
set /p bDir=请拖动文件夹B到此处:
cd /d "%bDir%\"
for /f "delims=" %%i in ('dir /b /s /a-d *.exe') do (
	if exist "%aDir%\%%~nxi" (
		copy /y "%aDir%\%%~nxi" "%%~dpi"
	)
)
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)