[其他] 批处理怎样解压一个文件以后删除这个文件的压缩包？

@echo off
chcp 65001 >nul
set rar="C:\Program Files\WinRAR\WinRAR.exe"
for /f "delims=" %%a in ('dir /b /s /a-d *.rar') do (
    %rar% x -ibck -y -pword "%%a" "%%~dpa"
    if not errorlevel 1 (
        del /f /q "%%a"
    )
)
pause
复制代码

@echo off
chcp 65001 >nul
set rar="C:\Program Files\WinRAR\WinRAR.exe"
for /f "delims=" %%a in ('dir /b /s /a-d *.rar') do (
    %rar% x -ibck -y -pword "%%a" "%%~dpa" && del /f /q "%%a"
)
pause
复制代码

@echo off
chcp 65001
set rar="C:\Program Files\WinRAR\Rar.exe"
for /f "eol=/ delims=" %%a in ('dir  /a-d /s /b *.rar') do (
        %rar%  x -y -pword "%%a" "%%~dpa" && del "%%a"
)
pause
复制代码

@echo off
chcp 65001 >nul
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /a-d *.rar *.zip ^|sort') do (
        set folder=%%~dpi
        set file=%%i
        setlocal enabledelayedexpansion
        "C:\Program Files\WinRAR\WinRAR.exe" x -y "!file!" "!folder!"
        if !errorlevel! equ 0 (
                del "!file!"
        ) else if !errorlevel! equ 6 (
                del "!file!"
        )
        endlocal
)
pause
复制代码

@echo off
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /s /a-d *.rar *.zip ^|sort') do (
	if exist "%%i" (
		"C:\Program Files\WinRAR\WinRAR.exe" x -y "%%i" "%%~dpi" && (
			del "%%i"
			for /f "delims=" %%j in ("%%~ni") do (
				del "%%~dpi%%~nj.part*%%~xi" 2>nul
			)
		)
	)
)
pause
复制代码