[文件操作] 批处理怎样定期删除ftp上的旧备份文件？

rem 格式：
rem -rw-rw-rw-   1 user     group    1004346458 Jan  3 18:43 2011_pwdll_20100102_2255.rar
@echo off
rem 指定FTP用户名
set ftpUser=aaa
rem 指定FTP密码
set ftppass=aaa
rem 指定FTP服务器地址
set ftpIP=11.11.22.22
rem 指定待删除的文件位于FTP服务器的什么位置
set ftpFolder=/dat1
rem 指定删除几天前的文件
set DaysAgo=15
set ftpDir=%temp%\TempDir.txt
set ftpDel=%temp%\Tempdel.txt
rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay
>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%
ping 127.1 -n 12
>"%ftpDel%" echo.%ftpUser%
>>"%ftpDel%" echo.%ftpPass%
>>"%ftpDel%" echo bin
>>"%ftpDel%" echo cd "%ftpFolder%"
(for /f "usebackq skip=2 tokens=1-12 delims=_ " %%a in ("%temp%\Filelist.txt") do (
   if "%%k" leq "%DstYear%%DstMonth%%DstDay%" (
    echo del "%%i_%%j_%%k_%%l" 
  )
  endlocal
))>>"%ftpDel%"
>>"%ftpDel%" echo bye
ping -n 5 127.1 >nul
rem -rw-rw-rw-   1 user     group    1004346458 Jan  3 18:43 2011_ptas_20100102_2255.rar
rem start ftp -v -i -s:"%ftpDel%" %ftpIP%
ping -n 6 127.1 >nul
rem sdelete -p 1 "%ftpDel%"
rem sdelete -p 1 "%ftpDir%"
rem sdelete -p 1 "%temp%\Filelist.txt"
goto :eof
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

@echo off&setlocal EnableDelayedExpansion
for /f "tokens=9" %%i in (1.txt) do (echo %%i>>b.txt)
::选取文件名列表
for /f %%i in (b.txt) do (cd.>%%i)
::根据上面的文件名列表批量新建文件，作为演示
del b.txt
echo 新建演示文件成功
dir *.zip
::删除临时文件b.txt
for /f "tokens=1-3 delims=-/ " %%a in ('date /t') do set/a date1=%%a*365+%%b*30+%%c
::2010*365+02*30+02
::获取当前系统时间的数字格式
::echo 当前时间值为%date1%
set/p date2=请设定要删除几天前的记录：
set/a date3=%date1%-%date2%
::echo 之后时间值为%date3%
for /r %%i in (*.zip) do (
::echo %%~nxi 
set var=%%~nxi 
::echo !var!
set var1=!var!
call,  set/a var2=%%var1:~18,8%%
::echo !var2!
call, set/a var3=%%var2:~0,4%%*365+%%var2:~4,2%%*30+%%var2:~-2%%
::echo !var3!
if !var3! leq %date3% (del %%i) else echo.
)
echo 处理后文件列表：
dir *.zip
pause
复制代码

2010-02-02 星期二
复制代码

新建演示文件成功
驱动器 D 中的卷是 Windows 2003
卷的序列号是 6C8A-606C

D:\我的文档\桌面\新建文件夹 的目录

2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100118_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100119_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100120_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100121_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100122_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100123_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100124_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100125_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100126_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100127_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100128_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100129_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100130_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100131_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100201_1800.bak.zip
              15 个文件              0 字节
               0 个目录 14,049,058,816 可用字节
请设定要删除几天前的记录：3



处理后文件列表：
驱动器 D 中的卷是 Windows 2003
卷的序列号是 6C8A-606C

D:\我的文档\桌面\新建文件夹 的目录

2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100130_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100131_1800.bak.zip
2010-02-02  14:00                 0 5512_17Dgdaj-xxwj_20100201_1800.bak.zip
               3 个文件              0 字节
               0 个目录 14,049,058,816 可用字节
请按任意键继续. . .
复制代码

 
@echo off
forfiles /D -15 /C "cmd /c del @file"
pause
复制代码