批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理怎样操作xml文件？ [打印本页]

作者: Yamateh 时间: 2010-11-29 20:44 标题: 批处理怎样操作xml文件？

我有一个xml文件，想把它的第6,11,18行换成指定内容，所以写了下面的批处理
@echo off & setlocal EnableDelayedExpansion
set n=0
set path=c:\08r2moss07-rxz1200.xml
set path2=c:\test.xml
set a=2
set b=3
set c=1
for /f %%i in (%path%) do (
set /a n+=1
if !n! equ 6 (echo ^<backup-method^>%a%^</backup-method^> >>%path2%) ^
else (if !n! equ 11 (echo ^<data-configuration^>%b%^</data-configuration^> >>%path2%) ^
else (if !n! equ 18 (echo ^<advanced^>%c%^</advanced^> >>%path2%) ^
else echo %%i >>%path2%)
)
)
)
pause
问题是在C:\test.xml中第6,11,18行分别显示了2行，第一次是原始的xml，第二行是我更改的
我的程序错在哪啊？

作者: hanyeguxing 时间: 2010-11-29 21:24

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%a in ('more +7^<%~fs0') do set "#%%a=%%b"
(for /f "usebackq delims=" %%a in ("c:\08r2moss07-rxz1200.xml") do (
          set/a n+=1
          if defined #!n! (for %%b in (!n!) do echo !#%%b!) else echo %%a
))>"c:\test.xml"
exit
6:<backup-method>2</backup-method>
11:<data-configuration>3</data-configuration>
18:<advanced>1</advanced>
复制代码

作者: Yamateh 时间: 2010-11-30 19:30

请问我的代码错在哪啊

作者: hanyeguxing 时间: 2010-11-30 20:17

你在1楼的代码，没有发现语法错误，检查是否源文件中存在敏感字符

@echo off&setlocal enabledelayedexpansion
set "#6=<backup-method>2</backup-method>"
set "#11=<data-configuration>3</data-configuration>"
set "#18=<advanced>1</advanced>"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "c:\08r2moss07-rxz1200.xml"') do if defined #%%a (echo !#%%a!) else echo/%%b)>"C:\test.xml"
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)