for /f "tokens=1-2* delims=第集" %%a in ('dir /b /a-d "*.mp3"') do ...
复制代码

@echo off
setlocal enabledelayedexpansion
for %%i in (一 二 三 四 五 六 七 八 九 十) do (
set /a x+=1
set _%%i=!x!
)
for /f "tokens=1-2* delims=第集" %%a in ('dir /b /a-d "*.mp3"') do (
	set str=%%b
	set m1=!str:~,2!
	set m2=!str:~2,1!
	if "!m1:~,1!"=="十" (
		set /a n=10+_!m1:~1,1!
	) else if "!m1:~1,1!"=="十" (
		set /a n=_!m1:~,1!*10+_!m2!
	) else (
		set /a n=_!m1!
		set n=0!n!
	)
	rem set n=!n:~-2!
	ren "%%a第%%b集%%c" "%%a第!n!集%%c"
)
endlocal
复制代码

@echo off
set m=3
setlocal enabledelayedexpansion
for %%i in (一 二 三 四 五 六 七 八 九) do (
    set /a x+=1
    set /a _%%i=!x!
    set y=1
    for %%j in (十 百 千) do (
        set /a y*=10
        set /a _%%i%%j=!x!*!y!
    )
)
set _十=10
for /f "tokens=1,2* delims=第集" %%a in ('dir /b /a-d "*.mp3"') do (
    if "%%c"=="" (
        set str=%%a
    ) else (
        set str=%%b
    )
    set str=!str:零=!
    for %%i in (十 百 千) do set str=!str:%%i=%%i !
    set n=10000
    for %%j in (!str!) do set /a n+=_%%j
    if "%%c"=="" (
        ren "第%%a集%%b" "第!n:~-%m%!集%%b"
    ) else (
        ren "%%a第%%b集%%c" "%%a第!n:~-%m%!集%%c"
    )
)
pause
复制代码