[其他] [已解决]批处理如何给视频批量截图结尾最后3秒处？

@echo off
setlocal enabledelayedexpansion
REM 视频结尾最后3秒处
set "SecBack=3"
REM 根据自己电脑实际情况设置ffmpeg的路径
set "path=C:\Program Files\ffmpeg\ffmpeg-n5.1-latest-win64-gpl-5.1\bin\;%path%"
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
    echo Current file: %%i
    for /f "tokens=2-5 delims=:., " %%a in ('ffmpeg -i "%%i" 2^>^&1 ^| find "Duration:"') do (
        echo Duration %%a:%%b:%%c:%%d
        set /a "TotalCS=(1%%a%%100*3600+1%%b%%100*60+1%%c%%100)*100+1%%d%%100"
        set /a "SeekCS=TotalCS-SecBack*100"
        set /a "SeekSS=SeekCS/100"
        set /a "HH=SeekSS/3600+100"
        set /a "MM=SeekSS%%3600/60+100"
        set /a "SS=SeekSS%%60+100"
        set /a "CS=SeekCS%%100+100"
        set "SeekPosition=!HH:~1!:!MM:~1!:!SS:~1!.!CS:~1!"
        echo Position !SeekPosition!
    )
    ffmpeg -v quiet -i "%%i" -ss !SeekPosition! -frames:v 1 "%%~ni.png"
)
复制代码

@echo off & setlocal enabledelayedexpansion
title ffmpeg视频尾部X秒批量截图
:a
set /p "str=输入1-9秒:"
   echo %str%|findstr /x "[1-9]" >nul||(echo 输入有误,按任意键返回&goto :a ) 

for /f "delims=" %%i in ('dir /b /a-d *.avi *.mkv *.mp4 *.flv') do (
    for /f "tokens=2-5delims=:., " %%a in ('ffmpeg -i "%%i" 2^>^&1 ^| find "Duration:"') do (
        set /a "t=(1%%a%%100*3600+1%%b%%100*60+1%%c%%100)*1000+1%%d0%%1000,t-=%str%*1000,ms=t%%1000,t/=1000"
        set /a h=t/3600,m=t%%3600/60,s=t%%60,h+=100,m+=100,s+=100,ms+=1000
        set "t=!h:~1!:!m:~1!:!s:~1!.!ms:~1!"
        echo 文件：%%i 将在!t!处截图，请耐心等待……
        ffmpeg -v quiet -ss !t! -i "%%i" -frames:v 1 "%%~ni.png"
    )
)
pause
复制代码

@if(0)==(0) echo off& setlocal EnableDelayedExpansion&cd %~dp0
title ffmpeg视频尾部XX秒批量截图
:ss
set /p ss=请输入秒数（例：5或21）: 
@for /f "delims=" %%i in ('echo %ss%^|cscript -nologo -e:jscript "%~f0"') do (
if not "%%i"=="正确" echo. & echo 时间格式不对，请重新输入1-59内数字 & goto ss
)
for /f "delims=" %%i in ('dir /b /a-d *.avi *.mkv *.mp4 *.flv') do (
    for /f "tokens=2-5delims=:., " %%a in ('ffmpeg -i "%%i" 2^>^&1 ^| find "Duration:"') do (
        set /a "t=(1%%a%%100*3600+1%%b%%100*60+1%%c%%100)*1000+1%%d0%%1000,t-=%ss%*1000,ms=t%%1000,t/=1000"
        set /a h=t/3600,m=t%%3600/60,s=t%%60,h+=100,m+=100,s+=100,ms+=1000
        set "t=!h:~1!:!m:~1!:!s:~1!.!ms:~1!"
        echo 文件：%%i	将在!t!处截图，请耐心等待……
    )
    ffmpeg -v quiet -ss !t! -i "%%i" -frames:v 1 "%%~ni.jpg"
)

pause & exit /b
@end
WSH.echo(WSH.StdIn.ReadAll().replace(/^[1-5]\d|^[1-9]/, '正确').match(/^[^\r\n]+/).join('\r\n'));
复制代码