批处理之家 - Powered by Discuz! Board

标题: [文本处理] [己解决]批处理修改文本内容添加HTML标签 [打印本页]

作者: 18938530517 时间: 2019-4-6 01:37 标题: [己解决]批处理修改文本内容添加HTML标签

本帖最后由 18938530517 于 2019-4-9 16:20 编辑

请教：

将文本：
1.mp4
下载1
2.mp4
下载2
3.mp4
下载3

修改为：
<body><a href="下载1">1.mp4</a></body></html>
<body><a href="下载2">2.mp4</a></body></html>
<body><a href="下载3">3.mp4</a></body></html>

作者: codegay 时间: 2019-4-6 02:46

列1 列2
下1 1.mp3
复制代码

输入文件改成类似CSV格式的文件这样更好，对于代码逻辑更好处理。

作者: 18938530517 时间: 2019-4-6 02:54

正在找奇偶互换的代码

作者: yhcfsr 时间: 2019-4-6 10:22

powershell

$text=gc tt.txt -ReadCount 0;
$count=$text.Count;
[System.Collections.ArrayList] $result=@();
for($i=1;$i -lt $count;$i+=2)
{
    [void] $result.Add('<body><a href="'+$text[$i]+'">'+$text[$i-1]+'</a></body></html>')
}
[io.file]::WriteAllLines('结果.txt',$result,[text.encoding]::Default)
复制代码

作者: zaqmlp 时间: 2019-4-6 11:31

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
start mshta VBScript:Execute("msgbox(""%info%""):close")
cd /d "%~dp0"
set "入=1.txt"
set "出=2.txt"
cd.>"%出%"
for /f "delims=" %%a in ('type "%入%"') do (
    if defined line (
        >>"%出%" echo;^<body^>^<a href="%%a"^>!line!^</a^>^</body^>^</html^>
        endlocal&set "line="
    ) else (
        set "line=%%a"
        setlocal enabledelayedexpansion
    )
)
type "%出%"
pause
复制代码

作者: Batcher 时间: 2019-4-8 17:28

@echo off
setlocal enabledelayedexpansion
set "n=0"
(for /f "delims=" %%i in ('type "1.txt"') do (
    set /a n+=1
    set /a m=n%%2
    if !m! equ 1 (
        set str=%%i^</a^>^</body^>^</html^>
    ) else (
        echo ^<body^>^<a href="%%i"^>!str!
    )
))>"2.txt"
复制代码

作者: 18938530517 时间: 2019-4-9 16:12 标题: RE: (已解决)求助：批处理修改文本内容添加HTML标签

本帖最后由 18938530517 于 2019-4-9 16:23 编辑

回复 6# Batcher
感谢老大提供的思路，方法和技巧
这几天，for的我都有点晕了，看了老大的代码才有点思绪，专业的就是专业，我一定好好学一下
还有，如此认真的回帖，真的是值得让人尊敬！

再次感谢，所有热心回复的朋友，祝你们心想事成！！！！

欢迎光临批处理之家 (http://www.bathome.net/)