[出题]批处理搜索某文件夹并显示该文件夹的父目录

@echo off
call :next "D:"
pause
exit

:next
for /f "tokens=*" %%a in ('dir "%~s1" /ad /b') do (
  if "%%a"=="update" (echo  "%~1\%%a") else (
         call :next "%~1\%%a"
  )
)
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /s /ad /b C:\^|findstr /e  "\\update"') do (
set "t=%%i"&set "t=!t:\update=+!"
for /f "delims=+" %%j in ("!t!") do (
set "_%%j=vsbat"
)
)
for /f "tokens=1 delims=_=" %%h in ('set _') do echo %%h
endlocal
pause
复制代码

@echo off&setlocal enabledelayedexpansion
echo %cd%\ | findstr /I "nul'>\\update\\">nul && set yy=yy
if defined yy (for /f "delims=" %%a in ('echo %cd%\ ^| findstr /I "\\update\\"') do (
    set str=%%a
    for /f "delims=*" %%b in ('echo !str:\update\^=*!') do echo %%b
)) else (for /f "delims=" %%c in ('dir /ad /b /s^|findstr /I /E "update"') do (echo %%~dPc|findstr /I "\\update\\" >nul||echo %%~dPc))
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /ad /b /s *update') do (
    if /i "%%~na" equ "update" (
       set "str=%%a"&set "str=!str:update=/!"
       for /f "delims=/" %%a in ("!str!") do (
           if not defined _%%a echo %%a&set "_%%a=a"
       )
    )
)
pause>nul   
复制代码

@echo off
rem if /i "%cd:~-6%"=="update" echo %cd:~,-6%&pause&exit /b
rem 用for对特殊字符的兼容性好一点（如&^）。当然如果不介意，可以加引号以避免
for %%a in ("%cd%") do if /i "%%~nxa"=="update" echo %%~dpa&pause&exit /b
for /f "delims=" %%a in ('dir /ad/s/b update*') do if /i "%%~nxa"=="update" if "%%~dpa" neq "%%~da\" (if not exist "%%~dpa..\update\" echo %%~dpa) else echo %%~dpa
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir/ad/s/b d:\^|findstr /e /i "update"') do (
    set "str=%%i"
    set "a=!str:update=update?!"
    for /f "delims=?" %%j in ("!a!") do (
        set "b=%%j"
        if not defined !b! (
         set !b!=000 
        set "c=!b:~,-6!"
        echo !c! )
    )      
)
pause
::把d:\改成你想搜索的路径就可以了
复制代码

@echo off
setlocal enableDelayedExpansion
set fd=%~dp0
cd/d %fd%
for /f "delims=" %%d in ('dir/s/ad/b update? 2^>nul')do (
　if exist %%~dpdupdate\ (
　　set nd=%%d
　　set nd=!nd:%fd%=!
　　set nd=!nd:update=/!
　　set nd=!nd:*/=!
　　if "!nd!?"=="?" echo "%%~dpd"
　)
)
pause
复制代码