@echo off
echo 请按先后顺序输入两个字母 如：af ，不能输入 fa
set /p input= 
cls
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
 if /i "%input:~0,1%"=="%%b" set ok=ok
 if /i "%input:~1,1%"=="%%b" set ok=&echo %%b
 if defined ok echo %%b
)
echo.&pause&exit
复制代码

@echo off
setlocal enabledelayedexpansion
:ke
cls
set /p zhen= 请按先后顺序输入两个不相邻的字母(如输入多于两个则只取前两个，^
如先后顺序颠倒或输入了相邻的字母请重新输入）
set zhen=%zhen:~0,2%
if %zhen:~0,1% geq %zhen:~1,1% goto ke
cls
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
    set /a wang+=1
    set %%b=!wang!
    if %%b gtr %zhen:~0,1%  if %%b lss %zhen:~1,1% echo %%b
)
set /a lu=!%zhen:~1,1%!-!%zhen:~0,1%!
if %lu%==1 goto ke
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
set /a count+=1
set %%i=!count!
set !count!=%%i
)
set /p input=输入两个顺序字母：
cls
for /l %%i in (!%input:~0,1%!,1,!%input:~1,1%!) do echo !%%i!
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set /p var=请按字母先后顺序输入两个字母：
set var1=%var:~0,1%
set var2=%var:~-1,1%
set str=a b c d e f g h i j k l m n o p q r s t u v w x y z
set count=1
:begin
for /f "tokens=%count%" %%i in ("!str!") do (
set /a count+=1
if %%i==!var1! set count1=!count!
if %%i==!var2! set /a count2=!count!-2
goto begin )
echo %count1% %count2%
set /a a=2*(count1-1)
set /a b=2*(count2-count1+1)
echo %a% %b%
set str1=!str:~%a%,%b%!
echo %str1%
pause
复制代码

@set/ps=Plz input:&(call echo e102 '%%s%%'&more /e +1 "%~f0")|debug|findstr "^[^I\-0P]"&pause>nul&exit/b
a100
jmp 104

a104
MOV     BL,[0103]
MOV     AL,[0102]
SUB     BL,AL
LEA     CX,[BX+01]
MOV     AH,02
MOV     DL,[0102]
INT     21
INC     DL
LOOP    0116
INT     20

g
q
复制代码

@echo off
setlocal enabledelayedexpansion
set "str= abcdefghijklmnopqrstuvwxyz"
set/p input=请按先后顺序输入两个字母（如 af ，不能输入 fa）：
cls
set/a n=0
:a
if not "%input:~1,1%"=="!str:~%n%,1!"  (set/a n+=1&goto :a)
set str=!str:~1,%n%!
set str=!str:*%input:~0,1%=!
echo %input:~0,1%!str!
echo.&pause
复制代码

echo 请按先后顺序输入两个字母 如：af ，不能输入 fa
set /p input= 
cls
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
  if /i "%input:~0,1%"=="%%b" set ok=ok
  if /i "%input:~1,1%"=="%%b" set ok=&echo %%b
  if defined ok echo %%b
  pause
)
echo.&pause
复制代码

@echo off&setlocal enabledelayedexpansion
set /p var=Input Alphabet: 
set n=-2
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (%str%) do (
 set /a n+=2
 set %%i=!n!)
set "star=%var:~,1%"
set "end=%var:~-1%"
set /a end1=!%end%!-!%star%!+1
call echo %%str:~!%star%!,%end1%%%
pause
复制代码

@echo off&setlocal enabledelayedexpansion

set char=abcdefghijklmnopqrstuvwxyz
set /p str= "请输入英文字母:"
set c1=%str:~0,1%
set c2=%str:~1,1%

for /l %%a in (0,1,25) do (
	set c3=!char:~%%a,1!
	if !c1!==!c3! set start=""
	if defined start set /p= !c3! <nul
	if !c2!==!c3! goto end
	
)
	
:end
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set /p zimu=输入两个字母
for %%a in (%str%) do (
if not %%a==%zimu:~1% (echo;%%a) else (echo;%%a&pause&exit)
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set n=
set /p zimu=输入任意两个字母:
set zimu1=%zimu:~,1%
set zimu2=%zimu:~1%
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
if %%a==%zimu1% set n=dui
if !n!==dui echo;%%a
if %%a==%zimu2% set n=cuo
)
复制代码

@echo off
setlocal enabledelayedexpansion
set /p ch=按字母顺序输入两个字母: 
set result=这两个字母中间是:
set table=a b c d e f g h i j k o m n o p q r s t u v w x y z
for %%I in (%table%) do (
    if /i %%I GTR %ch:~1,1% goto Finish
    if /i %%I GEQ %ch:~,1% set result=!result! %%I
)
:Finish
echo %result%
复制代码

@echo off
set "var=abcdefghijklmnopqrstuvwxyz"
set /p input=请按先后顺序输入两个字母（如 af ，不能输入 fa）：
for /f "tokens=2 delims=%input:~0,1%%input:~1,1%" %%a in ("%var%") do echo;%%a&pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion

set letterstr=a b c d e f g h i j k l m n o p q r s t u v w x y z
echo 请按先后顺序输入两个字母 如：af 
set /p input=
set index=0

for %%i in (%letterstr%) do (
	if /i "%%i"=="%input:~0,1%" (
		set start=!index!
	) 
	if /i "%%i"=="%input:~1,1%" (
		set end=!index!
	) 
	set /a index+=2
)

echo !start!-!end!
if !end! lss !start! (
	set /a len=!start!-!end!+1
	set start=!end!
) else (
	set /a len=!end!-!start!+1
)

call echo %%letterstr:~!start!,!len!%%
复制代码