@echo off
for /r %%i in ("*.txt") do (
    for /f %%a in ('type "%%i"^|find /c "<img"') do (
        ren "%%i" "%%~ni（共%%a张图片）.txt"
    )
)
pause&exit
复制代码

@echo off
PowerShell "dir . -Filter *.txt -Recurse | forEach{$str=[IO.File]::ReadAllText($_.FullName); $n=($str -split '<img').Count-1; ren $_.FullName -NewName($_.BaseName + '（' + $n + '）' + $_.Extension) -WhatIf}"
pause
复制代码

@echo off
setlocal enabledelayedexpansion
set "SrcFolder=D:\Test\测试文件\"
if not exist "%SrcFolder%" (
    goto :eof
) else (
    cd /d "%SrcFolder%"
)
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
    for /f "delims=" %%b in ('grep -o "<img" "%%a" ^| find /c /v ""') do (
        ren "%%a" "%%~na（共%%b张图片）%%~xa"
    )
)
复制代码

@if (0)==(0) echo off
for /f "tokens=1*" %%i in ('dir /b /a-d /s *.txt ^| cscript //nologo //e:jscript "%~f0"') do (
    echo ren "%%j" "%%~nj（%%i）%%~xj"
)
pause & exit
@end

function getStrNumber(file){
    var ado = new ActiveXObject('ADODB.Stream');
    ado.Type = 2;
    ado.Mode = 3;
    ado.Charset = 'utf-8';
    ado.Open();
    ado.LoadFromFile(file);
    return ado.ReadText(-1).split('<img').length - 1;
}

while(!WSH.StdIn.AtEndOfStream){
    var f = WSH.StdIn.ReadLine();
    WSH.Echo('' + getStrNumber(f) + ' ' + f);
}
复制代码

@echo off
for /f "delims=" %%i in ('dir /b /a-d /s *.txt') do (
    for /f %%j in ('sed "s/<img/\n&/g" "%%i" ^| find /c "<img"') do (
        echo ren "%%i" "%%~ni（%%j）%%~xi"
    )
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /r %%i in ("*.txt") do (
    set n=0
    for /f "delims=" %%a in ('type "%%i"') do (
        set str=%%a
        set "str=!str:img alt= <img alt!"
        for %%k in (!str!) do (
            set var=%%k
            if not "!var!"=="!var:<img=!" set /a n+=1
        )
    )
    ren "%%i" "%%~ni（共!n!张图片）%%~xi"
)
pause&exit
复制代码

@echo off
setlocal enabledelayedexpansion
for /r %%i in ("*.txt") do (
    set n=0
    for /f "delims=" %%a in ('type "%%i"') do (
        set "str=%%a"
        set "str=!str:img alt= <img alt!"
        set "str=!str:"=!"
        for %%k in (!str!) do (
            if "%%k"=="<img" set /a n+=1
        )
    )
    ren "%%i" "%%~ni（共!n!张图片）%%~xi"
)
pause&exit
复制代码

@echo off & setlocal enabledelayedexpansion
chcp 65001
for /f "delims=" %%i in ('dir /b /a-d /s *.txt') do (
    set n=0
    for /f "delims=" %%j in ('type "%%i"') do (
        set "s=%%j"
        set "s=!s:"=!"
        for %%k in ("!s:<img=" "!") do set /a n+=1
        set /a n-=1
    )
    echo ren "%%i" "%%~ni（!n!）%%~xi"
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /r %%i in ("*.txt") do (
    set n=0
    for /f "delims=" %%a in ('type "%%i"^|findstr /c:"img alt"') do (
        set "str=%%a"
:a
        echo "!str!"|findstr /c:"img alt">nul&&set str=!str:*img alt=!&&set /a n+=1&&call :a
    )
    ren "%%i" "%%~ni（共!n!张图片）%%~xi" 2>nul
)
goto :eof
复制代码