[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖
jyswjjgdwtdtj

Rank: 3Rank: 3

帖子
168 
积分
220 
技术
9  
捐助
0  
注册时间
2023-2-9 
1楼 跳转到 » 倒序看帖
打印
tT
发表于 7 天前 18:11 | 只看该作者

[转贴] 学习wmi的好帮手之微软官方wmi.hta

本帖最后由 jyswjjgdwtdtj 于 2023-3-16 20:58 编辑

可惜我级别不够 发布到教程区 那就只能发这里了
  1. <html>

  2. <!--********************************************************************

  3. '*

  4. '*  File:           scriptomatic.hta 

  5. '*  Created:        August 2002

  6. '*  Version:        1.0

  7. '*

  8. '*  Description:    Learning tool. Enables users to generate and run 

  9. '*                  WSH scripts (in VBScript) that use WMI to display

  10. '*                  properties available through the Win32_ classes.      

  11. '*

  12. '*

  13. '* Copyright (C) 2002 Microsoft Corporation

  14. '*

  15. '********************************************************************-->

  16. <title>Windows .NET Server Resource Kit - Scriptomatic</title>

  17. 

  18. <HTA:APPLICATION 

  19.      ID="objScriptomatic" 

  20.      APPLICATIONNAME="Scriptomatic"

  21.      SCROLL="no"

  22.      SINGLEINSTANCE="yes"

  23.      WINDOWSTATE="normal"

  24. >

  25. <head>

  26. 

  27. <style>

  28. BODY

  29. {

  30.    background-color: buttonface;

  31.    font-family: Helvetica;

  32.    font-size: 8pt;

  33.    margin-top: 10px;

  34.    margin-left: 10px;

  35.    margin-right: 10px;

  36.    margin-bottom: 10px;

  37. }

  38. 

  39. 

  40. .button

  41. {

  42.    font-family: Helvetica;

  43.    font-size: 8pt;

  44.    width: 35px;

  45. }

  46. 

  47. textarea

  48. {

  49.    font-family: arial;

  50.    font-size: 8pt;

  51.    margin-left: 3px;

  52. }

  53. 

  54. select

  55. {

  56.    font-family: arial;

  57.    font-size: 8pt;

  58.    width: 450px;

  59.    margin-left: 0px;

  60. }

  61. 

  62. </style>

  63. 

  64. <script language="vbscript">

  65. Sub window_Onload

  66.    self.ResizeTo 1,1

  67.    self.MoveTo 300,300

  68.    Const adVarChar = 200

  69.    Const MaxCharacters = 255

  70.    strComputer = "."

  71.    

  72.    Set rsDataList = CreateObject("ADODB.Recordset")

  73.    rsDataList.Fields.Append "ClassName", adVarChar, MaxCharacters

  74.    rsDataList.Open

  75. 

  76.    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

  77.    For Each objclass in objWMIService.SubclassesOf()

  78.       bIsQualifier = False 

  79.       If UCase(Left(objClass.Path_.Class,5)) = "WIN32" Then

  80.          For Each Qualifier in objClass.Qualifiers_

  81.             If UCase(Trim(Qualifier.Name)) = "ASSOCIATION" Then

  82.                bIsQualifier = True

  83.             End If

  84.          Next

  85.          If bIsQualifier = False Then

  86.             rsDataList.AddNew

  87.             rsDataList("ClassName") = objClass.Path_.Class

  88.             rsDataList.Update

  89.          End If

  90.       End If

  91.    Next

  92. 

  93.    rsDataList.Sort = "ClassName"

  94.    rsDataList.MoveFirst

  95.    strHTML = "<select onChange=""ComposeCode()"" name=ClassesPulldown>" &_

  96.              "<option value=""ulldownMessage"">Begin by selecting a class"

  97.    Do Until rsDataList.EOF

  98.       strHTML = strHTML & "<option value= " & chr(34) &_

  99.       rsDataList.Fields.Item("ClassName") & chr(34) &_

  100.       ">" & rsDataList.Fields.Item("ClassName")

  101.       rsDataList.MoveNext

  102.    Loop

  103.    strHTML = strHTML & "</select>"

  104.    wmi_classes.insertAdjacentHTML "beforeEnd", strHTML

  105.    self.Focus()

  106.    self.ResizeTo 670,550

  107.    self.MoveTo 200,200

  108.       run_button.disabled = false

  109. 

  110. End Sub

  111. Sub ComposeCode

  112.    If ClassesPulldown.Value = "ulldownMessage" Then

  113.       run_button.disabled = True

  114.       Exit Sub

  115.    End If

  116. 

  117.    strComputer = "."

  118.    Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

  119.    Set objClass = objWMIService.Get(ClassesPulldown.Value)

  120.    strHTML = "<textarea cols=100 rows=30>"

  121.    strHTML = strHTML & "On Error Resume Next" & Chr(10)

  122.    strHTML = strHTML & "strComputer = " & chr(34) & "." & chr(34) & Chr(10)

  123.    strHTML = strHTML & "Set objWMIService = GetObject(" & chr(34) & "winmgmts:\\" & chr(34) & " & strComputer & " & chr(34) & "\root\cimv2" & chr(34) & ")" & Chr(10) 

  124.    strHTML = strHTML & "Set colItems = objWMIService.ExecQuery(" & chr(34) & "Select * from " & ClassesPulldown.value & chr(34) & ",,48)" & Chr(10)

  125.    strHTML = strHTML & "For Each objItem in colItems" & Chr(10)

  126.    For Each objProperty in objClass.properties_

  127.       strHTML = strHTML & "    Wscript.Echo " & chr(34) & objProperty.name & ": " & chr(34) & " & " & "objItem." & objProperty.name & Chr(10)

  128.    Next

  129.    strHTML = strHTML & "Next" & "</textarea>"

  130.    code.InnerHTML= strHTML

  131.    run_button.disabled = False

  132. 

  133. End Sub

  134. Sub RunScript

  135.    Set objFS = CreateObject("Scripting.FileSystemObject")

  136.    strtmpname="temp_script.vbs"

  137.    Set objScript = objFS.CreateTextFile(strTmpName,true,true)

  138.    objScript.Writeline code.InnerText

  139.    objScript.Close

  140.    Set objShell = CreateObject("WScript.Shell")

  141.    objShell.Run("cmd /k cscript.exe //nologo "&strtmpname)

  142.    sleep 100

  143.    objfs.deletefile(strtmpname)

  144. End Sub

  145. 

  146. Sub QuitScript

  147. 

  148.    On Error Resume Next

  149.    Set objFSO = CreateObject("Scripting.FileSystemObject")

  150.    objFSO.DeleteFile "temp_script.vbs"

  151.    Set objFSO = Nothing

  152.    self.Close()

  153. 

  154. End Sub

  155. 

  156. 

  157. </script>

  158. <script language="javascript">

  159. function sleep(delay) {

  160.     for(var t = Date.now(); Date.now() - t <= delay;);

  161. }

  162. </script>

  163. </head>

  164. 

  165. 

  166. <body>

  167. <table>

  168.    <td>

  169.       <span id="wmi_classes"> </span>

  170.       <input id=runbutton  class="button" type="button" value="Run"  name="run_button"  onClick="RunScript()">

  171.       <input id=quitbutton class="button" type="button" value="Quit" name="quit_button" onClick="QuitScript()">

  172.       <div ID=code_header></div>

  173.       <div id="code"></div>

  174.    </td>

  175. </tr>

  176. </table>

  177. </body>

  178. </html>
复制代码
保存为scriptomatic.hta
02年的啊
为了不超过10000个字符 删了所有的注释……
有点问题 修了一下
收藏 分享
角元塞瓦解决角格点问题的通解

返回列表