@echo off
>2.txt echo 35 70 39 96 45 26 79 86 40 72 92 46 31 68 95 71 65 73 58 90 29 89 10 82 50 42 94 84 01 34 17 93 06 32 74 07 44 76 37 08 55 47 53 22 23 88 13 16 66 19
>>2.txt echo 55 02 23 30 70 56 53 42 25 33 48 29 79 09 66 98 24 80 11 94 93 13 61 73 40 43 68 67 51 76 26 37 19 59 35 75 95 96 90 63 22 64 69 97 41 15 54 77 86 83
setlocal enabledelayedexpansion
for /f "delims=" %%a in (2.txt) do (
        for %%b in (%%a) do (
                set /a #%%b+=1
        )
)
for /f "delims=" %%a in (2.txt) do (
        for %%b in (%%a) do (
                if !#%%b! equ 2 (
                        if not defined ##%%b (
                                set str1=%%b !str1!
                                set str2=%%b !str2!
                                set /a m+=1
                                set ##%%b=1
                        )
                ) else (
                        set /a n+=1
                        set _!random!_!n!=%%b
                )
        )
)
for /f "tokens=2 delims==" %%a in ('set _') do (
        if !m! lss 50 (
                set str1=%%a !str1!
                set /a m+=1
        ) else (
                set str2=%%a !str2!
        )
)
call :1 "!str1!"
call :1 "!str2!"
pause & exit

        :1
        setlocal
        for %%a in (%~1) do (
                set /a k+=1
                set @!random!_!k!=%%a
        )
        for /f "tokens=2 delims==" %%a in ('set @') do (
                set newstr=%%a !newstr!
        )
        echo !newstr!
        endlocal
复制代码