[文本处理] 如何删除文本中的指定字符串并反转/颠倒文本行顺序

hqhlwz

求批处理文本 数字内容 排列方法
文本内容1万行为纯数字  如图1
想把文本中 所有开头的20去掉  同时将 后面5位数字之间的空格去掉  实现图2效果
并能 倒过来排列

hlzj88

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1-7 delims= " %%i in (1.txt) do (
  set "aa=%%i"
  set aa=!aa:~2!
 echo !aa! %%j%%k%%l%%m%%n%%o>>2.txt
)
pause
复制代码

xp3000

@set @n=0;/* & echo off

dir /b *.txt|cscript -nologo -e:jscript "%~0" ""
exit/b & rem */
arg = WScript.Arguments(0);
fso = new ActiveXObject("Scripting.FileSystemObject");
while (!WSH.StdIn.AtEndOfStream) {
    f = WSH.StdIn.ReadLine();
    txt = fso.OpenTextFile(f,1).ReadAll();
    txt = txt.replace(/^..(\d+ \d) (\d) (\d) (\d) (\d)/mg,"$1$2$3$4$5");
    fso.OpenTextFile(f,2).Write(txt);
}
复制代码

Batcher

回复 2# hlzj88

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1-7" %%i in (1.txt) do (
    set "aa=%%i"
    echo !aa:~2! %%j%%k%%l%%m%%n%%o
))>2.txt
复制代码

一万行的文本不算小，建议把重定向放到for循环外面，提高执行效率。

hlzj88

回复 4# Batcher

谢谢提醒，细节决定速度。

hqhlwz

回复 4# Batcher
感谢 各位大神指教  等下测试一下

hqhlwz

回复 4# Batcher
测试效果  速度很快 几秒 就好   再请教 如何  将 这1万行数字  倒过来重新排列呢

hqhlwz

回复 2# hlzj88
感谢指示  转换后的结果  如何能   从后而上  倒过来重新排列呢  谢谢

flashercs

回复 8# hqhlwz

sort /r 1.txt /o 2.txt
复制代码

hqhlwz

回复 9# flashercs
如何整合到图片中的代码呢？

xczxczxcz

几万行用纯P，一行行倒过来赋值给变量。速度估计个把小时。
下面的为 PowerShell 版。WIN7以上系统可用。PS3.0以上最好。
121440行。约12秒完成 修改并全部倒排。

$StartTime= Get-date # 开始计时

((cat ".\00.txt") | %{
	$str=$_ -replace "^20","" -replace "[\s]",""
	$str.insert(10," ")
	}
) | SC "$env:temp\ref.txt"
$Total = (cat "$env:temp\ref.txt" -TotalCount -1).Count
(Cat "$env:temp\ref.txt")[$Total..0] | SC ".\ok.txt"

Ri "$env:temp\ref.txt" -force

Write-host "共用时间："([DateTime]::Now - $StartTime).TotalMilliseconds"毫秒" -Fore RED

# 计时结束

pause
复制代码

===========保存为 xxx.ps1  点右键用 windows powershell 运行。系统自带
-------------------------------------------------------------------------------------------------------

附上 纯P 供参考：

@echo off & cd /d "%~dp0"
echo %time%

setlocal EnableDelayedExpansion
for /f "tokens=1*" %%a in (00.txt) do (
	set "aa=%%a"
	set "bb=%%b"
	set /a n+=1
	set "str!n!=!aa:~2! !bb: =!"
	rem echo !aa:~2! !bb: =!
)

(for /l %%e in (%n% -1 1) do echo !str%%e!)>final.txt

echo %time%

pause & exit
复制代码

注不要用 sort /r 它会按大小排序。

hqhlwz

回复 11# xczxczxcz
感谢你的提示 刚测试你的方法 用sort的方法 也测试了 结果是一样  但使用大神你的代码  转换过程有点慢
能否提高一下效率呢

附上 测试文件 下载地址http://data.917500.cn/cqssc_10000.txt

xczxczxcz

回复 12# hqhlwz


    偶那个是倒排的。不是倒序排列。倒序是从大到小排列。若你的原始文档是从小到大排好的。那倒排和倒序是一样的。用 sort /r 当然快。若你的原始文本内容并不是从小到大排列，是乱序的。倒排和倒序就不一样了。偶写的是倒排。不管你原始顺序如何。都是按原文本从后到前排列。不会受字符大小的影响。看你的需求了。

xczxczxcz

回复 12# hqhlwz

    针对你这个文本。全是从小到大的排序。当然简单了。

纯 P 约 2秒

@echo off & cd /d "%~dp0"
echo %time%

setlocal EnableDelayedExpansion
(for /f "tokens=1*" %%a in (00.txt) do (
	set "aa=%%a"
	set "bb=%%b"
	echo !aa:~2! !bb: =!
))>%temp%\ref.txt
sort /r "%temp%\ref.txt" /o final.txt
del /q/f "%temp%\ref.txt"
echo %time%

pause
复制代码

=============================
纯 PS 约 0.6秒

$StartTime= Get-date # 开始计时

((cat ".\00.txt") | sort -desc | %{
	$str=$_ -replace "^20","" -replace "[\s]",""
	$str.insert(10," ")
	}
) | SC ".\ok.txt"

$Time = [DateTime]::Now - $StartTime
Write-host "共用时间："$Time.Seconds"秒 "$Time.Milliseconds"毫秒" -Fore RED

# 计时结束

pause
复制代码

==============================

WHY

gawk "{a[NR]=substr($1,3)\" \"$2\"\"$3\"\"$4\"\"$5\"\"$6}END{for(i=NR;i>0;i--)print a[i]}" 1.txt > 2.txt
复制代码

PowerShell "[Collections.ArrayList]$arr=[IO.File]::ReadAllLines('1.txt') -replace '^20|(?<!\d\d)\s';$arr.Reverse();sc 2.txt -Value $arr"
复制代码

sort /r 1.txt | sed -r "s/^20|\s//g; s/[0-9]{5}$/ &/" > 2.txt
复制代码