[系统相关] [分享]schtasks命令管理计划任务示例

@echo off&setlocal ENABLEDELAYEDEXPANSION
set "taskName=自查提醒"
if not exist "%windir%\tasks\!taskName!.job" (
  set /p newpassword=请为当前用户输入新密码[否则不能成功创建循环任务]:
  set /p mins=请输入提醒间隔时间[单位:分][默认:1分钟]:
  if "!mins!"=="" set "mins=1"
  (net user %USERNAME% !newpassword!)
  rem 确保 Task Scheduler 服务启动
  sc config Schedule start= Auto>nul
  (sc query Schedule | find "RUNNING">nul) || (
  ((sc query Schedule | find "PAUSED">nul) && sc continue Schedule) || sc start Schedule
  )
  rem 建立计划任务运行本程序
  schtasks /create /tn "!taskName!" /sc minute /mo !mins! /tr %~s0 /ru %USERDOMAIN%\%USERNAME% /rp !newpassword!
  pause
)
rem Doing Task...
title 监保部提醒您：&color 0A&echo.&echo.&echo.&echo.
echo --------------------------------------------------------------------------------
echo.
echo                                      监保部提醒您
echo.  
echo                            贵单位今日是否已完成自查工作
echo.     
echo --------------------------------------------------------------------------------
echo.&echo.&echo.&echo.&echo.
SET /P ST=          请输入 Y (自查已完成)  或  N (现在做自查)  或 E (一会再做)：  
echo. 
if /I "%ST%"=="Y" (call :deleteTask)&exit /b
if /I "%ST%"=="N" (call :open)&exit /b
if /I "%ST%"=="E" exit /b
if /I "%ST%"=="" exit /b

:open
cls
start "" "http://21.28.16.128:8080/icmis2/urop/login.jsp"
exit /b

:deleteTask
schtasks /delete /tn "!taskName!" /f
exit /b
复制代码